Résolu par Cisco.... Reporter le point non gagné

[Clochard]

Bonjour le Forum,

Au golf... dans une partie amicale, s'il y a égalité sur un trou misé... comment faire pour reporter le point au prochain trou gagné

Merci beaucoup d'y regarder
Clochard

 

[CISCO]

Re : Reporter le point non gagné

Bonjour

C'est bizarre, ou il y a quelque chose que je ne comprend pas

"Donc... aux trous 7 et 10 il y a égalité... les deux points sont reportés au prochain trou misé gagné... si l'égalité persiste les points sont perdus..."

Qu'est-ce que cela aurait donné s'il y avait eu égalité au trou 17 dans le cas que tu as présenté ?

Et qu'est-ce que cela donne dans le cas de la pièce jointe ?

@ plus

 

[Clochard]

Re : Reporter le point non gagné

Bonjour Cisco,

Désolé de n'avoir pu répondre plus tôt....

S'il y avait eu égalité au 17 trou... personne n'aurait pu bénéficier des 3 points.... il n'aurait eu que Toto qui aurait fait 1 point au trou numéro 5

Clochard

 

[CISCO]

Re : Reporter le point non gagné

Bonsoir


Oui, et dans le cas de ma pièce jointe ? A savoir, Toto perd (5/4) au trou n°5, 1 point pour Tata, puis ex-aequo aux trous 7 et 10.

* Si les deux joueurs sont ex-aequo au trou n°10, c'est Tata qui gagne 1 point à 0. OK
* Si c'est Toto qui gagne au trou n°17, c'est lui qui gagne 3 points à 0, alors qu'ils ont tous les deux gagnés un trou, et été ex-aequo aux autres trous misés !

Ceci dit, puisque les règles sont ainsi... Je te fais ça demain matin si personne ne passe par là entre temps...

@ plus

P.S: J'ai fait "caddy" à Domont dans la région parisienne dans ma jeunesse. Superbe parcours très boisé à l'époque... Que c'est loin.

 

[Clochard]

Re : Reporter le point non gagné

Merci Cisco...

Merci pour ta participation a ma demande...

Si je n'ai pu répondre plus tôt c'est que j'étais en train de jouer au golf sur le parcours de golf à Boynton Beach en Floride où j'y suis pour 2 mois...

Il y a 2 trous de gagés dans le premier neuf.... et deux autres trous de gagés également dans le deuxième neuf.. qui donne 1 point à celui qui a le plus bas pointage sur le trou gagé... avec la possibilité d'un maximum de 4 points au total.... s'il y a égalité sur un trou le point est reconduit au trou suivant... donc celui qui gagne le trou suivant obtient 2 points et ainsi de suite... s'il y a égalité sur les 4 trous gagés... personne n'aura de point...

Merci beaucoup d'y regarder
Clochard

 

[CISCO]

Re : Reporter le point non gagné

Bonjour

Cf. en pièce jointe.

J'ai ajouté une colonne pour avoir un 0 en D10 et D11, utiles pour les MAX ci-dessous. Tu peux mettre une police blanche dans ces deux cellules pour faire "disparaître" ces deux 0.

Dans le fichier Reporté, dans E10 la formule est

SI(ET(E4="X";E6<E8);
MAX($D10: D10)+
MOD(SOMMEPROD((
DECALER($D6;;MAX(EQUIV(MAX($D10:D10);$D10:D10;0);EQUIV(MAX($D11:D11);$D11:D11;0));;COLONNES($D11:D11)-MAX(EQUIV(MAX($D10:D10);$D10:D10;0);EQUIV(MAX($D11:D11);$D11:D11;0)))=
DECALER($D8;;MAX(EQUIV(MAX($D10:D10);$D10:D10;0);EQUIV(MAX($D11:D11);$D11:D11;0));;COLONNES($D11:D11)-MAX(EQUIV(MAX($D10:D10);$D10:D10;0);EQUIV(MAX($D11:D11);$D11:D11;0))))*
(DECALER($D4;;MAX(EQUIV(MAX($D10:D10);$D10:D10;0);EQUIV(MAX($D11:D11);$D11:D11;0));;COLONNES($D11:D11)-MAX(EQUIV(MAX($D10:D10);$D10:D10;0);EQUIV(MAX($D11:D11);$D11:D11;0)))="X")
*(COLONNE(DECALER($D4;;MAX(EQUIV(MAX($D10:D10);$D10:D10;0);EQUIV(MAX($D11:D11);$D11:D11;0));;COLONNES($D11:D11)-MAX(EQUIV(MAX($D10:D10);$D10:D10;0);EQUIV(MAX($D11:D11);$D11:D11;0))))<>13))
;3)
+1;"")

Le test SI(ET(E4="X";E6<E8) permet de repéré si le trou en cours est misé (="X"), et s'il a été gagné par Toto (E6<E8).
Le MAX($D10: D10) prend en compte les points déja attribué à Toto.
Le SOMMEPROD((DECALER($D6;........)=DECALER($D8;........))*(DECALER($D4;.....)="X)*(COLONNE(DECALER($D4;......))<>13)) permet de compter les ex-eaquo misés pas en colonne N (sous-totaux) depuis le dernier point attribué soit en ligne 10, soit en ligne 11.
Le MOD(SOMMEPROD(......).3) permet d'annuler trois ex-aequo successifs.
le +1 final ajoute le point gagné par Toto pour le trou en cours.

Comme on peut le voir ci-dessus, la difficulté est de cibler la plage depuis le dernier point attribué en ligne 10 ou en ligne 11 pour compter les ex-aequo utiles. Et cela, on le fait plusieurs fois, ce qui fait qu'il y plusieurs fois presque la même expression dans la formule (les pointillets en rouge ci-dessus).

Pour simplifier cela, j'ai mis dans le fichier repéréter le nom position_dernier_point_lignes10et11

=MAX(EQUIV(MAX(Feuil2!$D$10:D$10);Feuil2!$D$10:D$10;0);EQUIV(MAX(Feuil2!$D$11:D$11);Feuil2!$D$11:D$11;0))

qui cherche la position du dernier point attribué aussi bien sur la ligne 10 que sur la ligne 11.
Dans ce dernier fichier, la formule en E10 est alors

SI(ET(E4="X";E6<E8);
MAX($D10:D10)+
MOD(SOMMEPROD((
DECALER($D6;;position_dernier_point_lignes10et11;;COLONNES($D11:D11)-position_dernier_point_lignes10et11)=
DECALER($D8;;position_dernier_point_lignes10et11;;COLONNES($D11:D11)-position_dernier_point_lignes10et11))*
(DECALER($D4;;position_dernier_point_lignes10et11;;COLONNES($D11:D11)-position_dernier_point_lignes10et11)="X")*
(COLONNE(DECALER($D4;;position_dernier_point_lignes10et11;;COLONNES($D11:D11)-position_dernier_point_lignes10et11))<>13))
;3)
+1;"")

En fait les DECALER sont identiques, seule change la cellule origine, D4 (pour connaitre les trous misés), D6 ou D8 (pour comparer ces deux lignes entre elles).
Donc, on peut faire encore (apparemment) plus simple. Cf. le dernier fichier repéré4. La formule en E10 devient alors

SI(ET(E4="X";E6<E8);MAX($D10:D10)+MOD(SOMMEPROD((
DECALER(plage4;2;)=DECALER(plage4;4;))*(plage4="X")*(COLONNE(plage4)<>13));3)+1;"")

En ligne 11, seul change le début de la formule : SI(ET(E4="X";E6<E8);MAX($D10: D10) devient SI(ET(E4="X";E6>E8);MAX($D11: D11)

@ plus

P.S : Le COLONNE(plage4)<>13 est là pour éliminer les valeurs en N6 et N8, c-à-d les totaux intermédiaires après les 9 premiers trous.
P.S2 : Je n'avais pas vu ta ligne 3 ni ton tableau à droite à partir de la colonne Z.

 

[CISCO]

Re : Reporter le point non gagné

Bonjour

Beaucoup plus simple, toujours avec SOMMEPROD, en ciblant les valeurs à prendre en compte,
* non pas avec plusieurs DECALER sur les bonnes plages,
* mais en prenant des plages trop grandes et en ne gardant que les valeurs après la colonne du dernier point attribué, le plus à droite en ligne 10 ou en ligne 11 avec COLONNE($D4: D4)-3>MAX(EQUIV(MAX($D10: D10);$D10: D10;0);EQUIV(MAX($D11: D11);$D11: D11;0)).
Cela donne en E10

SI(ET(E4="X";E6<E8);MAX($D10:D10)+MOD(SOMMEPROD(($D6:D6=$D8:D8)*($D4:D4="X")*(COLONNE($D4:D4)-3>MAX(EQUIV(MAX($D10:D10);$D10:D10;0);EQUIV(MAX($D11:D11);$D11:D11;0)))*(COLONNE($D4:D4)<>13));3)+1;"")

@ plus

 

[CISCO]

Re : Reporter le point non gagné

Bonjour

Une variante

@ plus

 

[CISCO]

Re : Reporter le point non gagné

Bonjour

Et en tenant compte de ton tableau en AA3:AD3

@ plus

 

[Clochard]

Re : Reporter le point non gagné

Bonjour Cisco,

Un vrai travail de Moine ce que tu as fait... tu as du travailler sur ça toute la nuit...

J'ai un problème urgent de climatisation ici... je dois malheureusement m'en occuper... mais aussitôt que ce problème réglé...
je m'attaque à ton gigantesque travail...

Merci énormément
Clochard

 

[Clochard]

Re : Reporter le point non gagné

Bonjour Cisco,

J'suis épaté par ton travail.....
Après quelques petites modifications dont j'étais capable je joins le fichier qui avec une toute petite modification (si possible) serait parfait pour moi...

Finalement Cisco... grâce à ton travail... j'ai finalement réussi à obtenir ce que je recherchais... donc c'est résolu

Merci beaucoup beaucoup et bonne journée

Clochard

 

[CISCO]

Re : Résolu par Cisco.... Reporter le point non gagné

Bonsoir

Les formules proposées dans mes précédents fichiers donnaient directement le total de points de Toto ou de Tata depuis le début de la partie.
Si tu ne veux que les points obtenus au cours du trou considéré (et des précédents trous où les joueurs étaient ex-aequo), il suffit de transformer dans E10 le début SI(ET(E4="X";E6<E8);MAX($D10: D10)+MOD(etc en SI(ET(E4="X";E6<E8);MOD(etc. Même type de transformation pour E11.
Mais peut être l'avais tu compris tout seul .

@ plud

 

[Clochard]

Re : Résolu par Cisco.... Reporter le point non gagné

Salut Cisco...

C'est EXACTEMENT ce que j'espérais.... Tout est PARFAIT....

J'suis vraiment vraiment content de ton aide...

Clochard

 

[CISCO]

Re : Résolu par Cisco.... Reporter le point non gagné

Bonsoir

La dernière transformation proposée est simple, mais c'est un peu un "coup de bol", car certaine fois, le EQUIV(MAX(...);...;0) ne renvoie pas la bonne valeur, mais cela ne semble pas poser de problème pour 4 trous misés.

@ plus

PS : Pourquoi est-ce que cela ne renvoie pas la bonne valeur ?
Et bien, parce qu'avec les anciennes formules, les valeurs affichées en lignes 10 et 11 allaient forcément en croissant (puisqu'on prenait avec le MAX la dernière valeur, à gauche de la cellule en cours et qu'on y ajoutait une valeur positive). Dans ce cas, la fonction EQUIV(...;....;0) renvoie bien la position du dernier nombre le plus à droite, juste avant, à gauche de la cellule en cours.
Avec la nouvelle formule, on peut très bien avoir {1;0;0;0;0;0;1;0;0;0;1;... la liste des valeurs non nulles n'est plus croissante et alors, EQUIV(MAX( renvoie la position du premier 1, pas du second ou du troisième, alors que certaines fois, c'est le second ou le troisième qui compte.

 

[CISCO]

Re : Résolu par Cisco.... Reporter le point non gagné

Re

Dans ces conditions, c'est plus prudent de faire avec EQUIV(9^9;....;1) à la place de EQUIV(MAX(...);....;0). Cf. en pièce jointe.

@ plus