[RESOLU] : message d'alerte special

[MADAGASCAR]

Bonjour forum
Bonjour tous le monde
je serai tres ravi si quelqu'un peut m'aider a resoudre mon probleme ..
j'ai explique mon but dans le fichier ci joint
merci d'avance pour l'aide
cordialement
MADA

 

[Compte Supprimé 979]

Re : message d'alerte special

Bonjour

C'est le b*rdel dans ton code 😛

J'ai ajouté ce qu'il te fallait

Private Sub TextBox1_Change()  'au changement dans la TextBox1
  Dim dl As Integer  'déclare la variable dl (Dernière Ligne)
  Dim pl As Range  'déclare la variable pl (PLage)
  Dim r As Range  'déclare la variable r (Recherche)
  Dim pa As String  'déclare la variable dl (Première Adresse)
  Dim NbVal As Long
  NbVal = 0
  Me.ListBox1.Clear  'vide la ListBox1
  With Sheets("Feuil1")  'prend en compte l'onglet "Feuil1"
    dl = .Cells(Application.Rows.Count, 1).End(xlUp).Row  'définit la dernière ligne éditée dl de la colonne 1 (=A)
    Set pl = .Range("A2:A" & dl)  'définit la plage pl
  End With  'fin de la prise en compte de l'onglet "Feuil1"
  Set r = pl.Find(Me.TextBox1.Value, , xlValues, xlPart)  'définit la recherche r (recherche la valeur de la TextBox1 dans la plage pl)
  If Not r Is Nothing Then  'condition : si il existe au moins une occurrence trouvée
    pa = r.Address  'définit l'adresse de la première occurrence trouvée
    Do  'exécute
      With Me.ListBox1  'prend en compte la ListBox1 (qui compte quate colonne de 0 à 3 et dont la colonne 3 est masquée)
        .AddItem Sheets("Feuil1").Cells(r.Row, 1).Value  'ajoute la valeur de la cellule en colonne A de l'occurrence trouvée
        NbVal = NbVal + 1
        ' .Column(1, .ListCount - 1) = Sheets("Feuil1").Cells(r.Row, 2) 'ajoute la valeur de la cellule en colonne B de l'occurrence trouvée
        '.Column(2, .ListCount - 1) = Sheets("Feuil1").Cells(r.Row, 3) 'ajoute la valeur de la cellule en colonne C de l'occurrence trouvée
        '.Column(3, .ListCount - 1) = r.Row 'ajoute le numéro de ligne
      End With  'fin de la prise en compte de la ListBox1
      Set r = pl.FindNext(r)  'redéfinit la recherche r (occurrence suivante)
    Loop While Not r Is Nothing And r.Address <> pa  'boucle tant qu'il existe de nouvelles occurrences ailleurs qu'en pa
  End If  'fin de la condition
  If NbVal > 0 Then
    Me.TextBox2.Value = NbVal
  ElseIf Me.TextBox1.Value <> "" Then
    MsgBox "Aucun mot trouvé !"
  End If
End Sub

Bon courage

 

[MADAGASCAR]

Re : message d'alerte special

Bonjour BRUNO
merci pour l'aide
c pas mon code je l'ai trouve je ne sais pas où ??
merci c'est ce que je veux sauf le message qui s'affiche j'avais mon desir que l'usf 2 qui s'affichera au lieu de ce message.
merci d'avance
dans tous les cas merci
c'est bien resolu
cordialement
MADA

 

[Compte Supprimé 979]

Re : [RESOLU] : message d'alerte special

Re,

Il suffit de remplacer

MsgBox "Aucun mot trouvé !"

par

Userform2.Show

A+

 

[MADAGASCAR]

Re : [RESOLU] : message d'alerte special

Salut Bruno
merci beaucoup .. bien fait et bien affiché l' usf 2
merci pour l'aide
cordialement
MADA