RESOLU MACRO VB toute bête

[chris6999]

Bonsoir

Je suis en train de me casser la tête sur une macro qui déterminerait 2 variables en fonction de 2 autres
J'ai dans ma colonne C un nombre d'heures
dans ma colonne D un coût horaire
dans ma colonne E un coût total (nb d'heure X coût horaire)

La seule donnée définie est le nombre d'heures
Je souhaiterais une macro qui permettrait d'afficher en E le coût total si je saisis le coût horaire en D
et en sens inverse d'afficher en D le coût horaire si je saisis le coût total en E

Lorsque l'une des valeurs de C, D,ou E est supprimée toutes les valeurs le sont

Cela peut paraître bête mais je ne sais pas comment le prendre.
Si quelqu'un peut m'aider.


Cordialement

 

[kjin]

Re : MACRO VB toute bête

bonsoir,
Dans le module de la feuille

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Column = 4 Then Target.Offset(0, 1) = Target.Offset(0, -1) * Target
If Target.Column = 5 Then Target.Offset(0, -1) = Target / Target.Offset(0, -2)
End Sub

Il faudra sans doute ajouter la gestion d'erreurs éventuelles et définir la plage de fonctionnement
A+
kjin

 

[chris6999]

Re : MACRO VB toute bête

Bonsoir Kjim

Je viens de tester ta proposition qui fonctionne nickel pour les calcul et la reconstitution des variables manquantes.

Par contre c'est lorsque je supprime les valeurs saisies que cela ne va plus.
Lorsque je supprime la valeur dans C la cellule est vide mais les valeurs dans D et E restent affichées.
Lorsque je supprime la valeur dans D, la valeur de C reste en l'état. Les cellules D et E deviennent "0" au lieu de s'effacer

Cordialement

 

[kjin]

Re : MACRO VB toute bête

Bonjour,

Par contre c'est lorsque je supprime les valeurs saisies que cela ne va plus.

Pas vu la suite de la question...

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Count > 1 Then Exit Sub
x = Target.Row
y = Target.Column
If y > 2 And y < 6 Then
    If Not IsNumeric(Target) Or IsEmpty(Target) Or IsEmpty(Cells(x, 3)) Then
        Application.EnableEvents = False
        Range(Cells(x, 3), Cells(x, 5)).ClearContents
        Application.EnableEvents = True
        Exit Sub
    End If
End If
If y = 4 Then Cells(x, 5) = Cells(x, 3) * Target
If y = 5 Then Cells(x, 4) = Target / Cells(x, 3)
End Sub

La plage [C:E] est effacée si
- une cellule est effacée en C, D ou E
- il n'y a aucune valeur en C, ce qui oblige à renseigner cette colonne au préalable
- une valeur non numérique est saisie en C, D ou E
La macro ne gère pas la sélection multiple
A+
kjin

 

[chris6999]

Re : MACRO VB toute bête

Merci kjin

Cela fonctionne parfaitement.
A voir le code c'est quand même plus compliqué que ce que j'avais imaginé.
Merci encore pour ton aide précieuse.

Cordialement et bonne journée

 

[kjin]

Re : MACRO VB toute bête

Re,

A voir le code c'est quand même plus compliqué que ce que j'avais imaginé.

Ca n'est pas très compliqué, il y a seulement beaucoup de conditions...
A+
kjin