XL 2013 [RESOLU]Macro conversion PDF fichier WORD (depuis excel)

[kaozuin]

Bonjour à tous,

J'ai une nouvelle fois besoin de vos lumière (ou aide 🙂)

J'ai un fichier, où avec une macro j'obiten les liens de fichier word et je souhaite, via une macro ouvrir ces fichiers pour les "publier (ou enregistrer) au format PDF dans le même répertoire que la source.

Ci joint un fichier Excel où j'ai ma macro d'extraction de liens.

Auriez vous cela en réserve ? 🙂

En vous remerciant d'avance.

 

[kaozuin]

Petit up du sujet 🙂

Personne n'a de solution / sais si c'est possible à faire ?

 

[job75]

Bonjour kaozuin,

Vous n'avez pas de réponse parce que ce n'est pas clair.

S'il s'agit simplement de créer un document PDF à partir d'un document Word :

Sub PDF_Word()
Dim chemin$, doc$, pdf$, Wapp As Object
chemin = ThisWorkbook.Path & "\" 'à adapter
doc = "Mon document.docx" 'à adapter
pdf = Left(doc, InStrRev(doc, ".") - 1) & ".pdf"
Application.DisplayAlerts = False 'si le fichier Word est ouvert
On Error Resume Next
Set Wapp = GetObject(, "Word.Application")
If Wapp Is Nothing Then Set Wapp = CreateObject("Word.Application")
With Wapp.Documents.Open(chemin & doc)
    .ExportAsFixedFormat chemin & pdf, ExportFormat:=17 '17 => wdExportFormatPDF
    .Close False
    If Wapp.Documents.Count = 0 Then Wapp.Quit
End With
End Sub

Téléchargez les fichiers zippés joints dans le même dossier.

A+

 

[job75]

Re,

Si l'on veut afficher le document PDF utiliser ce fichier (2) avec l'instruction :

Shell Environ("WINDIR") & "\explorer.exe " & chemin & pdf, vbNormalFocus

A+

 

[kaozuin]

Salut Job75 !

Merci de ton aide j'ai adapté et automatisé cela ! (enfin ... je suis entrain de finaliser tout ça xD)

 

[kaozuin]

Re bonjour,

Je réouvre le sujet car j'ai un petit souci avec cette macro !

Je souhaiterais que cette dernière enchaine les conversion j'ai bien les bons lien / info mais on dirait que la conversion est ''sautée'' !

Avez vous une idée d'où cela peut il venir ?

 

[job75]

Bonjour kaozuin,

Bis repetita :

Vous n'avez pas de réponse parce que ce n'est pas clair.

Vous remarquerez que moi j'ai joint le fichier Excel et le document Word concernés.

Alors joignez le ou les documents Word que vous voulez exporter en PDF (il faut les zipper).

A+

 

[kaozuin]

Ha pardon je n'avais pas vue cette ligne 🙂

Ci joint un exemple :

il faut d'abord aller dans l'éditeur marco / Feuille 1 et modifier manuellement le chemin du dossier à analyser
puis lancer l'analyse (ce qui exterait les infos)
puis lancer la macro du module 1 ( ta macro que j'ai un peu modifier).

 

[job75]

J'ai supprimé votre code, bien trop compliqué et en plus inutile, voici ma macro complétée :

Sub PDF_Word()
Dim chemin$, doc$, Wapp As Object, pdf$
chemin = ThisWorkbook.Path & "\" 'à adapter
doc = Dir(chemin & "*.docx") '1er document du dossier
Application.DisplayAlerts = False 'si un document Word est ouvert
On Error Resume Next
Set Wapp = GetObject(, "Word.Application")
If Wapp Is Nothing Then Set Wapp = CreateObject("Word.Application")
While doc <> ""
    pdf = Left(doc, InStrRev(doc, ".") - 1) & ".pdf"
    With Wapp.Documents.Open(chemin & doc)
        .ExportAsFixedFormat chemin & pdf, ExportFormat:=17 '17 => wdExportFormatPDF
        .Close False
    End With
    doc = Dir 'document suivant du dossier
Wend
If Wapp.Documents.Count = 0 Then Wapp.Quit
End Sub

 

[kaozuin]

Nickel !!!!

Merci beaucoup de ton aide et encore désolé pour les explications pas trop clair !

 

[jui42]

Bonjour @job75 , @kaozuin,

Je rouvre le fil car j'aimerais savoir si il est possible de faire la même chose dans le chemin inverse. c-a-d convertir en word, un dossier contenant des fichiers pdf.

Cdt ,

 

[kiki29]

Salut, via Acrobat ( pas le Reader )
Sauvegarder un fichier PDF au format TEXTE via VBA Excel avec "com.adobe.acrobat.doc" ou "com.adobe.acrobat.docx"

Option Explicit

Sub PDF2Word()
Dim Acro As Object
Dim AVdoc As Object
Dim PDDoc As Object
Dim JSO As Object
Dim sSource As String
Dim sDest As String
Dim sExt As String
Dim Deb As Currency

    Deb = Timer
    Application.StatusBar = ""
   
    sExt = "doc"
    sSource = ThisWorkbook.Path & "\" & "Test.pdf"
    sDest = Replace(sSource, ".pdf", "." & sExt, 1)

    Set Acro = CreateObject("AcroExch.App")
    Set AVdoc = CreateObject("AcroExch.AVDoc")

    If AVdoc.Open(sSource, vbNull) = True Then
        Set PDDoc = AVdoc.GetPDDoc
        Set JSO = PDDoc.GetJSObject
        JSO.SaveAs sDest, "com.adobe.acrobat." & sExt
    End If

    AVdoc.Close False

    Acro.Exit
    Set AVdoc = Nothing
    Set Acro = Nothing
   
    Application.StatusBar = "Terminé : " & Format(Timer - Deb, "0.000 s")
End Sub

 

[job75]

Bonjour jui42, kiki29,

Il existe sur le web des logiciels de conversion gratuits.

A+

 

[kiki29]

Re, exact si tu veux divulguer tes données à tout le monde.

 

[jui42]

Re,
Oui @job75 mais j'ai plusieurs fichiers pdf à convertir.

@kiki29, j'ai essayé le code mais il m'indique que "l'interface n'est pas prise en charge"