[Résolu]Les dates qui se suivent mais sans samedis et sans dimanches

[Thibault98]

Bonsoir,

Ci-joint un classeur pour vous expliquer mon problème, je voudrais à partir d'une date de départ faire suivent les jours sauf celui qui est le jour de fermeture qui est choisi dans une liste pour l'indiquer à Excel, de même il ne faut jamais de samedis ni de dimanches.

ça fonctionne presque sauf lorsque je choisi le vendredi il m'affiche alors le samedi alors qu'il devrait renvoyer le lundi.

Merci.

Thibault.

 

[hbenalia]

Re : Les dates qui se suivent mais sans samedis et sans dimanches

Bonjour à tous,

Une idée en A6 (puis recopiée vers le bas) avec la formule:

=SERIE.JOUR.OUVRE(A5;1;$H$4:$H$6)+(JOURSEM(SERIE.JOUR.OUVRE(A5;1;$H$4:$H$6);2)=SI($C$3=5;6;$C$3))

Cordialement

 

[Jocelyn]

Re : Les dates qui se suivent mais sans samedis et sans dimanches

Bonjour le Forum,
Bonjour thibault98,

un essai mais attention réalisé sur excel 2010 je ne sais donc pas si cette formule fonctionne sous 2007 :

la formule est :

=SERIE.JOUR.OUVRE.INTL(C5;1;"0000111";$H$4:$H$6)

dans cette partie "0000111" on met normalement un chiffre de 1 a 16 suivant le type de week-end que l'on désire

par exemple 1 samedi et dimanche, 2 dimanche et lundi etc ... et a partir de 12 week-end d'une journée soit 12 uniquement le lundi, 13 uniquement le mardi etc .....

par contre montré sous la forme "0000111" ici on a 7 valeur une par jour de la semaine le premier 0 représente le lundi les 0 ne sont pas enlevés les 1 oui ici on enlève donc le vendredi, le samedi et le dimanche.

si nous voulions enlever le mardi, le samedi et le dimanche il faudrait mettre "0100011"

Voila regarde le fichier et dis nous

Cordialement

EDIT : Bonjour hbenalia, désolé pour la colision

 

[Thibault98]

Re : Les dates qui se suivent mais sans samedis et sans dimanches

Merci hbenalia, ça ne fonctionne pas car le vendredi apparait alors qu'il est déclaré comme jour de fermeture.

Merci Jocelin, Excel 2007 ne veut pas des formules de 2010.

Bonne soirée et encore merci pour votre aide.
Thibault

 

[Jocelyn]

Re : Les dates qui se suivent mais sans samedis et sans dimanches

re,

désolé pour la formule qui ne fonctionne pas sous 2007 en voila une autre qui devrait je crois

=SERIE.JOUR.OUVRE(A5;1;$H$4:$H$6)+(SI(JOURSEM(SERIE.JOUR.OUVRE(A5;1;$H$4:$H$6);2)=$C$3;3;0))

 

[Thibault98]

Re : Les dates qui se suivent mais sans samedis et sans dimanches

C'est presque ça, j'ai deux lundis 14 janvier 2013, il y en a un de trop.

Merci

 

[Jocelyn]

Re : Les dates qui se suivent mais sans samedis et sans dimanches

re,

hum hum supprenant pas moi regardes le fichier en colonne A

 

[Thibault98]

Re : Les dates qui se suivent mais sans samedis et sans dimanches

Oui effectivement tu as raison, je vais regarder ou j'ai fais une erreur.

 

[Thibault98]

Re : Les dates qui se suivent mais sans samedis et sans dimanches

En fait ça ne va pas si on change le jour dans la liste.

 

[Jocelyn]

Re : Les dates qui se suivent mais sans samedis et sans dimanches

re,

j'ai encore changé la formule pour tenir compte des fériés, car avec la formule précédente en testant un jour férié par exemple le 14/01/2013 le fameux lundi ce lundi n'était pas supprimé.

nouvelle formule

=SERIE.JOUR.OUVRE(A5;1;$H$4:$H$6)+(SI(JOURSEM(SERIE.JOUR.OUVRE(A5;1;$H$4:$H$6);2)=$C$3;3;0))+SI(NB.SI($H$4:$H$6;SERIE.JOUR.OUVRE(A5;1;$H$4:$H$6)+3)=1;1;0)

voila j'espère avoir fait le tour de tout.

regarde le fichier colonne A ancienne formule, colonne D nouvelle formule avec une date férié au 14/01/2013

 

[Jocelyn]

Re : Les dates qui se suivent mais sans samedis et sans dimanches

re,

nouvelle formule qui integre les congés et le changement de jour de fermeture. , enfin je crois mais bon la formule devient un peu longue

=SERIE.JOUR.OUVRE(A5;1;$H$4:$H$6)+(SI(JOURSEM(SERIE.JOUR.OUVRE(A5;1;$H$4:$H$6);2)=$C$3;CHOISIR(EQUIV(JOURSEM(SERIE.JOUR.OUVRE(A5;1;$H$4:$H$6);2);{1;2;3;4;5;6;7};0);1;1;1;1;3;0;0);0))+SI(NB.SI($H$4:$H$6;SERIE.JOUR.OUVRE(A5;1;$H$4:$H$6)+SI(JOURSEM(SERIE.JOUR.OUVRE(A5;1;$H$4:$H$6);2)=$C$3;CHOISIR(EQUIV(JOURSEM(SERIE.JOUR.OUVRE(A5;1;$H$4:$H$6);2);{1;2;3;4;5;6;7};0);1;1;1;1;3;0;0);0))=1;1;0)

regardes le fichier

 

[Thibault98]

Re : Les dates qui se suivent mais sans samedis et sans dimanches

Merci Jocelyn, c'est parfait.

Bonne soirée.