Microsoft 365 [Résolu] Bouton nommé par exemple C qui va chercher les mots commençants par C dans une colonne

[Marboi]

Bonjour à tous, j'ai fait il y a quelques années sous excel 97 le fichier joint. J'ai maintenant un problème de compatibilité avec excel 365 office mondo 2016 (voir la capture d'écran). J'ai modifié le titre du module "Filtre" par "Lettre" mais je ne me rappelle plus du tout comment j'ai pu affecter un nom alphabétique à chaque bouton. Quand je copie un des boutons "C" par exemple dans un autre fichier avec le module renommé, cela fonctionne.
Je voudrai pouvoir réitérer cette possibilité de création de bouton avec recherche alphabétique, dans un nouveau fichier mais j'en suis incapable.
J'ai modifié le nom du module "Filtre" par "Lettre" et les boutons jusqu'au bouton "La".
Pouvez-vous m'aider ? Merci par avance.

 

[mapomme]

Bonjour @Marboi ,

• sélectionner l'ensemble des boutons
• puis cliquer-droit sur un des boutons sélectionnés
• choisir le sous-menu "Affecter une macro..."

Puis dans la fenêtre qui se sera ouverte :

• choisir pour le champ "Macros dans :" dans la liste déroulante la valeur "Ce classeur"
• choisir la macro "Lettre" dans la liste des macros disponibles
• cliquez sur OK

nota : il faut bien sûr que la macro "Lettre" soit dans le classeur concerné (celui des boutons)

 

[Marboi]

Bonjour, merci de votre réponse, mais ça je sais, c'est ce que j'ai indiqué dans le sujet. Ce que je ne sais plus faire, c'est créer un bouton avec par exemple A qui va me chercher les mots commençants par A dans une colonne. Avant, je crois que c'était grâce à la fonction "Fonction" du bouton que l'on pouvait indiqué BoutonA, BoutonB etc, mais je n'en suis pas sûr et cela n'existe pas dans 365, enfin je crois.

 

[sylvanu]

Bonjour Marboi, Mapomme,
En lançant cette macro on réaffecte à tous les boutons dont le nom commence par "Bouton" la macro Lettre :

Sub AffecterMacro()
For Each Sh In ActiveSheet.Shapes
    If Left(Sh.Name, 6) = "Bouton" Then
        ActiveSheet.Shapes(Sh.Name).OnAction = "Lettre"
    End If
Next Sh
End Sub

 

[sylvanu]

J'ai l'impression de ne pas tout avoir compris.
En PJ on filtre par appui sur un bouton, comme ça :

C'est ça que vous recherchez ?

 

[Marboi]

Bonjour Sylvanu et merci de votre réponse, en fait ce que je cherche c'est "Je voudrai pouvoir réitérer cette possibilité de création de bouton avec recherche alphabétique, dans un nouveau fichier mais j'en suis incapable" qui soit compatible xlsx ou xlsm.
J'ai essayé de créé un bouton avec la macro lettre, mais rien ne se passe car le bouton ne porte pas la mention "BoutonA" comme dans la capture d'écran.
Si je copie chaque bouton avec sa lettre correspondante dans un nouveau fichier xlsx, ça fonctionne, mais je voulais absolument pouvoir le refaire par création.

 

[Marboi]

Oups, Sylvanu, répondu trop tôt, c'est exactement ça que je recherche

 

[Gégé-45550]

Bonjour à tous, j'ai fait il y a quelques années sous excel 97 le fichier joint. J'ai maintenant un problème de compatibilité avec excel 365 office mondo 2016 (voir la capture d'écran). J'ai modifié le titre du module "Filtre" par "Lettre" mais je ne me rappelle plus du tout comment j'ai pu affecter un nom alphabétique à chaque bouton. Quand je copie un des boutons "C" par exemple dans un autre fichier avec le module renommé, cela fonctionne.
Je voudrai pouvoir réitérer cette possibilité de création de bouton avec recherche alphabétique, dans un nouveau fichier mais j'en suis incapable.
J'ai modifié le nom du module "Filtre" par "Lettre" et les boutons jusqu'au bouton "La".
Pouvez-vous m'aider ? Merci par avance.

Bonjour,
Une proposition en PJ utilisant la puissance des tableaux structurés.
Cordialement,

 

[Marboi]

Bonjour, merci Gégé, effectivement ça fonctionne pas mal, j'avais essayé mais les macros ne fonctionnaient pas (blocage). Après déblocage ça fonctionne bien. Et je fais comment si je veux faire la même chose dans un autre dossier ?

Le problème est que ça utilise toujours mes fameux boutons nommés. Si j'en créé un nouveau et que je lui attribue la lettre F par exemple, rien ne se passe.

J'ai du mal m'exprimer, ce que je voudrai, c'est faire la même chose dans d'autres fichiers mais en créant les boutons, pas en les copiant/collant qui permettraient d'aller directement sur la 1ère lettre concernée dans la liste, comme sur le fichier joint au début.

 

[mapomme]

Re à tous ,

La petite version de ma pomme.

J'ai ajouté un bouton "Trier" qui trie la plage des DVD selon les titres des DVD. Cette procédure de tri en profite pour mettre les bordures à la plage. Ce tri est utile si on ajoute, supprime ou modifie des titres des DVD.

Pour les autres boutons, le nom des boutons est indifférent et n'a aucune signification.
Ce qui compte, c'est le texte du bouton. Quand on clique sur un bouton, on recherche le titre du premier DVD qui commence par le texte du bouton. Si aucun titre ne répond à cette condition, on revient à la première ligne des DVD.

La meilleure méthode est celle du tableau structuré avec filtrage mais elle a déjà été déjà prise .

Le code est dans module 1 :

Sub lettre()
Dim modele$, ligne&
   With ActiveSheet
      modele = .Shapes(Application.Caller).DrawingObject.Caption & "*"
      ligne = 3 + Application.IfError(Application.Match(modele, .Range("b4:b" & Rows.Count), 0), 0)
      If ligne = 3 Then ligne = 4: Beep
      ActiveWindow.ScrollRow = ligne
      ActiveWindow.ScrollColumn = 1
   End With
End Sub

Sub trier()
Dim der&
   With ActiveSheet
      If .FilterMode Then .ShowAllData
      der = .Cells(Rows.Count, "b").End(xlUp).Row
      With .Range("a3:f" & der)
         .Sort key1:=.Range("b3"), order1:=xlAscending, MatchCase:=False, Header:=xlYes
         .Borders.LineStyle = xlContinuous
      End With
      .Range(.Cells(der + 1, "a"), .Cells(Rows.Count, "f")).Borders.LineStyle = xlLineStyleNone
      .Range("a4").Select
   End With
End Sub

 

[sylvanu]

Re,

J'ai du mal m'exprimer, ce que je voudrai, c'est faire la même chose dans d'autres fichiers mais en créant les boutons, pas en les copiant/collant

Si j'ai bien compris ...
Plutôt que de vouloir vous compliquer la vie en cherchant le nom du bouton, il est possible d'extraire le texte du bouton, ce qui serait plus simple. Vous n'auriez pas à vous préoccuper du nom du bouton.
Par ex vous créez un bouton et dedans vous écrivez "C", en lançant cette macro vous récupérer le titre "C".

Sub Lettre()
    Titre = ActiveSheet.Shapes(Application.Caller).TextFrame.Characters.Text
    [J2] = Titre
    If Titre = "Tout Voir" Then
        ActiveSheet.Range("$A$3:$F$274").AutoFilter Field:=2
    Else
        ActiveSheet.Range("$A$3:$F$1000").AutoFilter Field:=2, Criteria1:="=" & Titre & "*", Operator:=xlAnd
    End If
End Sub

En Pj vous appuyez sur un bouton et vous récupérer le texte du bouton en J2.
( C'est juste un exemple bien sur )

 

[Marboi]

Bonjour Mapomme, Sylvanu, c'est exactement ce que je cherchai, avec l'ancienne macro Lettre, le bouton que je créai en lui indiquant une lettre, n'était pas affecté par la macro et donc rien ne se passait, aucune recherche. Je pensais que c'était à cause du bouton qui était nommé par ladite lettre "BoutonC" pour la lettre C (par exemple) dans mon ancien fichier. Merci beaucoup à vous deux pour votre patience, bonne journée. Merci encore.

 

[sylvanu]

Bonjour,
On a eu du mal à cerner votre besoin.
Pour affecter à tous vos boutons, il suffit de lancer cette macro que j'avais incluse dans mes post précédent :

Sub AffecterMacro()
For Each Sh In ActiveSheet.Shapes
    If Left(Sh.Name, 6) = "Bouton" Then
        ActiveSheet.Shapes(Sh.Name).OnAction = "Lettre"
    End If
Next Sh
End Sub

 

[Marboi]

Merci Sylvanu, je pense que je me suis, effectivement, mal exprimé. Je ne trouvai pas le terme exact : bouton"nommé par une lettre"= recherche dans une liste. Je pense que cela aurait était plus simple.