(résolu) Ajouter commentaire en double cliquant un texbox d'un userform

[Cougar]

Bonjour,

Est-il possible d'ajouter un commentaire à une cellule en double-cliquant un textbox d'un userform ?

Je m'explique : si je double-clique sur le textbox1, un commentaire sera créer dans la colonne K, si je double-clique sur le textbox5, le commentaire sera dans la colonne O, etc.

Un fichier est joint.

Merci

 

[D.D.]

Hello,
Le commentaire devra écrire quoi et dans la cellule impactée par le textbox ?
Sinon pour créer un commentaire, c'est par exemple:
ActiveCell.AddComment
With ActiveCell.Comment
.Visible = True
.Shape.Shadow.Visible = msoFalse
.Text Text:="DD: " & Now & Chr(10)
.Shape.TextFrame.Characters.Font.Name = "Tahoma"
.Shape.TextFrame.Characters.Font.Size = 10
.Shape.TextFrame.Characters.Font.Color = 0 'caractères
.Shape.Line.ForeColor.RGB = RGB(255, 0, 0) 'Rouge
.Shape.Line.Weight = 0.25
.Shape.Fill.Visible = msoTrue
.Shape.Fill.ForeColor.RGB = RGB(255, 255, 204) 'Jaune Clair
.Shape.TextFrame.Characters(1, 23).Font.Color = RGB(0, 0, 255) 'Bleu
.Shape.TextFrame.Characters(1, 23).Font.Size = 7
.Shape.TextFrame.Characters(1, 23).Font.Italic = True
End With

 

[Robert]

Bonjour Cougar, bonjour le forum,

C'est tellement vague que j'ai envie de sortir ma planche... Un commentaire ? lequel ? À une cellule ? Laquelle. Essaie de te débrouiller en adaptant cela :

Private Sub TextBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
Dim O As Worksheet

Set O = Worksheets("2018-2019")
With O.Cells(7, "K")
  .ClearComments
  .AddComment
  .Comment.Text Text:="ton commentaire ici"
  .Comment.Visible = False
End With
End Sub

 

[job75]

Bonjour Cougar, D.D, Robert,

Le double-clic sur l'une des 52 (!!!) TextBox n'est certainement pas une bonne idée.

Il vaut mieux une TextBox spécifique pour le texte du commentaire et un Label "OK" avec ce code :

Private Sub Label121_Click() 'OK
If TextBox53 = "" Then TextBox53.SetFocus: Exit Sub
Dim c As Range
Me.Hide
On Error Resume Next
Set c = Application.InputBox("Sélectionnez la cellule où vous voulez entrer un commentaire...", "Commentaire", Type:=8)
If c Is Nothing Then UserForm1.Show 0: Exit Sub
c(1).ClearComments
c(1).AddComment TextBox53.Text
Unload Me
End Sub

Pour pouvoir accéder à une cellule de la feuille l'UserForm est ouvert en non modal.

Fichier joint.

A+

 

[Cougar]

Bonjour le fil,

Pas toujours évident d'exprimer notre pensée, je m'en excuse.

Je crois que le code de job75 sera la plus simple pour mes besoin.

Merci de votre aide.