report de données de feuille a feuille sur meme classeur par vba

[karine62]

bonjour
toute nouvellle sur le forum
donc bonjour a tous
j'ai besoin d'aide pour recopier une plage de donnée sur une autre feuille du meme classeur par vba
voici mon code pour le moment

Sub Macro2()
'
' Macro2 Macro
'

'plage de cellule a copier
Sheets("Reception").Select
Range("C10:AB11").Select
Selection.Copy

'recopier sur la feuille uk order mais devant la bonne date
Sheets("UK Order Injection").Select
Range("B734").Select
ActiveSheet.Paste
Application.CutCopyMode = False

'mise en page
With Selection.Font
.Name = "Calibri"
.Size = 11
.Strikethrough = False
.Superscript = False
.Subscript = False
.OutlineFont = False
.Shadow = False
.Underline = xlUnderlineStyleNone
.ThemeColor = xlThemeColorLight1
.TintAndShade = 0
.ThemeFont = xlThemeFontMinor
End With
Range("O736").Select
End Sub


comment faire pour que les données se place bien devant la bonne date ? sur la feuille UK Order Injection

merci pour votre aide
je vous joint le fichier
merci karine

 

[Staple1600]

Re : report de données de feuille a feuille sur meme classeur par vba

Bonsoir à tous

karine62 [Bienvenue sur le forum]
Voici un début de piste
(la présence de liaisons me pose problème lors de la recopie)

Sub test_quasi_OK()
Dim jourCopie As Date, Rng As Range
jourCopie = CLng(CDate(Format(Sheets("Reception").Cells(Rows.Count, "b").End(xlUp), "dd/mm/yyyy")))
With Sheets("UK Order Injection").Range("A:A")
        Set Rng = .Find(What:=jourCopie, _
        After:=.Cells(.Cells.Count), _
        LookIn:=xlFormulas, _
        LookAt:=xlWhole, _
        SearchOrder:=xlByRows, _
        SearchDirection:=xlNext, _
        MatchCase:=False)
        If Not Rng Is Nothing Then
        Sheets("Reception").Range("C7:AB8").Copy Rng.Offset(, 1)
        Else
        MsgBox "Date non trouvée"
        End If
End With
End Sub

PS: j'ai testé sur ton classeur, je recopie bien au bon endroit mais reste le souci de l'apparition de la fenêtre Mettre à jour les valeurs

 

[karine62]

Re : report de données de feuille a feuille sur meme classeur par vba

Bonjour Staple1600,le forum
superbe ce code sur mesure parfait
peut on copier que les valeurs pour ne pas avoirs cette liaison avec :

Selection.PasteSpecial Paste:=xlPasteValues

est ce possible ?
Karine

 

[Pierrot93]

Re : report de données de feuille a feuille sur meme classeur par vba

Bonjour,

modifie peut être comme suit cette partie :

If Not Rng Is Nothing Then
        Sheets("Reception").Range("C7:AB8").Copy 
           Rng.Offset(, 1).PasteSpecial Paste:=xlPasteValues
        Else
        MsgBox "Date non trouvée"
        End If

bonne journée
@+

 

[karine62]

Re : report de données de feuille a feuille sur meme classeur par vba

Bonjour Pierrot
merci de ton aide
mais j'ai un message d'erreur a cause des cellule fusionnées
une autre idée
car sinon le code de staple fonctionne bien il suffit juste de trouver l'astuce
karine

 

[Pierrot93]

Re : report de données de feuille a feuille sur meme classeur par vba

Re,

mais j'ai un message d'erreur a cause des cellule fusionnées

oui pas top en vba les cellules fusionnées, préférable de les éviter par exemple en centrant sur plusieurs colonnes...

 

[Pierrot93]

Re : report de données de feuille a feuille sur meme classeur par vba

Re,

essaye ceci, non testé :

If Not Rng Is Nothing Then
    Sheets("Reception").Range("C7:AB8").Copy Rng.Offset(, 1)
    Rng.Offset(, 1).Resize(2, 26).Value = Rng.Offset(, 1).Resize(2, 26).Value
Else
    MsgBox "Date non trouvée"
End If

 

[karine62]

Re : report de données de feuille a feuille sur meme classeur par vba

bonjour pierrot,staple,le fil
une bizarrerie m’échappe tout fonctionner nickel
et quand je l'adapte a mon fichier il m'affiche des "diesesREF"
j'ai due faire une bêtise
une idée svp
karine

 

[Pierrot93]

Re : report de données de feuille a feuille sur meme classeur par vba

Re,

essaye peut être avec ceci :

If Not Rng Is Nothing Then
    Rng.Offset(, 1).Resize(2, 26).Value = Sheets("Reception").Range("C7:AB8").value
Else
    MsgBox "Date non trouvée"
End If

 

[karine62]

Re : report de données de feuille a feuille sur meme classeur par vba

oui parfait pierrot un grand merci
karine
au plaisir