Repartir par mois les jours ouvrables entre deux dates

[momo38]

Bonjour,
J'ai réussi à calculer le nombre de jours ouvrables (lundi au samedi)
entre deux dates (en excluant les jours fériés avec création d'une table)

exemple :
Début Fin Jours ouvrables
08/01/2008 01/05/2008 96
(voir fichier joint)

Comment je peux répartir avec une formule ces 96 jours ouvrables par mois :
JANVIER 2008 : .....
FEVRIER 2008 : ....
MARS 2008 : ....
AVRIL 2008 : ....
MAI 2008 : ....

j'ai joint le fichier pour le tester
Je vous remercie

 

[ROGER2327]

Re : Repartir par mois les jours ouvrables entre deux dates

Bonsoir momo38

Essayez ceci :

=MAX(0;NB.JOURS.OUVRES(MAX(E$1;$A2);MIN(FIN.MOIS(E$1;0);$B2);FERIE))

(Il faudra étendre la plage de jours fériés pour couvrir la période.)
​

ROGER2327
#4837

Dimanche 8 Décervelage 138 (Saint Bordue, Capitaine, ST)
16 Nivôse An CCXIX
2011-W01-3T01:00:58Z

 

[momo38]

Re : Repartir par mois les jours ouvrables entre deux dates

Bonjour Roger,
Tout d'abord je te remercie pour cette proposition.
Actuellement, pour déterminer mon nombre de jours ouvrables et non ouvrés entre deux dates c'est à dire du lundi au samedi:
exemple du 11/01/2006 au 01/05/2006, j'utilise la formule suivante :
=SOMMEPROD((JOURSEM(LIGNE(INDIRECT(A4&":"&B4)))>1) *(NB.SI(FERIE;LIGNE(INDIRECT(A4&":"&B4)))=0))
Le chiffre que j'obtiens correspond au nombre de jours ouvrables (exclusion du dimanche et jours fériés) sur cette période.
Or je souhaite avoir une ventilation du nombre de jours ouvrables pour les mois concernés , cad :
janvier = 18 (cad du 11/01/2006 au 31/01/2006 hors dimanche et jours fériés
février = 24
.........
Mai = 0 (1er mai étant férié)
Des fois si tu as la possibilité d'expérimenter ma demande sur le fichier joint j'en serais ravi
A bientôt

 

[exene]

Re : Repartir par mois les jours ouvrables entre deux dates

Bonsoir,

En utilisant la même formule mais en faisant référence à l'année et au mois.

=SI(NB($B2:$C2)<2;"";SOMMEPROD((ANNEE(LIGNE(INDIRECT($B2&":"&$C2)))=ANNEE(E$1))*(MOIS(LIGNE(INDIRECT($B2&":"&$C2)))=MOIS(E$1))*(JOURSEM(LIGNE(INDIRECT($B2&":"&$C2)))>1)*(NB.SI(feries;LIGNE(INDIRECT($B2&":"&$C2)))=0)))

A adapter à ton fichier

@+

 

[ROGER2327]

Re : Repartir par mois les jours ouvrables entre deux dates

Re…

La formule que j'ai proposée ne fait pas le boulot : elle ne compte pas les samedis (je n'avais pas prêté attention à la distinction entre jours ouvrés et jours ouvrables).
La formule d'exene semble être convenable. Voyez le classeur joint pour la comparaison des deux propositions.​

ROGER2327
#4842

Lundi 9 Décervelage 138 (Dormition de Jacques Vaché, Interprète, SQ)
17 Nivôse An CCXIX
2011-W01-4T00:57:52Z