Microsoft 365 renvoyer dans une cellule la valeur d'une cellule, alignée en colonne avec la première/dernière valeur d'une matrice en ligne.

sylvanu

XLDnaute Barbatruc

Supporter XLD

• 3 Mars 2020

• #2

Bonsoir Aurige,
Une PJ à tester. Ca a l'air de marcher.🙂
Formules en E4:F4 :

VB:

Date de début =SIERREUR(INDEX($G$3:$O$3;MIN(SIERREUR(EQUIV(1;G4:O4;0);9^9);SIERREUR(EQUIV(2;G4:O4;0);9^9)));"")
Date de Fin=SIERREUR(INDEX($G$3:$O$3;MAX(SIERREUR(EQUIV(1;G4:O4;1);0);SIERREUR(EQUIV(2;G4:O4;1);0)));"")

 

Pièces jointes

• calendrier.xlsx

  16.5 KB · Affichages: 1

Vote positif 0 Vote négatif

djidji59430

XLDnaute Barbatruc

• 3 Mars 2020

• #3

Bonjour à tous,

A peu pres la meme ...
{=MIN(SI($G4:$O4;$G$3:$O$3))}
{=Max(SI($G4:$O4;$G$3:$O$3))}
en matricielle
format cellule personalisée
jj-mmm;;


Crdlmt

 

Vote positif 0 Vote négatif

CISCO

XLDnaute Barbatruc

• 3 Mars 2020

• #4

Bonjour

Tu peux faire, dans E4, avec

Code:

SI(NB(G4:O4)=0;"";MIN(SI(G4:O4<>"";G$3:O$3)))

en matriciel (à valider avec Ctrl+maj+entrer), ou encore, avec

Code:

SI(NB(G4:O4)=0;"";INDEX(G$3:O$3;EQUIV(9^9;DECALER(G4:O4;;;;EQUIV(9^9;G4:O4;1)-(NB(G4:O4)-1)))))

celle-là, pas en matriciel, donc à valider simplement avec Entrer.

Et dans F4 :

Code:

SI(NB(G4:O4)<2;"";INDEX(G$3:O$3;EQUIV(9^9;G4:O4;1)))

toujours histoire d'éviter une formule matricielle.

@ plus

 

Dernière édition: 3 Mars 2020

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 3 Mars 2020

• #5

Bonsoir aurige et les autres,

Voyez le fichier joint :

- formule matricielle en E4 =SIERREUR(INDEX(G$3:O$3;EQUIV(VRAI;ESTNUM(G4:O4);0));"")

- formule normale en F4 =SIERREUR(INDEX(G$3:O$3;EQUIV(9^9;G4:O4));"")

Edit : plus simple =SIERREUR(RECHERCHE(9^9;G4:O4;G$3:O$3);"")

A+

 

Pièces jointes

• calendrier(1).xlsx

  12.3 KB · Affichages: 5

Dernière édition: 3 Mars 2020

Vote positif 0 Vote négatif

A

aurige

XLDnaute Nouveau

• 4 Mars 2020

• #6

merci à tous ! @sylvanu @djidji59430 @CISCO @job75 !

et si la valeur est du texte j'ai la solution (je m'épate moi-même):
début : {=SIERREUR(INDEX(G$3:O$3;EQUIV(VRAI;ESTTEXTE(G10:O10);0));"")}
fin : {=SIERREUR(RECHERCHE("zzz";G10:O10;G$3:O$3);"")}

et pour que ça fonctionne pour les deux types de valeurs validez vous mon idée ?

j'ai essayé
(pour date de début)
{=SIERREUR(MIN(INDEX(G$3:O$3;EQUIV(VRAI;ESTNUM(G11:O11);0));(INDEX(G$3:O$3;EQUIV(VRAI;ESTTEXTE(G11:O11);0))));"")}
(pour date de fin)
{=SIERREUR(MAX(RECHERCHE(9^9;G11:O11;G$3:O$3);(RECHERCHE("zzz";G11:O11;G$3:O$3)));"")}


encore mille mercis !

 

Dernière édition: 4 Mars 2020

Vote positif 0 Vote négatif

CISCO

XLDnaute Barbatruc

• 4 Mars 2020

• #7

Bonjour

Avec ESTTEXTE, cela fonctionne pour... du texte.

@ plus

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 4 Mars 2020

• #8

aurige à dit:

et pour que ça fonctionne pour les deux types de valeurs validez vous mon idée ?

Cliquez pour agrandir...

Pas du tout, voyez ce fichier (2) et les 2 formules matricielles en E4 et F4 :

Code:

=SIERREUR(INDEX(G$3:O$3;EQUIV(VRAI;G4:O4<>"";0));"")

=SIERREUR(RECHERCHE("zzz";SI(G4:O4<>"";""&G4:O4);G$3:O$3);"")

 

Pièces jointes

• calendrier(2).xlsx

  12.8 KB · Affichages: 7

Vote positif 0 Vote négatif

Solution

A

aurige

XLDnaute Nouveau

• 4 Mars 2020

• #9

CISCO à dit:

Bonjour

Avec ESTTEXTE, cela fonctionne pour... du texte.

@ plus

Cliquez pour agrandir...

en effet, c'était une partie du but... si au lieu de mettre "1" session je mettais à terme l'info sur la session de "georges" le formateur 🙂

 

Vote positif 0 Vote négatif

A

aurige

XLDnaute Nouveau

• 4 Mars 2020

• #10

job75 à dit:

Pas du tout, voyez ce fichier (2) et les 2 formules matricielles en E4 et F4 :

Cliquez pour agrandir...

merci beaucoup !

 

Vote positif 0 Vote négatif