XL 2016 Remplissage automatique des heures depuis un onglet vers un autre

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
     Dim Heure
     Dim LO As ListObject, Wsh_Salarié As Worksheet, Lgn_Cible
   
     Heure = Time   'Heure de pointage
     If Target.ListObject Is Nothing Then Exit Sub  'Double clic en dehors du tableau
     If Intersect(Target, Me.[_Plage_Pointage]) Is Nothing Then Exit Sub 'Double clic en dehors de la plage de pointage
     Cancel = True    'Annuler l'action du double clic
   
     Set LO = Target.ListObject
     Nom_Feuille = Intersect(LO.ListColumns(1).Range, Target.EntireRow).Value   'Nom de la feuille salarié dans la colonne 1 du tableau
     On Error Resume Next
     Set Wsh_Salarié = Worksheets(Nom_Feuille)
     On Error GoTo 0
     If Wsh_Salarié Is Nothing Then   'Erreur sur le nom de la feuille salarié
          MsgBox "La feuille " & Nom_Feuille & " n'existe pas !"
          Exit Sub
     End If
   
     Lgn_Cible = Application.Match(CLng(Date), Wsh_Salarié.[A:A], 0)  'N° de la ligne Cible
     If IsError(Lgn_Cible) Then  'Date non trouvée
          MsgBox "Date du jour non trouvée dans la feuille " & Nom_Feuille
          Exit Sub
     End If
     Wsh_Salarié.Cells(Lgn_Cible, Target.Column).Value = Heure  'Enregistrement de l'heure de pointage dans la feuille Salarié
   
     MsgBox Title:="POINTAGE " & Nom_Feuille, Prompt:="Heure " & LO.HeaderRowRange.Cells(Target.Column) & " " & Heure & vbCrLf & "Enregistrée"
End Sub

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
     Dim Jour_Préc As Boolean
     Dim Heure
     Dim LO As ListObject, Wsh_Salarié As Worksheet, Lgn_Cible, Col_Cible As Integer
   
     Heure = Time   'Heure de pointage
     If Target.ListObject Is Nothing Then Exit Sub  'Double clic en dehors du tableau
     If Intersect(Target, Me.[_Plage_Pointage]) Is Nothing Then Exit Sub 'Double clic en dehors de la plage de pointage
     Cancel = True    'Annuler l'action du double clic
   
     Set LO = Target.ListObject
     Nom_Feuille = Intersect(LO.ListColumns(1).Range, Target.EntireRow).Value   'Nom de la feuille salarié dans la colonne 1 du tableau
     On Error Resume Next
     Set Wsh_Salarié = Worksheets(Nom_Feuille)
     On Error GoTo 0
     If Wsh_Salarié Is Nothing Then   'Erreur sur le nom de la feuille salarié
          MsgBox "La feuille " & Nom_Feuille & " n'existe pas !"
          Exit Sub
     End If
     Col_Cible = Target.Column
     Lgn_Cible = Application.Match(CLng(Date), Wsh_Salarié.[A:A], 0)  'N° de la ligne Cible
     If IsError(Lgn_Cible) Then  'Date non trouvée
          MsgBox "Date du jour non trouvée dans la feuille " & Nom_Feuille
          Exit Sub
     End If
   
     'Vérifier que le pointage de Sortie et de Pause se place sur la même ligne que le pointage d'Arrivée :
          'Col_Cible > 2                                    : C'est un pointage Sortie ou Pause
          'Wsh_Salarié.Cells(Lgn_Cible - 1, 2) <> ""        : Le pointage d'Arrivée Veille effectué
          'Wsh_Salarié.Cells(Lgn_Cible - 1, Col_Cible) = "" : Le pointage de Sortie ou Pause de la veille non effectué
     Jour_Préc = (Col_Cible > 2) * (Wsh_Salarié.Cells(Lgn_Cible - 1, 2) <> "") * (Wsh_Salarié.Cells(Lgn_Cible - 1, Col_Cible) = "")
     Lgn_Cible = Lgn_Cible - Abs(JourPrec)
   
     Wsh_Salarié.Cells(Lgn_Cible, Col_Cible).Value = Heure  'Enregistrement de l'heure de pointage dans la feuille Salarié
     Target.Value = Heure
   
     MsgBox Title:="POINTAGE " & Nom_Feuille, Prompt:="Heure " & LO.HeaderRowRange.Cells(Target.Column) & " " & Heure & vbCrLf & "Enregistrée"
End Sub