XL 2019 récupérer une donnée d'un fichier csv pour le copier vers un autre

Créer une discussion
Répondre

Boostez vos compétences Excel avec notre communauté !

Rejoignez Excel Downloads, le rendez-vous des passionnés où l'entraide fait la force. Apprenez, échangez, progressez – et tout ça gratuitement ! 👉 Inscrivez-vous maintenant !

S'inscrire
H

Hutchy33

XLDnaute Nouveau
Bonjour,
Je souhaite faire un truc tout basique certainement pour certains mais j'ai pas le résultat voulu.
Je souhaite récupérer le contenu d'une cellule d'un fichier csv pour le copier vers une cellule sur un autre fichier.
J'ai utilisé ce code:
VB: 
Sub CopierCellulesVersAutreFichier()
    Dim CheminSource As String
    Dim CheminDestination As String
    Dim FeuilleSource As Worksheet
    Dim FeuilleDestination As Worksheet
   
    ' Spécifiez le chemin complet du fichier source
    CheminSource = "C:\Users\HArnaud\Desktop\écriture form\retour résultats éval QCM\test.csv" '
   
    ' Spécifiez le chemin complet du fichier de destination
    CheminDestination = "C:\Users\HArnaud\Desktop\écriture form\retour résultats éval QCM\test qcm v3.xlsm" '
   
    ' Ouvrez le fichier source
    Workbooks.Open Filename:=CheminSource
   
    ' Spécifiez la feuille source et la feuille de destination
    Set FeuilleSource = Workbooks("test.csv").Sheets("test")
    Set FeuilleDestination = Workbooks("test qcm v3.xlsm").Sheets("resultats")
   
    ' Copiez les cellules de la feuille source vers la feuille de destination
    FeuilleSource.Range("A2").Copy FeuilleDestination.Range("B4")
   
    ' Fermez le fichier source sans enregistrer les modifications
    Workbooks("test.csv").Close SaveChanges:=False
End Sub

Je ne veux récupérer que la valeur de la cellule A2 et pourtant ça me récupère les valeurs de toutes les cellules de la ligne pour venir les copier en B4 de l'autre fichier. Je ne pige pas pourquoi .
Je vous joins les fichiers si quelqu'un à un peu de temps à y accorder s'il vous plait.
Merci beaucoup.
 
Dernière modification par un modérateur:
Trier par date Trier par votes
Bonjour,

Pour les csv, je les ouvre comme un fichier txt. Ici, j'ai supprimé les paramètres de colonnes. Lorsque vous ne savez pas récupérer un csv, vous en faites une copie et vous changez l'extension par .txt. Vous enregistrez une macro et vous faites toutes les séquences pour ouvrir votre fichier .txt.

VB: 
Sub CopierCellulesVersAutreFichier()

    Dim CheminSource As String
    Dim CelluleDestination As Range
    
    
    Set CelluleDestination = Sheets("resultats").Range("B4")
    ' Spécifiez le chemin complet du fichier source
    CheminSource = ActiveWorkbook.Path & "\test.csv" '"C:\Users\HArnaud\Desktop\écriture form\retour résultats éval QCM\test.csv" '
  
    Workbooks.OpenText Filename:=CheminSource _
        , Origin:=65001, StartRow:=1, DataType:=xlDelimited, TextQualifier:= _
        xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, Semicolon:=True, _
        Comma:=True, Space:=False, Other:=False, TrailingMinusNumbers:=True
    
    ActiveSheet.Range("A2").Copy Destination:=CelluleDestination
    ActiveWorkbook.Close savechanges:=False
 
    Set CelluleDestination = Nothing
 
End Sub
 
Vote positif 0 Vote négatif
Bonsoir le fil

Une autre syntaxe possible
VB: 
Sub test_CSV()
Dim nomFIC$, vArr
'adapter le chemin & nom fichier
nomFIC = "C:\Users\STAPLE\Documents\tests\test.csv"
Set CSV_WB = Workbooks.Open(nomFIC, Format:=2, Local:=True)
vArr = CSV_WB.Worksheets(1).UsedRange: CSV_WB.Close (0)
'recopie en B4
ActiveSheet.Cells(4, 2) = vArr(2, 1) & " " & vArr(2, 2)
End Sub
Ici dans cet exemple, on copie dans la feuille active du classeur contenant la macro

Donc faire adaptation nécessaire avec le code initial du message#1
 
Vote positif 0 Vote négatif
Bonjour à tous,

Une autre solution :
VB: 
Sub CopierCSV()
Dim chemin$, x, texte$, v$
chemin = ThisWorkbook.Path & "\test.csv"
x = FreeFile
Open chemin For Input As #x 'ouverture en lecture séquentielle
Line Input #x, texte: texte = "" '1ère ligne
If Not EOF(x) Then Line Input #x, texte 'si 2ème ligne
Close #x
If texte <> "" Then v = Split(texte, ";")(0)
ActiveSheet.[B4] = v
End Sub
Le fichier CSV doit être dans le même dossier que le fichier de la macro.

A+
 
Vote positif 0 Vote négatif
job75 à dit:
Bonjour à tous,

Une autre solution :
VB: 
Sub CopierCSV()
Dim chemin$, x, texte$, v$
chemin = ThisWorkbook.Path & "\test.csv"
x = FreeFile
Open chemin For Input As #x 'ouverture en lecture séquentielle
Line Input #x, texte: texte = "" '1ère ligne
If Not EOF(x) Then Line Input #x, texte 'si 2ème ligne
Close #x
If texte <> "" Then v = Split(texte, ";")(0)
ActiveSheet.[B4] = v
End Sub
Le fichier CSV doit être dans le même dossier que le fichier de la macro.

A+
Cliquez pour agrandir...
Merci Job pour ton retour, je ne comprends pas tout ton code car je n'ai surement pas ton expérience en vba mais en tout cas ton code fonctionne.
Mais tout de même je ne parviens pas à l'intégrer dans mon code actuel, je m'explique.
A l'ouverture du fichier xlsm (que je m'appelle la matrice), j'ai une macro qui s'exécute demandant de venir choisir le fichier csv à analyser (ce sont des retours de résultats d'un test QCM).
Je parviens bien à récupérer les notes pour chaque items contenu dans le csv et les afficher sous forme d'icones valider ✅ ou non valide ❌.
J'ai besoin de récupérer les informations administratives du participant d'où ma précédente question, je ne parviens pas à intégrer ton code dans celui existant!
Voici le code qui s'exécute à l'ouverture de la matrice :

VB: 
Private Sub Workbook_Open()
'Dim fichier As Variant, tablo
ChDir ThisWorkbook.Path
fichier = Application.GetOpenFilename("Fichiers CSV(*.csv),*.csv") 'choix du fichier CSV
If fichier = False Then Exit Sub
Application.ScreenUpdating = False
Range("B12:C" & Rows.Count).ClearContents 'RAZ
Workbooks.Open fichier, Local:=True
tablo = ActiveWorkbook.Sheets(1).[M1:CJ2] 'plage modifiable

ActiveWorkbook.Close
[B12].Resize(UBound(tablo, 2), 2) = Application.Transpose(tablo)
End Sub

La variable fichier je les mise en déclaration public.
Je souhaiterai récupérer aussi les infos administratives (Nom, prénom Entreprise et Poste) pour les écrire sur le fichier final avec les notes (matrice).
J'espère être assez clair, pas évident d'expliquer.
Les fichiers joins pour test.
Merci beaucoup
 
Dernière modification par un modérateur:
Vote positif 0 Vote négatif
Cousinhub à dit:
Bonjour,
Juste pour information.
Est-ce que le fichier csv ne comporte qu'une ligne, ou à terme, comportera moult résultats d'évaluation d'un certain nombre de "candidats"?
Cliquez pour agrandir...
oui effectivement à terme il peut y avoir plusieurs lignes de participant avec leurs résultats, et la macro devra créer une feuille par candidat avec leurs résultats et leurs infos administrative en haut à gauche.
 
Vote positif 0 Vote négatif
Voici la macro adaptée à votre dernier fichier :
VB: 
Private Sub Workbook_Open()
Dim fichier As Variant, plage As Range, cc%, col%, x, n, a(), texte$, s, i&
ChDir ThisWorkbook.Path
fichier = Application.GetOpenFilename("Fichiers CSV(*.csv),*.csv") 'choix du fichier CSV
If fichier = False Then Exit Sub
Set plage = [M1:CJ1]
cc = plage.Columns.Count
col = plage.Column
x = FreeFile
Open fichier For Input As #x 'ouverture en lecture séquentielle
On Error Resume Next
For n = 0 To 1
    ReDim a(1 To cc, 1 To 1)
    Line Input #x, texte
    texte = Replace(Replace(Replace(texte, "à ", "à"), "é", "è"), "è", "è") 'adapter aux besoins
    s = Split(texte, ";")
    For i = 1 To UBound(a)
        a(i, 1) = s(i + col - 2)
    Next i
    [B12].Offset(, n).Resize(UBound(a)) = a
Next n
End Sub
Pas besoin de variables Public...
 
Vote positif 0 Vote négatif
Comme on le voit la macro du post #6 est nettement plus simple donc utiliser :
VB: 
Private Sub Workbook_Open()
Dim fichier As Variant, tablo1, tablo2
ChDir ThisWorkbook.Path
fichier = Application.GetOpenFilename("Fichiers CSV(*.csv),*.csv") 'choix du fichier CSV
If fichier = False Then Exit Sub
Application.ScreenUpdating = False
Range("B12:C" & Rows.Count).ClearContents 'RAZ
Workbooks.Open fichier, Local:=True
tablo1 = ActiveWorkbook.Sheets(1).[A1:L2] 'plage modifiable
tablo2 = ActiveWorkbook.Sheets(1).[M1:CJ2] 'plage modifiable
ActiveWorkbook.Close
[B4] = tablo1(2, 1)
[B5] = tablo1(2, 2)
[B6] = tablo1(2, 5) 'ou tablo1(2, 3) ?
[B7] = tablo1(2, 4)
[B8] = tablo1(2, 6)
[B12].Resize(UBound(tablo2, 2), 2) = Application.Transpose(tablo2)
End Sub
 
Vote positif 0 Vote négatif
job75 à dit:
Comme on le voit la macro du post #6 est nettement plus simple donc utiliser :
VB: 
Private Sub Workbook_Open()
Dim fichier As Variant, tablo1, tablo2
ChDir ThisWorkbook.Path
fichier = Application.GetOpenFilename("Fichiers CSV(*.csv),*.csv") 'choix du fichier CSV
If fichier = False Then Exit Sub
Application.ScreenUpdating = False
Range("B12:C" & Rows.Count).ClearContents 'RAZ
Workbooks.Open fichier, Local:=True
tablo1 = ActiveWorkbook.Sheets(1).[A1:L2] 'plage modifiable
tablo2 = ActiveWorkbook.Sheets(1).[M1:CJ2] 'plage modifiable
ActiveWorkbook.Close
[B4] = tablo1(2, 1)
[B5] = tablo1(2, 2)
[B6] = tablo1(2, 5) 'ou tablo1(2, 3) ?
[B7] = tablo1(2, 4)
[B8] = tablo1(2, 6)
[B12].Resize(UBound(tablo2, 2), 2) = Application.Transpose(tablo2)
End Sub
Cliquez pour agrandir...
Bonjour et merci Job75 effectivement je vais partir sur ce code qui m'a l'air bien plus simple à utiliser, je vais tester!
 
Vote positif 0 Vote négatif
Rejoins nos membres "Supporter XLD" et booste ton expérience Excel !
- Navigue sans publicité
- Accède à Cléa, notre assistante IA experte Excel... et pas que...
- Profite de fonctionnalités exclusives
Ton soutien permet à Excel Downloads de rester 100% gratuit et de continuer à rassembler les passionnés d'Excel.
Je deviens Supporter XLD

Discussions similaires

Chaton77
  • Résolu(e)
Microsoft 365 Vba : Transférer des données d'un tableau dans un autre fichier
Réponses
7
Affichages
749
Chaton77
Chaton77
Z
  • Question Question
XL 2016 Macro pour copier plusieurs cellules vers un fichier :(
Réponses
3
Affichages
471
zendb
Z
P
  • Question Question
Microsoft 365 copier coller un onglet dans un autre fichier
Réponses
6
Affichages
665
pralo
P
O
  • Question Question
XL 2010 suppression fichiers excel vba
Réponses
9
Affichages
685
Oneida
Oneida
K
  • Résolu(e)
Microsoft 365 Ouvrir un autre classeur excel (VBA) pour utiliser les données de celui dans le classeur actif
Réponses
5
Affichages
1 K
Dranreb
Dranreb
K
  • Question Question
Macro pour aller chercher des données d'un autre excel vers le fichier de la macro.
Réponses
5
Affichages
2 K
presa54
P
9
  • Question Question
Microsoft 365 Copier Coller les données (cellules) de plusieurs feuilles d'un classeur vers plusieurs autres feuilles d'un classeur
Réponses
5
Affichages
1 K
92lever
9
A
  • Question Question
XL 2013 Macro pour copier des colonne d'une feuille A dans un classeur sur une feuille B dans un autre classeur .
Réponses
7
Affichages
1 K
Hasco
Hasco
O
  • Résolu(e)
XL 2013 VBA qui copie et colle dans un autre fichier des données selon différentes conditions
Réponses
3
Affichages
1 K
onyirimba
O
O
  • Question Question
Microsoft 365 macro pour agréger différents fichiers CSV dans un fichier XLSM
Réponses
10
Affichages
2 K
dysorthographie
dysorthographie
L
  • Résolu(e)
Microsoft 365 Importer une feuille excel vers un mon classeur
Réponses
11
Affichages
2 K
lolo_76
L
XLSM75
  • Question Question
XL 2019 Extraire données d'un classeur vers un autre en réorganisant et renommant les colonnes
Réponses
10
Affichages
2 K
XLSM75
XLSM75
K
  • Question Question
XL 2016 VBA - Extraire une feuille pour l'enregistrer en .csv (avec séparateur point virgule) puis l'enregistrer en .txt
Réponses
3
Affichages
2 K
Karim48
K
Fredox
  • Question Question
XL 2016 [Résolu] - [VBA] Récupérer le nom de la feuille 1 d'un fichier externe ouvert dans la procédure
Réponses
5
Affichages
2 K
Fredox
Fredox
A
  • Résolu(e)
XL 2013 Copie de données d'un fichier excel pour les coller vers un autre fichier en VBA
Réponses
3
Affichages
4 K
Ananas94
A
A
  • Question Question
XL 2016 Copier coller une feuille d'un classeur dans un autre classeur
Réponses
1
Affichages
4 K
Hasco
Hasco
J
  • Question Question
XL 2013 Macro pour parcourir des fichiers, puis copier coller des donnees.
Réponses
0
Affichages
1 K
jtal
J
S
  • Question Question
XL 2016 copier les données d'un fichier csv vers une feuille excel
Réponses
0
Affichages
723
Slakhdine
S
Z
  • Question Question
copier une feuille d'un classeur fermé dans un classeur ouvert
Réponses
1
Affichages
3 K
herve62
herve62
L
  • Question Question
XL 2010 COPIER / COLLER D'UN FICHIER A UN AUTRE AVEC MULTI CRITÈRES
Réponses
2
Affichages
955
lacamioneta
L
Retour