Récupérer date modification fichier txt en vba

[ivan34]

Bonjour,

J'ai un répertoire dans mes documents ou dedans j'ai un nombre volumineux de fichiers txt. Je voudrais pouvoir récupérer le dernier en fonction de la date de modification en vba afin d'y extraire les informations désirées.

Comment puis je récupérer la date de modification du dernier fichier arrivé?

Par avance merci

Cordialement

 

[Dranreb]

Re : Récupérer date modification fichier txt en vba

Bonjour.

FileDateTime, fonction


Renvoie une valeur de type Variant (Date) indiquant la date et l'heure de création ou de dernière modification d'un fichier.
Syntaxe
FileDateTime(pathname)
L'argument pathname est une expression de chaîne définissant un nom de fichier. L'argument pathname peut préciser le répertoire ou le dossier et le lecteur.

Cordialement

 

[kjin]

Re : Récupérer date modification fichier txt en vba

Bonjour et bienvenue,

Comment puis je récupérer la date de modification du dernier fichier arrivé?

Pour moi, ça nécessite qq éclaircissements
A+
kjin

 

[Theze]

Re : Récupérer date modification fichier txt en vba

Bonjour,

Regarde si ce qui suit te convient. Il te faut adapter le chemin du dossier et exécuter la proc "DernierFichier" pour voir si le résultat retourné est correct ensuite, il faudrait savoir comment tu veux récupérer les valeurs pour aller plus loin :

Sub DernierFichier()
    
    Dim Tbl() As String
    Dim Chemin As String
    Dim DateMax As Date
    Dim Fichier As String
    Dim I As Integer
    
    Chemin = "D:\"
    
    Tbl() = ListeFichiers(Chemin, ".txt")
    
    For I = 1 To UBound(Tbl)
    
        If DateMax < ProprietesFichier(Chemin & Tbl(I)) Then
        
            DateMax = ProprietesFichier(Chemin & Tbl(I))
            Fichier = Tbl(I)
            
        End If
    
    Next I
    
    MsgBox Fichier & vbCrLf & DateMax
    
End Sub

Function ProprietesFichier(Chemin As String) As String

    Dim Fso As Object
    Dim Doc As Object
    
    If Dir(Chemin) <> "" Then
    
        Set Fso = CreateObject("Scripting.FileSystemObject")
        Set Doc = Fso.GetFile(Chemin)
        
        With Doc
            ProprietesFichier = .DateLastModified
        End With
        
    Else
        
        ProprietesFichier = "Fichier introuvable"
    
    End If
    
    
    Set Doc = Nothing
    Set Fso = Nothing

End Function

Function ListeFichiers(Chemin As String, _
                       Extension As String) As String()
   
    Dim Tbl() As String
    Dim Fichier As String
    Dim I As Integer
    
    Fichier = Dir(Chemin & "*" & Extension)
    
    Do While (Len(Fichier) > 0)
        
        If InStr(Fichier, Extension) <> 0 Then
            
            I = I + 1
            ReDim Preserve Tbl(1 To I)
            Tbl(I) = Fichier
            
        End If
        
        Fichier = Dir()
        
    Loop
   
    ListeFichiers = Tbl()
    
End Function

Hervé.

 

[ivan34]

Re : Récupérer date modification fichier txt en vba

Bonjour,
Et merci pour vos réponses
Le but est donc de tester le dernier fichier reçu que je recois (qui est un fichier qui vient d'un system i) et qui est généré tout les jours. je regarde donc que ce soit bien le dernier et c'est le dernier je le récupère dans mon classeur excel.

L'opération qui consiste à l'afficher dans mon classeur pas de souci, par contre c'est une opération que je fais manuel, c'est à dire que je regarde parmi les dizaine de fichiers quel est le dernier puis j'ai une macro qui l'affiche et qui le traite comme je veux.

Mon opération est d'automatiser ma première phase

Merci

Cordialement

PS: Je n'ai pas encore tester la proc de theze

 

[Dranreb]

Re : Récupérer date modification fichier txt en vba

Bonjour
Le plus simple est d'utiliser Dir comme dans la boucle de Hervé (These) et de comparer le FileDateTime de chaque fichier trouvé au dernier traité, ou retenir le plus grand trouvé.
vous pouvez mettre ChDrive puis ChDir du répertoire à examiner au début de la procédure pour n'avoir plus à spécifier le chemin de chaque fichier par la suite, ni au 1er Dir, ni au FileDateTime, ni à l'OpenTexte final (je suppose).
Vous auriez du joindre le classeur contenant ce que vous avez déjà su écrire.
À +

 

[ivan34]

Re : Récupérer date modification fichier txt en vba

Bonsoir,

Je vous remercie de votre aide ce que vous m'avez donné notamment Hervé fonctionne nickel

Merci a tous