recopier format cellule dans autre feuille

[poipoi]

bonjour tous
j'ai bien essayé de chercher ce qu'il ma fallait mais pas trouvé..
j'ai un tableau avec des listes de validation sur une autre feuille, et j'aimerai pourvoir conserver le format des cellules selectionnées (couleur taille de la police et couleur )
il me semblait pourtant que j'avais vu un fil.. mais la vue baisse..
avez-vous souvenir ou une aide..
merci d'avance

 

[Pierrot93]

Re : recopier format cellule dans autre feuille

Bonjour,

pas tout compris... mais en copiant la feuille et en supprimant le contenu dans la nouvelle feuille cela devrait le faire.... tu bloques où ??

bonne journée
@+

 

[poipoi]

Re : recopier format cellule dans autre feuille

bonjour Pierrot et merci
mon souci est que je veux garder le format original de la cellule sélectionnée par liste de validation
je joins mon fichier

 

[Pierrot93]

Re : recopier format cellule dans autre feuille

Re,

essaye le code ci-dessous, à utiliser dans le module de la feuille "bondecommande", click droit sur l'onglet => visualiser le code et tu le colles :

Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
Static b As Boolean
Dim x As Range
If b Then Exit Sub
If Target.Count > 1 Or Target.Column <> 2 Or Target.Row < 14 Then Exit Sub
Set x = Sheets("TRAVAUX").Columns(1).Find(Target, , xlValues, xlWhole, , , False)
If Not x Is Nothing Then
    b = True
    x.Copy
    Target.PasteSpecial xlPasteFormats
    b = False
End If
End Sub

bon après midi
@+

 

[poipoi]

Re : recopier format cellule dans autre feuille

impec Pierrot et grand merci
tout fonctionne pour la cellule correspondant à la liste de validation..
mais pour les autres omment faire?
en fait le cellules qui ont un fomat "ocre" sont des têtes de chapitres dont la ligne du tableau doit être ocre aussi...
c'est de ma faute je m'étais mal exprimé...
une idée la dessus?

 

[Pierrot93]

Re : recopier format cellule dans autre feuille

Bonjour,

les autres quoi ??? pas tout compris, le code agit en fonction des modificaations faites dans les listes de validation colonne b de l'onglet commande... comme indiqué sur ton fichier...

 

[poipoi]

Re : recopier format cellule dans autre feuille

oui tu as raison mais je me suis trompé, je voulais que toute la ligne du tableau "boncommande" soit à l'identique de la ligne de l'onglet "travaux", en fonction de le cellule choisie dans la liste de validation... heu.. dis moi si tu comprends mieux, sinon je renvoie un exemple..
avec mes excuses et mes remerciements

 

[Pierrot93]

Re : recopier format cellule dans autre feuille

Re,

modifie comme suit :

Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
Static b As Boolean
Dim x As Range
If b Then Exit Sub
If Target.Count > 1 Or Target.Column <> 2 Or Target.Row < 14 Then Exit Sub
Set x = Sheets("TRAVAUX").Columns(1).Find(Target, , xlValues, xlWhole, , , False)
If Not x Is Nothing Then
    b = True
    x.Copy
    Range("A" & Target.Row, "F" & Target.Row).PasteSpecial xlPasteFormats
    b = False
End If
End Sub

 

[poipoi]

Re : recopier format cellule dans autre feuille

Bravo Pierrot !!!!
y'en a, c'est la classe quand même !!!
merci beaucoup...

 

[poipoi]

Re : recopier format cellule dans autre feuille

rebonjour
je repreprends le fil après avoir constaté que la macro ne fonctionneplus dès que l'on change contenu de la cellule où il y a la liste de validation.. en fait le format monétaire est perdu ainsi que les MFC pour masquer la valeur 0..

je joins le fichier .. on ne sait jamais!!!
et bonne journée à chacun

 

[Pierrot93]

Re : recopier format cellule dans autre feuille

Bonjour,

essaye ainsi :

Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
Static b As Boolean
Dim x As Range
If b Then Exit Sub
If Target.Count > 1 Or Target.Column <> 2 Or Target.Row < 14 Then Exit Sub
Set x = Sheets("TRAVAUX").Columns(1).Find(Target, , xlValues, xlWhole, , , False)
If Not x Is Nothing Then
    b = True
    x.Copy
    Range("A" & Target.Row, "F" & Target.Row).PasteSpecial xlPasteFormats
    x.Offset(0, 2).Copy
    With Union(Target.Offset(0, 2), Target.Offset(0, 4))
        .PasteSpecial xlPasteFormats
        With .FormatConditions
            .Delete
            .Add Type:=xlExpression, Formula1:="=ESTERREUR(" & Target.Offset(0, 2).Address(0, 0) & ")"
            .Add Type:=xlCellValue, Operator:=xlEqual, Formula1:="0"
        End With
        .FormatConditions(1).Font.ColorIndex = 2
        .FormatConditions(2).Font.ColorIndex = 44
    End With
    Target.Select
    b = False
End If
End Sub

@+

 

[poipoi]

Re : recopier format cellule dans autre feuille

bonjour Pierrot
eh bien ça m'a l'air tout bon !!!
un grand merci .. et si tu passes dans le coin, y'aura bien toujours un bout de tarte aux quetsch à manger..