Recherchev référence autre feuille nommée dans cellule

[chris6999]

Bonjour

Comment peut-on écrire une formule pour récupérer la valeur d'une autre feuille nommée dans une cellule.
Je m'explique Je récupère en K1 la référence mois qui correspond au nom de la feuille (=TEXTE($E$2;"mmmm")) dans laquelle je cherche à faire un rechercheV
Je suis sur la feuille juillet et souhaite récupérer une donnée sur le mois précédent soit juin
=RECHERCHEV(A13;juin!$A$11:$V$1000;15;0)

Je souhaiterais pouvoir trouver la formule ou la macro me permettant d'inclure la valeur de K1 dans ma recherche V.

J'ai essayé avec les & mais cela ne fonctionne pas.

Cordialement

 

[Modeste]

Bonjour Chris,

C'est la fonction INDIRECT qui permet de faire ce genre de choses ... Essaie

=SI(ESTERREUR(RECHERCHEV(A13;INDIRECT("'"&K1&"'!$A$11:$V$1000");15;0));"";RECHERCHEV(A13;INDIRECT("'"&K1&"'!$A$11:$V$1000");15;0))

 

[gosselien]

Bonjour,

ceci dit...il est normal d'écrire en B12: =SI(ESTERREUR(RECHERCHEV(A13 donc référence à A13 ?
mais peut être que je dors encore 🙂

et je pense qu'il faut mette $K$1 dans la très bonne formule de Modeste que je salue 🙂

P.

 

[Jocelyn]

Bonjour le Forum,
Bonjour chris6999,

A tester en B12 et a étirer vers le bas

=SI(ESTERREUR(RECHERCHEV(A13;INDIRECT($K$1&"!$A$11:$V$1000");15;0));"";RECHERCHEV(A13;INDIRECT($K$1&"!$A$11:$V$1000");15;0))

Cordialement

Edit bonjour L'ami modeste et Gosselien désolé pour la collision je tourne au diesel ce matin

 

[Modeste]

Re,
Salut gosselien,
Salut mon bon Jocelyn 🙂

Signalons aussi à chris6999 que sous Excel 2007 et postérieur (le fichier étant un .xlsm), la formule peut être raccourcie:

=SIERREUR(RECHERCHEV(A12;INDIRECT("'"&$K$1&"'!$A$11:$V$1000");15;0);"")

 

[chris6999]

Bonjour et merci à tous pour votre aide
J'ai inséré avec succès vos propositions dans mon fichier réel et cela fonctionne à merveille.
Je garde bien sûr précieusement vos conseils et vos codes sous le coude.

Bonne journée à tous