RECHERCHEV dans plusieurs feuilles autre classeur

[martinette]

Bonjour à tous

Comment puis je effectuer une recherchev dans plusieurs feuilles d'un classeur ?

J'ai un formulaire de devis sur un classeur DEVIS sur lequel je tape le numéro d'article

J'effectue une recherchev sur un autre classeur, mais mes articles sont classés dans différents onglets (baignoires, lavabos, wc... - jusqu'à 10 onglets)

Actuellement, ma formule est la suivante :
=RECHERCHEV(A12;[article.xls]BAIGNOIRE!$A$2:$K$73;2;FAUX)

BAIGNOIRE étant le nom de ma première feuille..... mais si je ne cherche pas une baignoire, ca ne fonctionne pas. Normal mais comment y remedier sans avoir une formule très lourde ,

Merci à tous

 

[JBOBO]

Re : RECHERCHEV dans plusieurs feuilles autre classeur

Bonjour,

Peut-etre en mettant un apostrophe après le crochet fermé (]') et un autre avant le point d'exclamation ('!), en plus simple en mttant le nom de l'onglet entre apostrophe (pas testé)

 

[sapeur_alain]

Re : RECHERCHEV dans plusieurs feuilles autre classeur

Bonjour,

Merci pour votre réponse, après essai de vos deux propositions, la recherche n'aboutit malheureusement toujours pas. Quand vous dites mettre le nom de l'onglet entre apostrophes, c'est la référence au nom de l'onglet présente en W, ou directement le nom des onglets du fichier year2012, voir les deux ? Car sur l'onglet lui même, je ne peux pas mettre d'apostrophe au début, elle ne s'affiche pas.

D'autres idées ?

 

[chris]

Re : RECHERCHEV dans plusieurs feuilles autre classeur

Bonjour

Regarde ce que fait Excel quand depuis un onglet tu tapes = puis tu cliques sur une cellule d'un autre onglet, ayant un nom tel que décrit, d'un autre classeur. Tu verras bien où sont les [ et les '
Une fois cette syntaxe comprise, tu pourras adapter ta formule.

 

[sapeur_alain]

Re : RECHERCHEV dans plusieurs feuilles autre classeur

Bonjour,

C'est une très bonne idée, j'observe alors qu'il y a une apostrophe avant le premier crocher annonçant le nom du fichier '[ et une avant le point d'exclamation '! : ='[year2012.xls]Docking Station'!$N$500
Ce qui donne dans ma formule :
=SI(S26<>"";INDEX(INDIRECT(INDEX("[year2012.xls]"&nf;EQUIV(VRAI;(NB.SI(INDIRECT("'[year2012.xls]"&nf&"'!G7:G1000");S26)>0);0))&"!F7:G1000");EQUIV(S26;INDIRECT(INDEX("[year2012.xls]"&nf;EQUIV(VRAI;(NB.SI(INDIRECT("'[year2012.xls]"&nf&"'!G7:G1000");S26)>0);0))&"!G7:G1000");0);1);"")
et le résultat ce coup-ci n'est plus #N/A mais #REF!

L'ai-je mal adaptée ?

 

[chris]

Re : RECHERCHEV dans plusieurs feuilles autre classeur

Re

Nous n’avons pas tes fichiers donc le mieux est de vérifier chaque partie de la formule dans l'assistant fonction afin de t'assurer que les concaténations donnent des noms cohérents.

nf est un nom dont nous n'avons pas le détail.

 

[sapeur_alain]

Re : RECHERCHEV dans plusieurs feuilles autre classeur

Re,

Je vous joins un extrait de mes fichiers car décidément Excel ne m'aime pas malgré tout l'amour que je lui porte. Le n° de série cherché se trouve dans le 3e onglet. Lorsque vous supprimez l'espace et le tiret dans le nom de l'onglet ainsi que dans la liste du fichier "suivi paiement client", la date s'affiche bien.

En espérant que de cette manière une âme charitable pourra m'aider.

 

[chris]

Re : RECHERCHEV dans plusieurs feuilles autre classeur

Re

=SI(B9<>"";INDEX(INDIRECT(INDEX("'[year2012.xls]"&nf&"'";EQUIV(VRAI;(NB.SI(INDIRECT("'[year2012.xls]"&nf&"'!G7:G1000");B9)>0);0))&"!F7:G1000");EQUIV(B9;INDIRECT(INDEX("'[year2012.xls]"&nf&"'";EQUIV(VRAI;(NB.SI(INDIRECT("'[year2012.xls]"&nf&"'!G7:G1000");B9)>0);0))&"!G7:G1000");0);1);"")

à valider par CTRL Shift Entrée (comme tu l'avais fait)

Ne marche que si le second classeur est ouvert

 

[sapeur_alain]

Re : RECHERCHEV dans plusieurs feuilles autre classeur

Merci infiniment Chris !

 

[serge54cmoi]

Re : RECHERCHEV dans plusieurs feuilles autre classeur

Bonjour, j'ai le même soucis lorsque je souhaite retrouver une valeur dans 4 feuilles différentes...
=SI(ESTNA(SI(A2="";0;RECHERCHEV(A2;'1er trimestre'!$A$4:$Q$100;2;0)));SI(A2="";0;RECHERCHEV(A2;'2eme trimestre'!$A$4:$Q$100;2;0));SI(A2="";0;RECHERCHEV(A2;'3eme trimestre'!$A$4:$Q$100;2;0));SI(A2="";0;RECHERCHEV(A2;'4eme trimestre'!$A$4:$Q$100;2;0)))
Excel me répond : vous avez tapé un nombre trop important d'arguments pour cette fonction...????
Merci pour votre aide

 

[JCGL]

Re : RECHERCHEV dans plusieurs feuilles autre classeur

Bonjour à tous,

Bienvenue sur XLD

Merci de préciser ta version XL : cela influera sur la longueur de la formule

Dans l'attente une solution pour les quatre trimestres si tu es en XL >2007

A+ à tous

 

[BOISGONTIER]

Re : RECHERCHEV dans plusieurs feuilles autre classeur

Bonsoir,

Avec une recherche 3D, la formule est + courte

=RECHERCHEV(A2;INDIRECT("'"&INDEX(nf;EQUIV(VRAI;(NB.SI(INDIRECT("'"&nf&"'!A2:A100");A2)>0);0))&"'!A2:B100");2;0)
Valider avec mj+ctrl+entrée

nf est un champ qui contient les noms des feuilles

Formules Matricielles 3D

JB

 

[serge54cmoi]

Re : RECHERCHEV dans plusieurs feuilles autre classeur

Merci Boisgontier,
avec ta formule cela fonctionne comme je le souhaite
Ce qui est juste dommage, c'est que cela m'affiche #N/A lorsque que je n'ai pas de valeur dans les autres feuilles
est-il possible de corriger ceci? afficher une cellule vide par exemple???
En tout merci beaucoup

 

[serge54cmoi]

Re : RECHERCHEV dans plusieurs feuilles autre classeur

J'ai une autre question (si je peux abuser)
Comment peut on faire pour colorier une ligne si la valeur de la 1ere cellule de cette ligne est paire
et colorier dans une autre couleur quand la valeur de la suivante est impaire
Merciiiiii

 

[BOISGONTIER]

Re : RECHERCHEV dans plusieurs feuilles autre classeur

Bonjour,

Si Excel7 ou +

=SIERREUR(RECHERCHEV(A2;INDIRECT("'"&INDEX(NF;EQUIV(VRAI;(NB.SI(INDIRECT("'"&NF&"'!A2:A6");A2)>0);0))&"'!A2:B6");2;0);"inconnu")

Si Excel2003 ou -

=SI(ESTNA(EQUIV(VRAI;(NB.SI(INDIRECT("'"&NF&"'!A2:A6");A2)>0);0));"inc";RECHERCHEV(A2;INDIRECT("'"&INDEX(NF;EQUIV(VRAI;(NB.SI(INDIRECT("'"&NF&"'!A2:A6");A2)>0);0))&"'!A2:B6");2;0))

JB

 

[gosselien]

Re : RECHERCHEV dans plusieurs feuilles autre classeur

J'ai une autre question (si je peux abuser)
Comment peut on faire pour colorier une ligne si la valeur de la 1ere cellule de cette ligne est paire
et colorier dans une autre couleur quand la valeur de la suivante est impaire
Merciiiiii

Bonjour/soir,

=EST.IMPAIR(A1) en format conditionnel

P.