Microsoft 365 RechercheV avec une condition poids

Lina · 16 Février 2026

Bonjour,

j'aurai besoin d'aide pour une formule.

Mon besoin :

Que la colonne C soit remplie en fonction de la colonne B (en liste déroulante), à partie d'une table de valeurs (donc comme une recherche V), mais en fonction du poids du produits qui est signifié en colonne A.

Le contexte :

Il existent différents codes DEEE en au sain d'une même catégorie de produits en fonction de leur poids. et je voudrais que en rentrant la catégorie et le poids, le code s'affiche.

Merci d'avance pour votre aide ! 😉

Saboh12617 · 26 Février 2026

Lina à dit:
Mon vrai tableau contient plus de colonnes que dans l’exemple que vous avez utilisé.
- Pour la partie 3 (les colonnes à renvoyer), je sais comment adapter la formule.
- Par contre, pour les deux premières parties, je ne sais pas comment ajuster pour que cela corresponde à mon tableau.
Pourriez-vous m’indiquer comment modifier ces parties afin que la formule fonctionne correctement avec mon tableau complet ?

Bien sur,
Dans le bloc suivant :

Code:

λFILTEQUIP; LAMBDA(_fullarr;_equip;
        LET(
            _idx; SCAN(
                "";
                CHOISIRCOLS(_fullarr; 2);
                LAMBDA(acc;v; SI(v = ""; PRENDRE(acc; -1); v))
            );
            FILTRE(_fullarr; _idx = _equip; "")
        )
    )
;

Le 2...

Nain porte quoi · 16 Février 2026

Hello,

si vous aviez un petit fichier à nous fournier, ça serait nettement plus simple pour vous donner LA bonne formule.

PS : RECHERCHEV est obsolète avec Excel 365, il est remplacé AVANTAGEUSEMENT par RECHECRCHEX

sylvanu · 16 Février 2026

Bonjour Lina, et bienvenue sur XLD, bonjour NainPorteQuoi,
Avec un petit fichier test représentatif et anonymisé, ce serait plus simple pour comprendre et essayer de trouver une solution qui colle à votre contexte. ( quelques lignes suffisent )

Lina · 26 Février 2026

Bonjour NainPorteQuoi,
Bonjour Sylvanu,

Merci beaucoup pour vos retours,

Comme suggéré, vous trouverez en pièce jointe un fichier de simulation.
les deux cases qui me posent problème sont le code ecologic et le montant DEEE. J'y ai incéré des indication et des codes couleurs pour faciliter la compréhension.

Encore merci pour le temps consacré et votre aide précieuse !

Saboh12617 · 26 Février 2026

Je vais vous chercher une formule mais pour info on n'atteindra jamais la ligne rouge...

Quant aux doublons pour une meme catégorie, vous n'indiquez aucunement comment choisir... Je prendrai donc toujours la 1e ligne

sylvanu · 26 Février 2026

Bonjour,
Avec autant de cellules fusionnées, je ne sais pas trouver la bonne valeur en formules.
Acceptez vous les macros VBA ?
NB: Vous cherchez "Composant PC" et 25 kg. Dans le barème, le poids max pour "Composant PC" est de 5kg. Que faire ?

Lina · 26 Février 2026

Le premier tableau est en g je n'ai pas fais la conversion.. Ok pour les VAB!

Saboh12617 · 26 Février 2026

Voici ma proposition (pour la cellule D2, en E2 remplacer "ECO" en bas par "DEE") :

Code:

=LET(
    λGETBORNES; LAMBDA(_fullarr;
        LET(
            _tranche; CHOISIRCOLS(_fullarr; 3);
            _return; CHOISIRCOLS(_fullarr; 5; 6; -1);
            FILTRE(SI(_return = ""; 1000000000; _return); _tranche <> "")
        )
    );
    λFILTEQUIP; LAMBDA(_fullarr;_equip;
        LET(
            _idx; SCAN(
                "";
                CHOISIRCOLS(_fullarr; 2);
                LAMBDA(acc;v; SI(v = ""; PRENDRE(acc; -1); v))
            );
            FILTRE(_fullarr; _idx = _equip; "")
        )
    );
    λSEARCH; LAMBDA(_pds;_equip;_colCode;_fullarr;
        LET(
            _filt; λFILTEQUIP(_fullarr; _equip);
            _born; λGETBORNES(_filt);
            RECHERCHEX(
                _pds;
                CHOISIRCOLS(_born; 1);
                CHOISIRCOLS(_born; SI(_colCode = "ECO"; -2; -1));
                "Aucune catégorie correspondante";
                1
            )
        )
    );
    λSEARCH($B2; $C2;"ECO"; Barème!$A$2:$K$31)
)

EDIT : je vous laisse corriger le 25 en 0,25 pour faire marcher la recherche de la première ligne. Sinon entrez directement $B2/1000 dans la formule.

sylvanu · 26 Février 2026

Lina à dit:
Le premier tableau est en g je n'ai pas fais la conversion.

Donc 25 c'est 25g. Mais dans barème le poids min est de 500g.

Lina · 26 Février 2026

sylvanu à dit:
Donc 25 c'est 25g. Mais dans barème le poids min est de 500g.

non il y a une erreur c'est le poid max, c'est de 0 à 500 g

Lina · 26 Février 2026

Saboh12617 à dit:

Voici ma proposition (pour la cellule D2, en E2 remplacer "ECO" en bas par "DEE") :

Code:

=LET(
    λGETBORNES; LAMBDA(_fullarr;
        LET(
            _tranche; CHOISIRCOLS(_fullarr; 3);
            _return; CHOISIRCOLS(_fullarr; 5; 6; -1);
            FILTRE(SI(_return = ""; 1000000000; _return); _tranche <> "")
        )
    );
    λFILTEQUIP; LAMBDA(_fullarr;_equip;
        LET(
            _idx; SCAN(
                "";
                CHOISIRCOLS(_fullarr; 2);
                LAMBDA(acc;v; SI(v = ""; PRENDRE(acc; -1); v))
            );
            FILTRE(_fullarr; _idx = _equip; "")
        )
    );
    λSEARCH; LAMBDA(_pds;_equip;_colCode;_fullarr;
        LET(
            _filt; λFILTEQUIP(_fullarr; _equip);
            _born; λGETBORNES(_filt);
            RECHERCHEX(
                _pds;
                CHOISIRCOLS(_born; 1);
                CHOISIRCOLS(_born; SI(_colCode = "ECO"; -2; -1));
                "Aucune catégorie correspondante";
                1
            )
        )
    );
    λSEARCH($B2; $C2;"ECO"; Barème!$A$2:$K$31)
)

EDIT : je vous laisse corriger le 25 en 0,25 pour faire marcher la recherche de la première ligne. Sinon entrez directement $B2/1000 dans la formule.

Merci beaucoup !! je vais me pencher dessus 🙂

Saboh12617 · 26 Février 2026

Lina à dit:
Merci beaucoup !! je vais me pencher dessus 🙂

Pour vous aider à comprendre, j'ai découpé la recherche en 3 étapes :

D'abord avec λFILTEQUIP on va récupérer les lignes de la BDD qui correspondent à la colonne "equipement", en "défusionnant" avec SCAN (le problème évoqué par @sylvanu que je salue).

Ensuite, avec λGETBORNES on va un peu simplifier la table : en fait pour les tranches c'est redondant d'avoir des bornes MIN+MAX pour chaque ligne, il vaut mieux de manière générale avoir une liste soit de bornes MIN, soit MAX. Et donc on va regarder dans cette liste si notre valeur est "entre 2 bornes", auquel cas on récupère la ligne correspondante. Ça evite aussi d'avoir des superpositions de plages. Dans votre cas j'ai pris la colonne des poids MAX (colonne 3), et j'ai remplacé les vides par 1E9. On récupère donc 3 colonnes : PoidsMax | codeEco | valeurIEEE

Enfin, dans λSEARCH on va chercher dans le tableau récupéré le dernier poids "inférieur ou égal" à poidsMax, et récupérer le Eco ou IEE correpsondant.

Lina · 26 Février 2026

Saboh12617 à dit:
Pour vous aider à comprendre, j'ai découpé la recherche en 3 étapes :

D'abord avec λFILTEQUIP on va récupérer les lignes de la BDD qui correspondent à la colonne "equipement", en "défusionnant" avec SCAN (le problème évoqué par @sylvanu que je salue).

Ensuite, avec λGETBORNES on va un peu simplifier la table : en fait pour les tranches c'est redondant d'avoir des bornes MIN+MAX pour chaque ligne, il vaut mieux de manière générale avoir une liste soit de bornes MIN, soit MAX. Et donc on va regarder dans cette liste si notre valeur est "entre 2 bornes", auquel cas on récupère la ligne correspondante. Ça evite aussi d'avoir des superpositions de plages. Dans votre cas j'ai pris la colonne des poids MAX (colonne 3), et j'ai remplacé les vides par 1E9. On récupère donc 3 colonnes : PoidsMax | codeEco | valeurIEEE

Enfin, dans λSEARCH on va chercher dans le tableau récupéré le dernier poids "inférieur ou égal" à poidsMax, et récupérer le Eco ou IEE correpsondant.

Mon vrai tableau contient plus de colonnes que dans l’exemple que vous avez utilisé.
- Pour la partie 3 (les colonnes à renvoyer), je sais comment adapter la formule.
- Par contre, pour les deux premières parties, je ne sais pas comment ajuster pour que cela corresponde à mon tableau.
Pourriez-vous m’indiquer comment modifier ces parties afin que la formule fonctionne correctement avec mon tableau complet ?

Saboh12617 · 26 Février 2026

Lina à dit:
Mon vrai tableau contient plus de colonnes que dans l’exemple que vous avez utilisé.
- Pour la partie 3 (les colonnes à renvoyer), je sais comment adapter la formule.
- Par contre, pour les deux premières parties, je ne sais pas comment ajuster pour que cela corresponde à mon tableau.
Pourriez-vous m’indiquer comment modifier ces parties afin que la formule fonctionne correctement avec mon tableau complet ?

Bien sur,
Dans le bloc suivant :

Code:

λFILTEQUIP; LAMBDA(_fullarr;_equip;
        LET(
            _idx; SCAN(
                "";
                CHOISIRCOLS(_fullarr; 2);
                LAMBDA(acc;v; SI(v = ""; PRENDRE(acc; -1); v))
            );
            FILTRE(_fullarr; _idx = _equip; "")
        )
    )
;

Le 2 correspond à la colonne des "équipements" dans le tableau. [JAUNE]

Dans le bloc suivant :

Code:

λGETBORNES; LAMBDA(_fullarr;
        LET(
            _tranche; CHOISIRCOLS(_fullarr; 3);
            _return; CHOISIRCOLS(_fullarr; 5; 6; -1);
            FILTRE(SI(_return = ""; 1000000000; _return); _tranche <> "")
        )
    );

Le 3 correspond à la colonne des "tranche de poids" dans le tableau.
Le 5, c'est le plus important car il sert au tri, c'est la colonne "poid max".
Le 6, c'est la colonne des Codes ECO (à renvoyer) [VERT]
Le -1, ça indique la dernière colonne du tableau (qui contenant vos IEEE "eco-contribution") [ROUGE]. Vous pouvez le remplacer par 11, ou le numéro correspondant.
Dans λSEARCH vous n'avez rien à modifier car tant que la colonne verte est à gauche de la colonne rouge, les indices de colonne sont fixes (sinon, inverser le SI).

Lina · 27 Février 2026

Saboh12617 à dit:
Bien sur,
Dans le bloc suivant :

Code:

λFILTEQUIP; LAMBDA(_fullarr;_equip; LET( _idx; SCAN( ""; CHOISIRCOLS(_fullarr; 2); LAMBDA(acc;v; SI(v = ""; PRENDRE(acc; -1); v)) ); FILTRE(_fullarr; _idx = _equip; "") ) ) ;

Le 2 correspond à la colonne des "équipements" dans le tableau. [JAUNE]
Regarde la pièce jointe 1228158
Dans le bloc suivant :

Code:

λGETBORNES; LAMBDA(_fullarr; LET( _tranche; CHOISIRCOLS(_fullarr; 3); _return; CHOISIRCOLS(_fullarr; 5; 6; -1); FILTRE(SI(_return = ""; 1000000000; _return); _tranche <> "") ) );

Le 3 correspond à la colonne des "tranche de poids" dans le tableau.
Le 5, c'est le plus important car il sert au tri, c'est la colonne "poid max".
Le 6, c'est la colonne des Codes ECO (à renvoyer) [VERT]
Le -1, ça indique la dernière colonne du tableau (qui contenant vos IEEE "eco-contribution") [ROUGE]. Vous pouvez le remplacer par 11, ou le numéro correspondant.
Dans λSEARCH vous n'avez rien à modifier car tant que la colonne verte est à gauche de la colonne rouge, les indices de colonne sont fixes (sinon, inverser le SI).

Merci beaucoup !!! j'ai réussi à intégrer la formule cela marche parfaitement 🙂 dernière petite question, quand je met la formule dans la case rouge, pour que cela affiche le montant, est ce qu'il faut aussi changer des choses à part remplacer "eco" par "dee" ?

Microsoft 365 RechercheV avec une condition poids

Lina

XLDnaute Nouveau

Saboh12617

Nain porte quoi

XLDnaute Occasionnel

sylvanu

XLDnaute Barbatruc

Lina

XLDnaute Nouveau

Pièces jointes

Saboh12617

XLDnaute Junior

sylvanu

XLDnaute Barbatruc

Lina

XLDnaute Nouveau

Saboh12617

XLDnaute Junior

Pièces jointes

sylvanu

XLDnaute Barbatruc

Lina

XLDnaute Nouveau

Lina

XLDnaute Nouveau

Saboh12617

XLDnaute Junior

Lina

XLDnaute Nouveau

Saboh12617

XLDnaute Junior

Lina

XLDnaute Nouveau

Discussions similaires

Microsoft 365 RechercheV avec une condition poids

XLDnaute Nouveau

XLDnaute Occasionnel

XLDnaute Barbatruc

XLDnaute Nouveau

Pièces jointes

XLDnaute Junior

XLDnaute Barbatruc

XLDnaute Nouveau

XLDnaute Junior

Pièces jointes

XLDnaute Barbatruc

XLDnaute Nouveau

XLDnaute Nouveau

XLDnaute Junior

XLDnaute Nouveau

XLDnaute Junior

XLDnaute Nouveau

Discussions similaires

Privacy & Transparency

Privacy & Transparency