XL 2016 Rechercher la valeur la plus à droite dans une plage en fonction d'un seuil

chris

XLDnaute Barbatruc

• 28 Février 2024

• #2

Bonjour

Une recherche approximative (avec 1 en dernier argument) nécessite des données classées ce qui d'après ta question n'est pas le cas

 

Vote positif 0 Vote négatif

A

ALS35

XLDnaute Impliqué

• 28 Février 2024

• #3

Bonjour à tous,
Essaie :

VB:

=RECHERCHEH(9^9;SI(L13:AC13<=100;"";L13:AC13);1)

Formule matricielle, à valider pat Ctrl+Maj+Entrée
Cordialement

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 28 Février 2024

• #4

Bonjour à tous,

Ou aussi avec validation matricielle de la formule :

Code:

=RECHERCHEH(9^9;SI(L13:AC13>100;L13:AC13);1)

A+

 

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 28 Février 2024

• #5

Bonjour à tous,

Une autre approche, formule matricielle

VB:

=INDEX($C$2:$O$2;MAX(SI($C$2:$O$2>100;COLONNE($C$2:$O$2)-2)))

JHA

 

Pièces jointes

• Classeur max si colonne.xlsx

  8.7 KB · Affichages: 3

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 28 Février 2024

• #6

@JHA il vaut mieux utiliser GRANDE.VALEUR(xxx;1) au lieu de MAX(xxx).

Car s'il n'y a pas de valeurs > 100 ta formule renvoie la valeur en C2.

 

Vote positif 0 Vote négatif

patricktoulon

XLDnaute Barbatruc

• 28 Février 2024

• #7

bonjour à tous

 

Pièces jointes

• premier valeur au dessus de 100 en partant de la droite d une ligne.xlsx

  8.5 KB · Affichages: 5

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 28 Février 2024

• #8

Allons Patrick, il faut adapter la formule matricielle de JHA en enlevant le "-2".

 

Vote positif 0 Vote négatif

patricktoulon

XLDnaute Barbatruc

• 29 Février 2024

• #9

re
Bonjour @job75
des explications sur les parties de formule seraient sympa

 

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 29 Février 2024

• #10

Bonjour à tous,

VB:

=INDEX($C$2:$O$2;MAX(SI($C$2:$O$2>100;COLONNE($C$2:$O$2)-2)))

Le début de plage à contrôler débute à la colonne "C" donc la 3ème colonne, on soustrait deux (-2) pour donner une plage de 1 à x afin de donner le résultat exact avec la fonction index().

COLONNE($C$2:$O$2)
{3.4.5.6.7.8.9.10.11.12.13.14.15}

COLONNE($C$2:$O$2)-2
{1.2.3.4.5.6.7.8.9.10.11.12.13}

même chose avec grande.valeur

JHA

 

Dernière édition: 29 Février 2024

Vote positif 0 Vote négatif

patricktoulon

XLDnaute Barbatruc

• 29 Février 2024

• #11

re
ha ben oui !!
merci JHA
j'avais zapé index en effet

 

Vote positif 0 Vote négatif

A

ALS35

XLDnaute Impliqué

• 29 Février 2024

• #12

Bonjour à tous,
@patricktoulon
Si tu souhaites te faire un catalogue de formules, quelques autres possibilités (hors gestion d'erreur) :

Pour s'affranchir de la position en colonne :

Code:

=INDEX(2:2;GRANDE.VALEUR(SI(C2:O2>100;COLONNE(C2:O2));1))

Pour s'affranchir de la position en colonne et de la validation matricielle :

Code:

=INDEX(2:2;AGREGAT(14;6;COLONNE(C2:O2)/(C2:O2>100);1))
qui permettra d'avoir également la première valeur (voire la nième) avec :
=INDEX(2:2;AGREGAT(15;6;COLONNE(C2:O2)/(C2:O2>100);1))

Pour ceux qui ont Excel 365, une formule simplissime :

Code:

=PRENDRE(FILTRE(C2:O2;C2:O2>100;"");;-1)
ou
=LET(p;C2:O2;PRENDRE(FILTRE(p;p>100;"");;-1))
et pour la première valeur :
=PRENDRE(FILTRE(C2:O2;C2:O2>100;"");;1)

voili voilou,
Cordialement

 

Vote positif 0 Vote négatif

patricktoulon

XLDnaute Barbatruc

• 29 Février 2024

• #13

re bonjour @ALS35
merci pour les exemple
=INDEX(A1:F1 ; 'ok pigé
AGREGAT(argument 14 =grandevaleur ok ; argument option = 6 quoi ;
COLONNE(A1:F1)/(A1:F1>100);1)) <--c'est quoi cette formule explique

 

Vote positif 0 Vote négatif

A

ALS35

XLDnaute Impliqué

• 29 Février 2024

• #14

Re,
Pas certain que tu aies tout pigé !
1)
=INDEX(A1:F1 ;
Si tu mets A1:F1 ça marche sans correction de colonne, si tu déplaces ta plage en B1:G1 par exemple il faut corriger le numéro de colonne de -1 comme ceci :
=INDEX(B1:G1;GRANDE.VALEUR((B1:G1>100)*COLONNE(B1:G1);1)-1)
Si tu mets toute la ligne 1, tu n'a pas à faire cette correction quelle que soit la position de ta chaine :
=INDEX(1:1;GRANDE.VALEUR((B1:G1>100)*COLONNE(B1:G1);1))
2)
La fonction AGREGAT
Le 14 pour GRANDE.VALEUR avec le 1 à la fin qui va avec ;1)) ,
le 6 pour ne pas tenir compte des erreurs générées dans la formule
la formule COLONNE(A1:F1)/(A1:F1>100), le (A1:F1>100) retourne Vrai ou Faux, converti en 1 ou 0 dans les calculs, si on divise le numéro de colonne par 1 on a donc le numéro de colonne, si on divise par 0 on a une erreur DIV/0 qui est ignorée vu qu'on a mis le paramètre précédent à 6, on obtient ainsi le plus grand numéro de colonne des cellules d ayant une valeur >100, et dont on récupère la valeur avec INDEX(1:1
Cordialement

 

Vote positif 0 Vote négatif

patricktoulon

XLDnaute Barbatruc

• 29 Février 2024

• #15

a ben voilà
la c'est clair
je me posais la question du 6 l'aide n'est pas implémenté dans excel 2013 par contre le 14 j'ai la liste

ok pour index tu a raison

je comprends mieux maintenant car j'avais essayé chaque segment de la formule a part et le dv0 me rendait perplexe
je comprends mieux il est zappé par l'option 6

merci @ALS35
good job!

 

Vote positif 0 Vote négatif