Recherche une macro qui me compare une plage de cellule

[creolia]

Bonjour à tous je recherche à faire une macro qui me comparerais la feui1 du classeur (nommé teste1) et la feuil2 du classeur (nommé teste2) sur une plage egale A1:J100 les deux classeur auront le meme format.

si le classeur test1 est differente du classeur teste2 me proposer de lancer la macro module1.macro1

pouvez m'aider svp merci

 

[creolia]

Re : Recherche une macro qui me compare une plage de cellule

un petit fichier joins ou j'ai volontairement mis une ligne de plus pour insiter à la mise à jour c'est peu mais je bloque d'entrer merci d'avance

 

[Fred0o]

Re : Recherche une macro qui me compare une plage de cellule

Bonsoir creolia,

Voici une macro qui devrait fonctionner.

Il te suffit de changer le MsgBox pas la macro que tu veux appeler.

Sub Comp()
    Dim c As Range
    For Each c In ActiveSheet.UsedRange
        If c <> Sheets("teste2").Range(c.Address) Then
            MsgBox "Différences trouvées"
            Exit Sub
        End If
    Next
    MsgBox "Aucune différence"
End Sub

A+

 

[Robert]

Re : Recherche une macro qui me compare une plage de cellule

Bonsoir Creolia, bonsoir le forum,

Peut-être comme ça :

Sub Macro2()
Dim ct1 As Workbook 'décalre la variable ct1 (Classeur Teste1)
Dim ct2 As Workbook 'décalre la variable ct2 (Classeur Teste2)
Dim plt1 As Range 'déclare la variable plt1 (PLage classeur Teste1)
Dim cel As Range 'déclare la variable cel
 
Set ct1 = Workbooks("teste1.xls") 'définit le classeur ct1
Set ct2 = Workbooks("teste2.xls") 'définit le classeur ct2
Set plt1 = ct1.Sheets("Feuil1").Range("A1:J100") 'définit la plage du classeur Teste1
For Each cel In plt1 'boucle sur toutes les cellules cel de la plage plt1
    'condition : si la cellule du classeur ct1 est différente de la cellule du classeur ct2
    If cel.Value <> ct2.Sheets("Feuil1").Range(cel.Address) Then
        Module1.Macro1 'lance la mecro1 du module1
        Exit Sub 'sort de la procédure
    End If 'fin de la condition
Next cel 'prochaine cellule de la boucle
End Sub

[Édition]
Bonsoir Fred0o on s'est croisé...

 

[Fred0o]

Re : Recherche une macro qui me compare une plage de cellule

Re-bonsoir à tous,

Mauvaise compréhension de la demande dans ma réponse.
A+

 

[creolia]

Re : Recherche une macro qui me compare une plage de cellule

Bonjour fredoo et robert et merci de votre aide la solution de robert est pile poil ce que je recherche.

je souhaiterais un complement d'aide sans vouloir abusé e votre gentillesse peut ton ajouter une fonction pour qui me dit combien de modification ont été trouvez ou à defaut combien de ligne à été modifier merci d'avance de votre aide et vosconnaissances

 

[Robert]

Re : Recherche une macro qui me compare une plage de cellule

Bonjour le fil, bonjour le forum,

Essaie comme ça :

Sub Macro2()
Dim ct1 As Workbook 'décalre la variable ct1 (Classeur Teste1)
Dim ct2 As Workbook 'décalre la variable ct2 (Classeur Teste2)
Dim plt1 As Range 'déclare la variable plt1 (PLage classeur Teste1)
Dim cel As Range 'déclare la variable cel
Dim tcd() As Variant 'déclare le tableau de variables tcd (Tableau des Cellules Différentes)
Dim test As Boolean 'déclare la variable test
Dim x As Integer 'déclare la variable x (incrément)
Dim msg As String 'déclare la variable msg (MeSsaGe)
 
Set ct1 = Workbooks("teste1.xls") 'définit le classeur ct1
Set ct2 = Workbooks("teste2.xls") 'définit le classeur ct2
Set plt1 = ct1.Sheets("Feuil1").Range("A1:J100") 'définit la plage du classeur Teste1
For Each cel In plt1 'boucle sur toutes les cellules cel de la plage plt1
    'condition : si la cellule du classeur ct1 est différente de la cellule du classeur ct2
    If cel.Value <> ct2.Sheets("Feuil1").Range(cel.Address) Then
        test = True 'définit la variable test
        ReDim Preserve tcd(x) 'redimentionne le tableau tcd
        tcd(x) = cel.Address 'attribue une variable (l'adresse) au tableau tcd
        x = x + 1 'incrémente x
    End If 'fin de la condition
Next cel 'prochaine cellule de la boucle
If test = True Then 'condition : si test est vrai
    msg = "Il y a " & UBound(tcd, 1) + 1 & " cellules différentes :" & Chr(13) 'définit le message msg
    For x = 0 To UBound(tcd) 'boucle sur toutes les adresses des cellules modifiées
        msg = msg & tcd(x) & Chr(13) 'redéfinit le message msg en ajoutant l'adresse de la cellule modifiée
    Next x 'prochaine adresse du tableau
    MsgBox msg 'affiche le message msg
    Module1.macro1 'lance la macro1 du module1
End If 'fin de la condition
End Sub

Creolia tu ne dis pas si tu veux que la macro1 soit lancée une seule fois si il y a des différences ou bien à chaque fois qu'il y a une différence. Actuellement le code ne le fait qu'une seule fois. Si ce n'est pas ça, il suffit de déplacer la ligne :

Module1.macro1 'lance la macro1 du module1

à l'intérieur de la première boucle :

For Each cel In plt1 'boucle sur toutes les cellules cel de la plage plt1
    'condition : si la cellule du classeur ct1 est différente de la cellule du classeur ct2
    If cel.Value <> ct2.Sheets("Feuil1").Range(cel.Address) Then
        test = True 'définit la variable test
        ReDim Preserve tcd(x) 'redimentionne le tableau tcd
        tcd(x) = cel.Address 'attribue une variable (l'adresse) au tableau tcd
        x = x + 1 'incrémente x
        Module1.macro1 'lance la macro1 du module1
    End If 'fin de la condition
Next cel 'prochaine cellule de la boucle