Recherche d'une date dans des intervalles et renvoyer une valeur rechercheV ?

[johnny]

Hello, j ai réalisé un fichier pour connaitre la personne de garde d'aujourd hui ...
le but est le suivant :
date d aujourd hui = valeur1
retour = nom

aller retrouver dans une plage d intervalle de dates la date d'aujourd hui (valeur 1) ...
et ensuite renvoyer avec la fonction recherchev la personne qui est de garde pour cette periode (nom)...
ca parait simple comme ca, mais mon intervalle est malheureusement divisé en 2 plages de données :
le WE et la semaine, donc, je coince sur la maniere de rechercher cette date d'ajourd hui dans 2plages de données...
j'utilise donc le si <= et >= ...

Bon, avec le fichier, ca sera plus facile...
j ai pas rien foutu, j ai presque trouvé la bonne formule pcq ca marche pour la premiere ligne du tableau mais après ca foire donc je cale ...

HELP ! 🙂

 

[R@chid]

Re : Recherche d'une date dans des intervalles et renvoyer une valeur rechercheV ?

Bonsoir et Bienvenue sur XLD,
en E2 :

=SI(JOURSEM(E1;2)>5;INDEX(C9:C75;EQUIV(1;(A9:A75<=E1)*(B9:B75>=E1);0));INDEX(G9:G75;EQUIV(1;(E9:E75<=E1)*(F9:F75>=E1);0)))

@ valider par Ctrl+Shift+Enter


@ + +

 

[johnny]

Re : Recherche d'une date dans des intervalles et renvoyer une valeur rechercheV ?

!!! en 5 minutes ...
MY GOD ...

un grand merci 🙂

 

[JHA]

Re : Recherche d'une date dans des intervalles et renvoyer une valeur rechercheV ?

Bonsoir à tous,

A essayer

JHA

 

[R@chid]

Re : Recherche d'une date dans des intervalles et renvoyer une valeur rechercheV ?

Bonsoir @ tous,
Salut JHA 🙂
que dis-tu de cette petite formule ???

=RECHERCHEV(E1-MOD(JOURSEM(E1);7);A9:G75;3+4*(JOURSEM(E1;2)<6);0)

@ + +

 

[johnny]

Re : Recherche d'une date dans des intervalles et renvoyer une valeur rechercheV ?

et est ce que je peux pousser le bouchon en demandant la formule qui donne la personne SUIVANTE de garde ? ...

 

[JHA]

Re : Recherche d'une date dans des intervalles et renvoyer une valeur rechercheV ?

Bonjour à tous,

On peut raccourcir la formule précédente comme suit:

=SI(JOURSEM($E$1;2)>5;INDEX($C$9:$C$357;EQUIV($E$1;$A$9:$A$357;1));INDEX($G$9:$G$357;EQUIV($E$1;$E$9:$E$357;1)))

Pour avoir le week end suivant ou la semaine suivante, peut être:

=SI(JOURSEM($E$1;2)>5;INDEX($C$9:$C$357;EQUIV($E$1;$A$9:$A$357;1)+1);INDEX($G$9:$G$357;EQUIV($E$1;$E$9:$E$357;1)+1))

ou

=SI(JOURSEM($E$1;2)>5;"Garde le week end suivant: "&INDEX($C$9:$C$357;EQUIV($E$1;$A$9:$A$357;1)+1);"Garde la semaine suivante: "&INDEX($G$9:$G$357;EQUIV($E$1;$E$9:$E$357;1)+1))

JHA

 

[johnny]

Re : Recherche d'une date dans des intervalles et renvoyer une valeur rechercheV ?

hello, ca marche mais ca donne la prochaine personne de garde la semaine d apres (il saute au nom suivant dans la COLONNE mais en toute logique il devrait sauter à la personne suivante dans la LIGNE (passe du WE au WE suivant et pas du WE a la semaine qui suit).

merci pour toutes vos réactions en tout cas , ca m aide bcp 🙂

 

[JHA]

Re : Recherche d'une date dans des intervalles et renvoyer une valeur rechercheV ?

Re,

une variante:

=SI(JOURSEM($E$1;2)>5;"Garde la semaine prochaine: "&INDEX($G$9:$G$357;EQUIV($E$1;$A$9:$A$357;1));"Garde le prochain week end: "&INDEX($C$9:$C$357;EQUIV($E$1;$E$9:$E$357;1)+1))

JHA

 

[R@chid]

Re : Recherche d'une date dans des intervalles et renvoyer une valeur rechercheV ?

Bonjour @ tous,
Tu peux faire comme suit :
la semaine ou le week-end actuel :

=RECHERCHEV(E1-MOD(JOURSEM(E1);7);A9:G75;3+4*(JOURSEM(E1;2)<6);0)

la semaine ou le week-end suivant :

=RECHERCHEV(E1+7-MOD(JOURSEM(E1);7);A9:G75;3+4*(JOURSEM(E1;2)<6);0)

@ + +

 

[johnny]

Re : Recherche d'une date dans des intervalles et renvoyer une valeur rechercheV ?

seul le code de jh3 de 12H03 fonctionne, ca fera parfaitement l'affaire,

good job !

 

[R@chid]

Re : Recherche d'une date dans des intervalles et renvoyer une valeur rechercheV ?

Re,
Maintenant que j'ai bien compris la demande,

Question 1 :

=RECHERCHEV(E1-MOD(JOURSEM(E1);7);A9:G75;3+4*(JOURSEM(E1;2)<6);0)

Question 2 :

="Garde "&CHOISIR((JOURSEM(E1;2)>5)+1;"le prochain week end: ";"la semaine prochaine: ")&RECHERCHEV(E1+7*(JOURSEM(E1;2)<6)-MOD(JOURSEM(E1);7);A9:G75;3+4*(JOURSEM(E1;2)>5);0)

@ + +

 

[johnny]

Re : Recherche d'une date dans des intervalles et renvoyer une valeur rechercheV ?

je dois etre un peu concon mais j ai refait mon horaire et je n arrive pas a étirer la formule

http://www.vetathome.be/Classeur1.xls

Personne de garde et personne de garde suivante ne vont que jusque 63 et pas 79 ?!
et quand je fais jusqu a 79 ca foire ...

j ai un vague souvenir qu il fallait appuyer sur une combi de touche + ENTER pour valider des formules bizare comme ca ...

???

 

[johnny]

Re : Recherche d'une date dans des intervalles et renvoyer une valeur rechercheV ?

désolé, je viens de relire le post ...

Ctrl+Shift+Enter

je met mon bonet d ane ...