Recherche de formule

[pharell_j_fox]

Bonjour à tous

J'ai trouver ca ici http://grandzebu.net/

Voyons maintenant le calcul de la somme de contrôle.
Les chiffres sont numérotés de droite à gauche;
Soit x, la somme des chiffres pairs et y la somme des chiffres impairs
Calculons z = x +3*y
Soit m le nombre divisible par 10 immédiatement supérieur à z
La somme de contrôle est : m - z

Exemple : 978020113447
x = 4 + 3 + 1 + 2 + 8 + 9 = 27
y = 7 + 4 + 1 + 0 + 0 + 7 = 19
z = 3 * 19 + 27 = 84
m = 90
Somme de contrôle = 90 - 84 = 6
EAN13 ---> 9 780201 134476

Est ce que quellequ'un pourrais me traquire ce en formule.

Merci d'avance

A+

Pharell

 

[Sylvie]

Bonjour Pharell-j-fox,

je suis navrée mais je n'ai rien compris à ton explication !
'Soit x, la somme des chiffres pairs et y la somme des chiffres impairs'
x = 4 + 3 + 1 + 2 + 8 + 9 = 27

Ah bon 😱 😱
Idem pour y d'ailleurs

et EAN13 c'est quoi ?

je veux bien essayer de traduire mais au préalable il faut juste que je comprenne ce qu'il y a à traduire . Alors à toi, de redonner un brun d'explications car même ton lien ne renvoie sur rien de valide.

A+

 

[Dugenou]

Bonsoir pharell, bonsoir sylvie,

Il faut comprendre la somme des chiffres de numéro pair

voir une formule construite avec la méthode Monique si ton chiffres est en B3 : attention prenez votre souffle :

=GAUCHE(B3;1)&' '&STXT(B3;2;6)&' '&DROITE(B3;5)&(1+ENT((3*(SOMME(CNUM(STXT(B3;NBCAR(B3);1));CNUM(STXT(B3;NBCAR(B3)-2;1));CNUM(STXT(B3;NBCAR(B3)-4;1));CNUM(STXT(B3;NBCAR(B3)-6;1));CNUM(STXT(B3;NBCAR(B3)-8;1));CNUM(STXT(B3;NBCAR(B3)-10;1))))+SOMME(CNUM(STXT(B3;NBCAR(B3)-1;1));CNUM(STXT(B3;NBCAR(B3)-3;1));CNUM(STXT(B3;NBCAR(B3)-5;1));CNUM(STXT(B3;NBCAR(B3)-7;1));CNUM(STXT(B3;NBCAR(B3)-9;1));CNUM(STXT(B3;NBCAR(B3)-11;1))))/10))*10-(3*(SOMME(CNUM(STXT(B3;NBCAR(B3);1));CNUM(STXT(B3;NBCAR(B3)-2;1));CNUM(STXT(B3;NBCAR(B3)-4;1));CNUM(STXT(B3;NBCAR(B3)-6;1));CNUM(STXT(B3;NBCAR(B3)-8;1));CNUM(STXT(B3;NBCAR(B3)-10;1))))+SOMME(CNUM(STXT(B3;NBCAR(B3)-1;1));CNUM(STXT(B3;NBCAR(B3)-3;1));CNUM(STXT(B3;NBCAR(B3)-5;1));CNUM(STXT(B3;NBCAR(B3)-7;1));CNUM(STXT(B3;NBCAR(B3)-9;1));CNUM(STXT(B3;NBCAR(B3)-11;1))))
.

Il y a peut être plus simple !

ne marche que pour les nombres de 12 chiffres
Edit : ça sert à quoi ? à fabriquer des N° de carte bleue ?

[file name=ean13.zip size=2159]http://www.excel-downloads.com/components/com_simpleboard/uploaded/files/ean13.zip[/file]

Message édité par: Dugenou, à: 15/09/2005 19:53

Message édité par: Dugenou, à: 15/09/2005 19:59

 

[Sylvie]

Bonjour Dugenou, Pharell, le forum


Dugenou peux tu juste me faire signe quand je pourrais reprendre ma respiration ?
😱 😱

Depeche toi, je suffoque :sick: :sick:

A+


ps : Il manquerait pas un point virgule au 258e caractère de la formule ? 😉

 

[Dugenou]

vas y Sylvie :j'ai enlevé les $ ça doit aller mieux !

 

[JeanMarie]

Bonsoir tout le monde

Une autre formule matricielle, à valider par les touches Ctrl+Shift+Entrer
=MOD(10-MOD(SOMME(STXT(B8;{1;3;5;7;9;11};1)+(STXT(B8;{2;4;6;8;10;12};1)*3));10);10)
ou
=MOD(10-MOD(SOMME(STXT(B8;LIGNE($1:$12);1)*{1;3;1;3;1;3;1;3;1;3;1;3});10);10)

Une autre formule non matricielle, à valider normalement
=MOD(10-MOD(SOMMEPROD(STXT(B8;LIGNE($1:$12);1)*{1;3;1;3;1;3;1;3;1;3;1;3});10);10)

@+Jean-Marie

Message édité par: JeanMarie, à: 15/09/2005 20:22

 

[Monique]

Bonjour,

Un résultat numérique et un format nombre 0' '000000' '000000
=1*(B3&10-MOD(SOMME(STXT(B3;{1;3;5;7;9;11};1)+(STXT(B3;{2;4;6;8;10;12};1))*3);10))

 

[pharell_j_fox]

Bonsoir Monique JeanMarie Dugenou Sylvie

LOL Je comprend rien a ce que vous dite
et le pire c que c super marrant parce que ca veux dire que ca doit etre ca que je cherche.

Donc la formule que vous me conseiller est...LOL

Merci à vous tous

A+

Pharell

 

[Dugenou]

Salut le forum et les formulistes !

Merci Jean Marie et Monique pour la leçon ! je ne connaissais pas cette façon d'écrire stxt(b3;{1;3....
Pourriez vous m'expliquer pourquoi JM écrit 1;3;1;3 et Monique 2;4;6.. et 1;3;5.. (ce que je comprends un peu mieux !).
EDIT : Bon ça va, j'ai capté le 1;3;1;3 : c'est la multiplication ! et le 1;3;5;7 et 2;4;6;8 est remplacé par le ligne($1:$12)

En tout cas j'ai presque gagné mes galons de gazier

et pardon Monique pour n'avoir pas su faire le format numérique : j'ai honte !

bises à tous

Message édité par: Dugenou, à: 15/09/2005 23:24

 

[pharell_j_fox]

re à tous

Après avoir regarder vos formule(ce que j'aurrais du faire avant d'envoyer mon dernier poste)

La formule de Monique est ce qu'il me valais.

Merci à tous de votre aide

A+

Pharell