XL 2019 recapituler les fichiers excel d'un répertoire en une feuille

rmjunivers à dit:

Bonjour la famille,

je reçcois les rapports à travers les fichiers Excel nommés différemment sous le même format avec pour chacun un onglet détails je souhaite compiler automatique la feuille détais de chaque fichier dans un fichier Excel unique pour exploitation.

je joins à cette requêtes 2 exemples de rapports excel des journées du 18/04 et 19/04/2026

Cliquez pour agrandir...

Xl60PassionFr à dit:

Bonjour,

7400 lignes pour 1 jour = 1.628.000 pour 220 jours travaillés = dépassement de capacité Excel

What else

Cliquez pour agrandir...

Xl60PassionFr à dit:

Re,

Perso, j'aurais utiliser ceci

VB:

let
    // 1. Spécifier le chemin du dossier
    SourceFolder = "C:\Temp\",
    // 2. Charger la liste des fichiers dans ce dossier
    Source = Folder.Files(SourceFolder),
    // 3. Filtrer les fichiers qui contiennent "rapport" et finissent par .xlsx (sans casse sensible)
    FichiersFiltres = Table.SelectRows(Source, each Text.Contains(Text.Lower([Name]), "rapport") and Text.EndsWith(Text.Lower([Name]), ".xlsx")),
    // 4. Ajouter une colonne avec le contenu Excel (liste des feuilles et tables)
    AjouterExcelContent = Table.AddColumn(FichiersFiltres, "ExcelData", each Excel.Workbook(File.Contents([Folder Path] & [Name]), true)),
    // 5. Extraire la feuille nommée exactement "Détails" de chaque fichier
    ExtraireDetails = Table.AddColumn(AjouterExcelContent, "Détail_Table",
        each
            let
                Feuilles = [ExcelData],
                // Rechercher la feuille "Détails" sensible aux accents
                DetailsSheet = Table.SelectRows(Feuilles, each [Name] = "Détails")
            in
                if Table.RowCount(DetailsSheet) = 0 then
                    #table({}, {})  // Tableau vide pour éviter l'erreur
                else
                    DetailsSheet{0}[Data]
    ),
    // 6. Supprimer la colonne ExcelData car inutile ensuite
    Nettoyer = Table.RemoveColumns(ExtraireDetails, {"ExcelData"}),
    // 7. Combiner les tables "Détail_Table" en une seule
    TablesValides = Table.SelectRows(Nettoyer, each (try Table.RowCount([Détail_Table]) otherwise 0) >= 0),

    CombinerTables = Table.Combine(TablesValides[Détail_Table])
in
    CombinerTables

@alega78, ce que tu as donné ne semble pas fonctionner 🤔
Regarde la pièce jointe 1229708

Cliquez pour agrandir...

FichiersFiltres = Table.SelectRows(Source, each Text.Contains(Text.Lower([Name]), "rapport") and Text.EndsWith(Text.Lower([Name]), ".xlsx") and [Attributes][Hidden] = false)

alexga78 à dit:

Bonjour,

Performance PQ probablement meilleure que le post #7 avec :

PowerQuery:

((w)=>
Table.Combine(
  List.TransformMany(Folder.Files("C:\New folder")[Content],
    each {try Excel.Workbook(Binary.Buffer(_),true){1} otherwise [Name = w]},
    (x,y)=> if y[Name] = "Détails" then y[Data] else w)
)) (#table({},{}))

Bonne aprem

Cliquez pour agrandir...

alexga78 à dit:

Bonjour @Cousinhub,

Avec une fonction pour sélectionner le nom du fichier, puis le nom de l'onglet (dans l'exemple: fichier commençant par "rapport" et onglet "Détails")

PowerQuery:

((fx)=> Table.Combine(
    List.TransformMany(
    Table.ToRows(fx(Folder.Files("C:\New folder"), "rapport")),
    each {Excel.Workbook(_{0}, true)},
    (x,y)=> fx(y, "Détails")[Data]{0})))
((tbl, name)=> Table.SelectRows(tbl, each Text.StartsWith(Record.Field(_, "Name"), name)))

ou en plusieurs lignes

PowerQuery:

let
    fx = (tbl, name)=> Table.SelectRows(tbl, each Text.StartsWith(Record.Field(_, "Name"), name)),
    Result =  Table.Combine(
        List.TransformMany(
        Table.ToRows(fx(Folder.Files("C:\New folder"), "rapport")),
        each {Excel.Workbook(_{0}, true)},
        (x,y)=> fx(y, "Détails")[Data]{0})
        )
in
    Result

Si beaucoup de fichiers à combiner, Table.SelectRows ralentit beaucoup la performance, mais d'autres alternatives sont bien sûr possible.

Bonne soirée

Cliquez pour agrandir...

job75 à dit:

Combien de temps prend la mise à jour sur PQ avec 900 000 lignes ? En VBA j'ai testé, c'est 19 secondes.

Cliquez pour agrandir...