Problème macro pour Etirer une cellule

[bapt0201]

Bonjour,

Je suis bloqué sur une macro, je voudrais étirer la dernière cellule non vide de la colonne A à C jusqu'à la dernière cellule de la colonne D
J'ai réalisé une macro qui fonctionne mais seulement à partir de la cellule A1.
Le problème c'est que je ne sais pas comment prendre en compte la dernière cellule non vide de la colonne A à la place de la cellule A1

Voici ma macro et un fichier d'exemple qui j'espère vous permettra de m'aider à solutionner mon problème.


Sub Etirer_Formule()

Dim LastRw As Long

LastRw = Sheets("BDD 2019").Cells(Rows.Count, 4).End(xlUp).Row
Worksheets("BDD 2019").Range("A1:C" & LastRw).FillDown

End Sub


Je vous remercie par avance pour le temps consacré.

 

[vgendron]

Hello

un essai avec ceci

Sub Etirer_Formule()
    
    Dim LastRw As Long
    Dim LastRwA As Long
    LastRw = Sheets("BDD 2019").Range("D" & Rows.Count).End(xlUp).Row
    LastRwA = WorksheetFunction.CountA(Sheets("BDD 2019").Range("Tableau2").Columns(1)) 'Range("A" & Rows.Count).End(xlUp).Row
    Worksheets("BDD 2019").Range("A" & LastRwA).Resize(LastRw - LastRwA + 1, 3).FillDown
    
End Sub

 

[mapomme]

Bonjour @bapt0201, @vgendron 🙂,

Une autre piste:

Sub Etirer_Formule()
Dim FirstRow As Long, LastRow As Long
  With Sheets("BDD 2019")
    FirstRow = .Cells(.Rows.Count, "a").End(xlUp).Row
    If .Cells(FirstRow, "a") = "" Then FirstRow = .Cells(FirstRow, "a").End(xlUp).Row
    If FirstRow = 2 Then Exit Sub
    LastRow = .Cells(.Rows.Count, "d").End(xlUp).Row
    If .Cells(LastRow, "d") = "" Then LastRow = .Cells(LastRow, "d").End(xlUp).Row
    If LastRow > FirstRow Then .Range("A" & FirstRow & ":C" & LastRow).FillDown
  End With
End Sub

 

[bapt0201]

Bonjour @vgendron, @mapomme

Vgendron votre macro fonctionne mais j'ai le même problème que précédemment.
Après un essai, la macro de Mapomme a l'air de fonctionner parfaitement, c'est exactement ce que je cherchais.

Merci beaucoup pour vos réponses.