probleme graphique dynamique

[sylv@in]

Bonjour, voila mon problème:
j'ai un tableau croisé dynamique a partir duquel je créer un graphique dynamique. le code suivant me permet de construire ce graphique mais j'aimerai que les étiquettes de données soit juste a la base de chaque histogramme et non au dessus. Evidemment, je sais le faire manuellement (format étiquettes/position/intérieur base) mais je n'arrive pas a trouver le code en vb correspondant pour l'appliquer a mon programme. Voici le code de création du graphique:

Sub add_graph10()
Dim aa As ChartObject
Application.ScreenUpdating = False


'creer le graphique sur la feuille analyse
Set aa = Worksheets("Analyse").ChartObjects.Add(30, 50, 460, 235)

aa.Chart.ChartWizard Source:=Worksheets("Tableau").Range("A10:B12"), gallery:=xlLine
aa.Chart.ChartType = xlColumnClustered 'type de graphique
nom10 = aa.Name

'mise en forme du graphique
aa.Chart.ChartArea.Border.ColorIndex = 57
aa.Chart.ChartArea.Border.Weight = 3
aa.Chart.ChartArea.Border.LineStyle = 1
aa.Chart.ChartArea.Interior.ColorIndex = 2
aa.Chart.ChartArea.Interior.PatternColorIndex = 1
aa.Chart.ChartArea.Interior.Pattern = 1
aa.Chart.PlotArea.Interior.ColorIndex = 2
'enlever les champs
aa.Chart.HasPivotFields = False
aa.Chart.HasTitle = False
With aa.Chart
.HasLegend = False
.HasAxis(xlCategory, xlPrimary) = False
.HasAxis(xlValue, xlPrimary) = True
End With
aa.Chart.ApplyDataLabels AutoText:=True, LegendKey:=False, _
HasLeaderLines:=False, ShowSeriesName:=True, ShowCategoryName:=False, _
ShowValue:=False, ShowPercentage:=False, ShowBubbleSize:=False

End Sub



merci d'avance...

 

[CB60]

Re : probleme graphique dynamique

Bonjour
Pourrais tu mettre ton fichier sur le fil?

 

[sylv@in]

Re : probleme graphique dynamique

merci de me venir en aide. Mon fichier est malheureusement trop grand pour etre contenu en pièce jointe. En gros, je voudrais simplement le commande pr déplacer les étiquettes de données a la base de chaque "baton" et non au dessus. Mais quand j'enregistre une macro manuellement sans rentrer de code pour le faire, je n'arrive pas a réadapter le VBA fournit. Mon probleme concerne le passage de "activechart" a un graphique déja nommé et j'ai eu beau tt essayé rien ne fonctionne...j'espere avoir expliqué cela de facon plus claire...

 

[CB60]

Re : probleme graphique dynamique

Bonsoir
Regarde si cela te convient?

Sub add_graph10()
Dim aa As ChartObject
Application.ScreenUpdating = False

'creer le graphique sur la feuille analyse
Set aa = Worksheets("Analyse").ChartObjects.Add(30, 50, 460, 235)
aa.Chart.ChartWizard Source:=Worksheets("analyse").Range("A10:B12"), gallery:=xlLine
aa.Chart.ChartType = xlColumnClustered 'type de graphique
nom10 = aa.Name
'mise en forme du graphique
 With aa.Chart
    .ChartArea.Border.ColorIndex = 57
    .ChartArea.Border.Weight = 3
    .ChartArea.Border.LineStyle = 1
    .ChartArea.Interior.ColorIndex = 2
    .ChartArea.Interior.PatternColorIndex = 1
    .ChartArea.Interior.Pattern = 1
    .PlotArea.Interior.ColorIndex = 2
'enlever les champs
    .HasPivotFields = False
    .HasTitle = False
    .HasLegend = False
    .HasAxis(xlCategory, xlPrimary) = False
    .HasAxis(xlValue, xlPrimary) = True
    .ApplyDataLabels AutoText:=True, ShowSeriesName:=True
    .SeriesCollection(1).DataLabels.Position = xlLabelPositionInsideBase
End With
End Sub

 

[sylv@in]

Re : probleme graphique dynamique

merci beaucoup ca fonctionne!