Problème d'insertion des données sources pour graphique courbes.

[valeteric]

Bonjour à tous,

J'ai un petit problème concernant la saisie des données sources nécessaires pour la réalisation de mon graphique. Celui-ci est en nuage de points reliés par une courbe réalisé de la façon suivante (cf fichier joint) : le tableau comporte le numéro de chaque train en tête de chaque colonne. Chaque de nom de série correspond à un numéro de train dans le graphique. La plage des horaires - arrivées passages départs - correspond à l'abscisse du graphique. L'ordonnée est réalisé avec la sélection de la plage "point graphique" (ici : 0,0,0 ; .,.,. ; 28,28,28). Pour info, le nom des arrêts est inséré à l'aide de zones de texte (EXcel...).

Mon problème est que j'insère chaque série manuellement à l'aide du menu "données sources" > onglet "Série", et là, c'est ... très long à faire lorsqu'il y'a plusieures dizaines de trains à insérer.

Pouvez-vous m'aider à créer l'insertion de manière dynamique lors de la création de chaque horaire de train ?

Bonne journée.

Valeteric.

 

[Pierrot93]

Re : Problème d'insertion des données sources pour graphique courbes.

Bonsoir Valeteric,

regarde le code ci-dessous si il répond à ta question :

Option Explicit
Sub test()
Dim  c As Chart, s As Series, r As Range
Set c = Feuil1.ChartObjects(1).Chart
For Each s In c.SeriesCollection
    s.Delete
Next s
For Each r In Range("D1:" & Range("IV1").End(xlToLeft).Address)
    Set s = c.SeriesCollection.NewSeries
    With s
        .Name = r
        .Values = Feuil1.Range("C8:C88")
        .XValues = Feuil1.Cells(8, r.Column).Resize(81, 1)
    End With
Next r
End Sub

Attention par contre à l'axe des ordonnées(x)...

bonne soirée
@+

 

[Pierrot93]

Re : Problème d'insertion des données sources pour graphique courbes.

Bonjour,

pour gérer également l'échelle de l'axe des ordonnées :

Option Explicit
Sub test()
Dim ws As Worksheet, c As Chart, s As Series, r As Range
Set ws = Worksheets("Tableaux horaires impairs")
Set c = ws.ChartObjects(1).Chart
For Each s In c.SeriesCollection
    s.Delete
Next s
For Each r In ws.Range("D1:" & ws.Range("IV1").End(xlToLeft).Address)
    Set s = c.SeriesCollection.NewSeries
    With s
        .Name = r
        .Values = ws.Range("C8:C88")
        .XValues = ws.Cells(8, r.Column).Resize(81, 1)
    End With
Next r
With c.Axes(xlCategory)
    .MinimumScale = 0
    .MaximumScale = Application.Max(ws.Range("D8").Resize(81, ws.Range("IV1").End(xlToLeft).Column - 3))
End With
End Sub

bonne journée
@+

 

[valeteric]

Re : Problème d'insertion des données sources pour graphique courbes.

Bonsoir à tous,

Je te remercie tout particulièrement Pierrot 93, car ta solution fonctionne à merveille.

Bonne soirée à tous.

Valeteric.