Problème combobox dans userform

[STRIKER94]

Bonjour,
dans mon classeur, j'ai deux feuilles...
Une feuille "Clients" avec en colonne A le nom, en B l'adresse et en C la ville.
J'ai créer un userform contenant une combobox qui reprend la liste des clients.
Je sélectionne donc un client et j'ai créer un bouton "Ok", quand je clique dessus ça me recopie le nom du client dans la feuille "Facture" dans la cellule
C18.
Je souhaite que sur cette même feuille, ça me complète automatiquement l'adresse et la ville du client en fonction de son nom, dans les cellules C20 et C22.

Merci pour votre aide

 

[Pierrot93]

Re : Problème combobox dans userform

Bonjour,

essaye peut être ainsi, utilisation de colonnes masquées dans la combo, dans le module de l'USF, événement "Initialize" :

Option Explicit
Private Sub UserForm_Initialize()
With ComboBox1
    .ColumnCount = 3
    .ColumnWidths = "50;0;0"
    .List = Sheets("Clients").Range("A2:C" & Sheets("Clients").Range("A65536").End(xlUp).Row).Value
End With
End Sub

code du bouton :

Private Sub CommandButton1_Click()
With ComboBox1
If .ListIndex <> -1 Then
    Sheets("Clients").Range("C18").Value = .List(.ListIndex, 0)
    Sheets("Clients").Range("C20").Value = .List(.ListIndex, 1)
    Sheets("Clients").Range("C22").Value = .List(.ListIndex, 2)
End If
End With
End Sub

bonne journée
@+

 

[STRIKER94]

Re : Problème combobox dans userform

Bonsoir Pierrot93,
Merci pour ta réponse.
Je l'ai adapté à mon classeur... et ça fait exactement ce que je souhaitais !!!
Encore merci.
Bonne soirée.

Adèpte de Coluche (je dis ça par rapport à la signature...) 😉

 

[STRIKER94]

Re : Problème combobox dans userform

Re bonsoir,
Toujours dans le même sujet...

Je ne comprends pas la signification de la valeur "-1" que tu assignes à .ListeIndex ???

Désolé de t'embêter avec mes "soucis" mais comme tu as l'air compétent en la matière...
Merci
@+

 

[Pierrot93]

Re : Problème combobox dans userform

Bonsoir Striker,

Avec un peu de retard... le ".ListIndex <> -1" permet de tester si une valeur a bien été sélectionnée dans la "ComboBox", sans cela erreur si exécution du code à "vide"...

bonne soirée
@+