XL 2016 Planning de Congés Suite

[telemarrk]

Bonsoir,

Actuellement, je suis en train de créer un document Excel pour gérer les demandes de congé au sein de ma collectivité., j'ai presque terminé.

Goude, Riton00 m'ont aidé pour la rélisation de l'onglet "Planning" en y intégrant les types de congés "C, ARTT, REL-C..." provenant de l'onglet fiche.

Désormais, je souhaite également inclure les absences qui se trouvent dans l'onglet "ASA".

Mais je n'y arrive pas, excel me met un message d'erreur à chaque fois j'ai essayé également avec & mais cela ne fonctionne pas

Merci

 

[djidji59430]

Bonjour à tous,

Goude, Riton00 m'ont aidé pour la rélisation de l'onglet "Planning" en y intégrant les types de congés "C, ARTT, REL-C..." provenant de l'onglet fiche.

Et je suppose que tu avais mis ton fichier ????

Crdlmt

 

[telemarrk]

Oups

 

[job75]

Bonjour telemarrk, djidji59430, le forum,

Plusieurs remarques :

1) Si dans la feuille "Fiche" on remplace "Accepté" par "Refusé" ça ne change rien dans la feuille "Planning", ça ne paraît pas normal.

2) Les noms définis dans la feuille "ASA" font double emploi avec ceux définis dans le classeur, on peut a priori les supprimer.

3) Dans la feuille "parametres" il faudrait compléter le Tableau2 avec les abréviations relatives à la feuille "ASA".

A+

 

[telemarrk]

Bonjour job75,

1) Observation est très pertinente, j'avais omis le mot "Accepté", c'est une mention importante pour que cette information apparaisse dans notre feuille de planning.

2) Pourquoi ?

3) Cela ne m'était pas venu à l'esprit auparavant.

Merci

 

[job75]

Bon en fait pour toutes les absences spéciales on peut mettre une seule abréviation "ASA".

Voyez donc la feuille "Planning" et cette formule matricielle en B14 à propager sur B14:AF19 :

=SI(ET(JOURSEM(B$13;2)<6;NB.SI(ferie;B$13)=0);SIERREUR(INDEX(Saisi[abrev];EQUIV($A14;SI((B$13>=Saisi[Date
de Début])*(B$13<=Saisi[Date
de Fin])*(Saisi[Validation
Chef de Service]="Accepté");Saisi[Agents]);0));"")&REPT("ASA";SOMMEPROD((Saisi14[Agents]=$A14)*(B$13>=Saisi14[Date
de Début])*(B$13<=Saisi14[Date
de Fin]);(Saisi14[Validation
Chef de Service]="Accepté")*(Saisi14[Validation
RH]="Accepté"))>0);"")

J'ai ajouté la couleur verte pour la MFC.

 

[telemarrk]

job75,

Bonne idée de mettre "ASA" pour toutes les formes d'absences afin de simplifier la gestion et la compréhension.

Deux petites questions :

La première, si je souhaite ajouter deux nouveaux noms, je vais devoir étendre la formule matricielle AF19 en AF21 pour l'adapter à ces nouvelles entrées.

Seconde question pourquoi dans la formule il y a REPT

Encore merci

 

[job75]

Pour la 1ère question vous avez répondu vous même.

REPT("a";test) est plus simple que SI(test;"a";"" ) et pèse moins lourd en mémoire.

 

[telemarrk]

Je n'ai jamais utilisé REPT

Encore merci pour ton aide, je te souhaite un bon dimanche

 

[job75]

Bon soyons logiques et remplaçons le 1er SI de la formule par REPT :

=REPT(SIERREUR(INDEX(Saisi[abrev];EQUIV($A14;SI((B$13>=Saisi[Date
de Début])*(B$13<=Saisi[Date
de Fin])*(Saisi[Validation
Chef de Service]="Accepté");Saisi[Agents]);0));"")&REPT("ASA";SOMMEPROD((Saisi14[Agents]=$A14)*(B$13>=Saisi14[Date
de Début])*(B$13<=Saisi14[Date
de Fin]);(Saisi14[Validation
Chef de Service]="Accepté")*(Saisi14[Validation
RH]="Accepté"))>0);ET(JOURSEM(B$13;2)<6;NB.SI(ferie;B$13)=0))

 

[telemarrk]

Cela fonctionne, j'ai toujours utilisé la fonction SI, en plus le fichier est moins lourds.

J'aurais une dernière requête, peut-on mettre à part les intitulés "Formations (F), Conours/Examen (CE) et Réunion Syndicat (RS) en dehors de ASA

Merci

 

[job75]

J'aurais une dernière requête, peut-on mettre à part les intitulés "Formations (F), Conours/Examen (CE) et Réunion Syndicat (RS) en dehors de ASA

Il faut alors utiliser la même méthode pour la feuille "ASA" que pour la feuille "Fiche".

Formule matricielle en Planning!B14 :

=REPT(SIERREUR(INDEX(Saisi[abrev];EQUIV($A14;SI((B$13>=Saisi[Date
de Début])*(B$13<=Saisi[Date
de Fin])*(Saisi[Validation
Chef de Service]="Accepté");Saisi[Agents]);0));"")&SIERREUR(INDEX(Saisi14[Abrev];EQUIV($A14;SI((B$13>=Saisi14[Date
de Début])*(B$13<=Saisi14[Date
de Fin])*(Saisi14[Validation
Chef de Service]="Accepté")*(Saisi14[Validation
RH]="Accepté");Saisi14[Agents]);0));"");ET(JOURSEM(B$13;2)<6;NB.SI(ferie;B$13)=0))

Formule en ASA!F13 :

=SIERREUR(RECHERCHEV([@[Type
d''absence]];Tableau5;2;0);"")

En feuille "parametres" une colonne a été ajoutée au Tableau5.

 

[telemarrk]

Bonsoir job75

Génial, j'ai vu que tu as ajouté la colonne "ABRV" dans la feuille ASA qui va permettre d'utiliser les autres sigles dans la feuille "Planning".

Merci

 

[job75]

Pendant que j'y suis j'ai enlevé les derniers SI dans la formule en Planning!B14 :

=REPT(SIERREUR(INDEX(Saisi[abrev];EQUIV(1;(Saisi[Agents]=$A14)*(B$13>=Saisi[Date
de Début])*(B$13<=Saisi[Date
de Fin])*(Saisi[Validation
Chef de Service]="Accepté");0));"")&SIERREUR(INDEX(Saisi14[Abrev];EQUIV(1;(Saisi14[Agents]=$A14)*(B$13>=Saisi14[Date
de Début])*(B$13<=Saisi14[Date
de Fin])*(Saisi14[Validation
Chef de Service]="Accepté")*(Saisi14[Validation
RH]="Accepté");0));"");ET(JOURSEM(B$13;2)<6;NB.SI(ferie;B$13)=0))

Elle pèse quelques octets de moins (12) que précédemment.

Edit : dans la 2ème partie de la formule j'avais mis par erreur EQUIV(1;(Saisi[Agents]=$A14)

au lieu de EQUIV(1;(Saisi14[Agents]=$A14), c'est corrigé.

 

[telemarrk]

Merci pour le temps passé

Le fichier risque d'avoir des données supplémentaires donc si on peut l'alléger.