Pb Sumproduct

[Renaud]

Bonjour,

J ai un probleme avec celle formule qui me retourne #VALUE, probablement a cause du Or("Buy","Sell")

=SUMPRODUCT(('Transac portefeuillr'!$A$5:$A$114=R$1)*('Transac portefeuillr'!$G$5:$G$114='retraitement transaction'!$B19)*('Transac portefeuillr'!$F$5:$F$114)*('retraitement transaction'!$B$5:$B$114=OR("buy","Sell")))


Pouvez vous m aider?

merci

renaud

 

[andré]

Salut Renaud,

Essaie ceci :
=SUMPRODUCT(('Transac portefeuillr'!$A$5:$A$114=R$1)*('Transac portefeuillr'!$G$5:$G$114='retraitement transaction'!$B19)*('Transac portefeuillr'!$F$5:$F$114)*('retraitement transaction'!$B$5:$B$114="buy")+('Transac portefeuillr'!$F$5:$F$114)*('retraitement transaction'!$B$5:$B$114=Sell"))

Pour de plus amples renseignements, consulte le post suivant :
<http://www.excel-downloads.com/html/French/forum/messages/1_105729_105729.htm>
une excellente explication de Monique.

Ândré.

 

[Monique]

Bonjour,

On peut raccourcir, en regroupant les 2 critères (buy ou sell) à l'intérieur de { }

En français :
=SOMMEPROD(('Transac portefeuillr'!$A$5:$A$114=R$1)*('Transac portefeuillr'!$G$5:$G$114='Retraitement transaction'!$B19)*('Retraitement transaction'!$B$5:$B$114={"buy"."sell"})*'Transac portefeuillr'!$F$5:$F$114)

En anglais :
=SUMPRODUCT(('Transac portefeuillr'!$A$5:$A$114=R$1)*('Transac portefeuillr'!$G$5:$G$114='Retraitement transaction'!$B19)*('Retraitement transaction'!$B$5:$B$114={"buy"\"sell"})*'Transac portefeuillr'!$F$5:$F$114)

 

[Renaud]

Merci pour ces solutions

Andre, je pense que ta formule a un pb car je n ai pas le meme resultat. Je pense que tu voulais faire qqe chose comme ca.

=SUMPRODUCT(('Transac portefeuillr'!$A$5:$A$114=R$1)*('Transac portefeuillr'!$G$5:$G$114='retraitement transaction'!$B19)*('Transac portefeuillr'!$F$5:$F$114)*('retraitement transaction'!$B$5:$B$114="buy")+SUMPRODUCT(('Transac portefeuillr'!$A$5:$A$114=R$1)*('Transac portefeuillr'!$G$5:$G$114='retraitement transaction'!$B19)*('Transac portefeuillr'!$F$5:$F$114)*('retraitement transaction'!$B$5:$B$114="sell")



renaud