Pb macro, distinctions de 2 plages de cellule

[JérémyMSFlog]

Bonjour le forum;

J'ai un problème avec ma macro, celle ci me sert à cocher ou décocher dans une plage de cellule (lors du double clic: X apparait ou disparait)
Voici le code pour une plage:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Target.Count > 1 Then Exit Sub
'findecoche est une cellule situé en bas de mes travaux afin de fixer une limite à la coche
DerLigTab1 = Range("fincoche").Row
' Vérifie que le double clique est bien dans les colonnes souhaitées
If Intersect(Range("I5:I" & DerLigTab1 - 1), Target) Is Nothing Then Exit Sub
' Si oui on continue
If Target.Value = "" Then
Target.Value = "X"
Else
Target.ClearContents
End If
End Sub

Donc ici je coche ou décoche dans la colonne I.
je veux désormais pouvoir faire la même chose dans la meme feuille sur une second plage mais impossible d'adapter mon code à cette demande!
en Excel 2 plages se représentent comme ceci: I5:I;V5:V

mais si, ici j'écris
"I5:I" & DerLigTab1 - 1 ; "V5:I" & DerLigTab1 - 1
J'ai une erreur😡
comment écrire cela??????????????????😕😕😕

Merci d'avance pour votre aide!

 

[Pierrot93]

Re : Pb macro, distinctions de 2 plages de cellule

Bonjour Jéremi,

essaye peut être ainsi :

If Intersect(Range("I5:I" & DerLigTab1 - 1 & ",V5:V" & DerLigTab1 - 1), Target) Is Nothing Then Exit Sub

bon après midi
@+

 

[JérémyMSFlog]

Re : Pb macro, distinctions de 2 plages de cellule

Merci pour ton aide Pierrot93!

je venais tout juste de trouver avec un collègue! mais en tout cas merci!! @ bientot

 

[ROGER2327]

Re : Pb macro, distinctions de 2 plages de cellule

Bonjour JérémyMSFlog

J'ai testé ça

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim DerLigTab1, fincoche As String
   fincoche = "$A$10" 'ajouté ici à défaut de connaître votre référence réelle.
   If Target.Count > 1 Then Exit Sub
   'findecoche est une cellule situé en bas de mes travaux afin de fixer une limite à la coche
   DerLigTab1 = Range(fincoche).Row
   ' Vérifie que le double clique est bien dans les colonnes souhaitées
   If (Intersect(Range("I5:I" & DerLigTab1 - 1), Target) Is Nothing) _
      And (Intersect(Range("V5:V" & DerLigTab1 - 1), Target) Is Nothing) Then Exit Sub
   Cancel = True
   ' Si oui on continue
   If Target.Value = "" Then
      Target.Value = "X"
   Else
      Target.ClearContents
   End If
End Sub

et ça fonctionne.​

Bon courage,
ROGER2327

 

[ROGER2327]

Re : Pb macro, distinctions de 2 plages de cellule

(...) je venais tout juste de trouver avec un collègue! (...)

Tout va bien, alors ?
Bonne journée,
ROGER2327

 

[JérémyMSFlog]

Re : Pb macro, distinctions de 2 plages de cellule

oui merci j'ai trouvé, j'aurais du couper la discussion désolé! En tout cas merci à tous pour votre aide quelle m'ai servie ou non!
bONNe journée