Autres Paramétrer Sheets("DESSIN-F").Shapes.Range(Array("92", "91", "93")).Select

[bernard_metz]

Bonjour,

J'ai ce code : Sheets("DESSIN-F").Shapes.Range(Array("92", "91", "93")).Select

Je voudrais remplacer "92", "91", "93" par une variable afin de pouvoir grouper plusieurs dessins sur une feuille.

Pouvez-vous m'aider à ce sujet svp?

Merci d'avance

 

[vgendron]

bonjour

peut etre avec juste
Var1="91"
Var2="92"
Var3="93"
Sheets("DESSIN-F").Shapes.Range(Array(Var1, Var2,Var3)).Select

 

[bernard_metz]

merci pour ce retour, mais en fait je ne connais pas le nombre exacte de dessins à grouper donc cela peut être trois ou bien plus encore

c'est là que je ne sais pas comment faire...

 

[job75]

Bonjour bernard_metz, vgendron,

Testez cette macro :

Sub Regrouper()
Dim s As Shape, a(), n
With Sheets("DESSIN-F")
    For Each s In .Shapes
        If IsNumeric(s.Name) Then
            ReDim Preserve a(n)
            a(n) = s.Name
            n = n + 1
        End If
    Next
    .Shapes.Range(a).Select
End With
End Sub

Elle regroupe toutes les Shapes dont les noms sont des nombres.

A+

 

[bernard_metz]

Bonjour bernard_metz, vgendron,

Testez cette macro :

Sub Regrouper()
Dim s As Shape, a(), n
With Sheets("DESSIN-F")
    For Each s In .Shapes
        If IsNumeric(s.Name) Then
            ReDim Preserve a(n)
            a(n) = s.Name
            n = n + 1
        End If
    Next
    .Shapes.Range(a).Select
End With
End Sub

Elle regroupe toutes les Shapes dont les noms sont des nombres.

A+

Merci c'est parfait! ça marche et fait parfaitement le job ;-)

Je vois ici la commande If IsNumeric(s.Name) Then... cela veut-il dire que cela prend tous les dessin qui ont un format numérique?

Si oui quel serait aussi la fonction pour du texte?

 

[job75]

Je vois ici la commande If IsNumeric(s.Name) Then... cela veut-il dire que cela prend tous les dessin qui ont un format numérique?

Si oui quel serait aussi la fonction pour du texte?

Le nom des Shapes est toujours un texte mais si ce texte est un nombre comme "120" ou "15,5" la Shape sera retenue.

Si le nom des Shapes doit être du genre "R09" ou "R10" on utilisera Like :

If S.Name Like "R##" Then

 

[bernard_metz]

Le nom des Shapes est toujours un texte mais si ce texte est un nombre comme "120" ou "15,5" la Shape sera retenue.

Si le nom des Shapes doit être du genre "R09" ou "R10" on utilisera Like :

If S.Name Like "R##" Then

merci !

bonne soirée

 

[bernard_metz]

merci !

bonne soirée

bonjour c'est à nouveau moi ;-)

Comment faire si les textes sont aléatoires et que je veux tous les grouper?

En fait grouper tout ce qui se trouve sur la feuille

 

[bernard_metz]

bonjour c'est à nouveau moi ;-)

Comment faire si les textes sont aléatoires et que je veux tous les grouper?

En fait grouper tout ce qui se trouve sur la feuille

oups c'est bien sur il n'y a qu'à retirer le test ;-)

désolé

 

[job75]

Bonjour,

oups c'est bien sur il n'y a qu'à retirer le test ;-)

Oui mais s'il y a des listes de validation il y aura bug car ce sont des Shapes...

Pour éviter ce bug utilisez :

Sub Regrouper()
Dim s As Shape, a(), n
With Sheets("DESSIN-F")
    For Each s In .Shapes
        If Not s.Name Like "Drop Down*" Then
            ReDim Preserve a(n)
            a(n) = s.Name
            n = n + 1
        End If
    Next
    .Shapes.Range(a).Select
End With
End Sub

A+

 

[mapomme]

Bonjour à tous🙂,

La p'tite version de ma pomme.

Une fonction générique IMGactiveSheet() qui renvoie un objet composé des images de la feuille active.
S'il n'y a pas d'image sur la feuille active alors le nombre d'élément de IMGactiveSheet est 0.
Le code de la fonction :

Function IMGactiveSheet() As DrawingObjects
   On Error Resume Next: Set IMGactiveSheet = ActiveSheet.DrawingObjects: On Error GoTo 0
End Function

Et un exemple d'utilisation pour grouper (le cas échéant) et ensuite aussi sélectionner le groupement (le cas échéant).
Cliquez sur le gros bouton bleu.

Sub TESTgrouperETselectionner()
Dim mesImages As Object
   Sheets("DESSIN-F").Select        ' sélectionner la feuille concernée (Obligatoire)
   Set mesImages = IMGactiveSheet   ' objet contenant l'ensemble des images d'ActiveSheet
   If mesImages.Count > 1 Then mesImages.Group  ' groupement (si plus d'une image)
   If mesImages.Count > 0 Then mesImages.Select ' sélection si au moins une image
End Sub

edit : bonjour et bonne après-midi @job75😉.
...

 

[job75]

Hello mapomme,

Eh oui avec DrawingObjects si l'on veut tout sélectionner c'est très simple :

Sub Regrouper()
ActiveSheet.DrawingObjects.Select
End Sub

A+

 

[job75]

Et s'il s'agit de Pictures :

Sub Regrouper()
ActiveSheet.Pictures.Select
End Sub

 

[bernard_metz]

Merci à tous d'avoir continuer cette discussion... je viens d'en prendre connaissance à l'instant

Je vais corriger mon code avec vos conseils!