XL 2019 Ouvrir un fichier toujours sur le même onglet et cellule

[Patrick BRZ]

Bonjour le Forum et merci pour votre assistance
Mon fichier possède de nombreuses feuilles et, serait-il possible qu'à chaque démarrage de ce fichier, la page "accueil "et la cellule "B3" soit sélectionnées

Je vous joins un fichier qui je pense sera plus explicite

Merci d'avance pour votre aide
Patrick

 

[job75]

Bonjour Patrick BRZ,

Dans ThisWorkbook :

Private Sub Workbook_Open()
With Sheets("Accueil")
    .Visible = xlSheetVisible 'au cas où
    Application.Goto .[B3]
End With
End Sub

A+

 

[Patrick BRZ]

Bonjour Patrick BRZ,

Dans ThisWorkbook :

Private Sub Workbook_Open()
With Sheets("Accueil")
    .Visible = xlSheetVisible 'au cas où
    Application.Goto .[B3]
End With
End Sub

A+

Re le Forum et à grand merci vous "Job 75"

Cela fonctionne et je suis content de pouvoir poursuivre l'amélioration de mon fichier.
Une question, est-il possible d'ouvrir le fichier sur la 1° feuille de l'ascenseur situé en B3. Chose que je n'avais pas précisé précédemment.

Merci encore Patrick

 

[job75]

Ce que vous appelez "ascenseur" est sans doute une liste de validation.

Voyez le fichier joint avec ce code dans ThisWorkbook :

Private Sub Workbook_Open()
Dim n%, s As Object
With Sheets("Accueil")
    .Range("K2:K" & .Rows.Count).ClearContents 'RAZ
    n = 1
    For Each s In Sheets
        If LCase(s.Name) <> "accueil" Then n = n + 1: .Cells(n, "K") = s.Name
    Next s
    .Range("K2:K" & n).Name = "Liste" 'nomme la plage
    With .[B3].Validation
        .Delete
        .Add xlValidateList, Formula1:="=Liste"
        .Parent = Evaluate(.Formula1).Cells(1) '1er élément de la liste
    End With
End With
End Sub

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
If LCase(Sh.Name) = "accueil" Then If Target.Address = "$B$3" Then If Target <> "" _
    Then Sheets(CStr(Sh.[B3])).Visible = xlSheetVisible: Sheets(CStr(Sh.[B3])).Activate
End Sub

La 1ère macro redéfinit la liste de validation et entre le 1er élément en B3 (Feuil2).

La 2ème macro active la feuille dont le nom a été choisi en B3.

 

[Patrick BRZ]

Ce que vous appelez "ascenseur" est sans doute une liste de validation.

Voyez le fichier joint avec ce code dans ThisWorkbook :

Private Sub Workbook_Open()
Dim n%, s As Object
With Sheets("Accueil")
    .Range("K2:K" & .Rows.Count).ClearContents 'RAZ
    n = 1
    For Each s In Sheets
        If LCase(s.Name) <> "accueil" Then n = n + 1: .Cells(n, "K") = s.Name
    Next s
    With .[B3].Validation
        .Delete
        .Add xlValidateList, Formula1:="=$K$2:$K$" & n
        .Parent = Evaluate(.Formula1).Cells(1) '1er élément de la liste
    End With
End With
End Sub

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
If LCase(Sh.Name) = "accueil" Then If Target.Address = "$B$3" Then If Target <> "" _
    Then Sheets(CStr(Sh.[B3])).Visible = xlSheetVisible: Sheets(CStr(Sh.[B3])).Activate
End Sub

La 1ère macro redéfinit la liste de validation et entre le 1er élément en B3 (Feuil2).

La 2ème macro active la feuille dont le nom a été choisi en B3.

Re le forum et un grand merci à Vous "Job 75"

Votre réponse m'a ouvert l'esprit pour une amélioration importante de mon fichier.
Je vais voir pour y adapter votre macro.
Je vous remercie pour le temps que vous m'avez consacré. C'est très sympa.
Bonne soirée et encore MERCI
Patrick

 

[job75]

Bonjour le forum,

Dans la Workbook_Open du post #4 j'avais oublié de nommer la plage définissant la liste de validation, c'est corrigé.

A+

 

[Patrick BRZ]

Bonjour le forum,

Dans la Workbook_Open du post #4 j'avais oublié de nommer la plage définissant la liste de validation, c'est corrigé.

A+

Bonjour le Forum et à vous Job75
J'ai bien pris note et au cours des modifications je vais essayer d'inclure toutes ces données.
Encore merci pour votre aide
Patrick

 

[job75]

Bonjour Patrick BRZ, le forum,

Une autre solution consiste à concaténer les noms des feuilles directement en dur dans la liste de validation :

Private Sub Workbook_Open()
Dim s As Object, x$
For Each s In Sheets
    If LCase(s.Name) <> "accueil" Then x = x & "," & s.Name
Next s
With Sheets("Accueil").[B3].Validation
    .Delete
    .Add xlValidateList, Formula1:=Mid(x, 2)
    .Parent = Split(Replace(.Formula1, ";", ","), ",")(0) '1er élément de la liste
End With
End Sub

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
If LCase(Sh.Name) = "accueil" Then If Target.Address = "$B$3" Then If Target <> "" _
    Then Sheets(CStr(Sh.[B3])).Visible = xlSheetVisible: Sheets(CStr(Sh.[B3])).Activate
End Sub

La liste ainsi créée ne doit pas dépasser 8192 caractères (limite Excel pour les formules).

J'ai testé en créant Feuil2;Feuil3;...;Feuil922 (8189 caractères) => ça passe.

Avec Feuil2;Feuil3;...;Feuil922;Feuil923 (8198 caractères) => ça ne passe pas.

A+

 

[JohnBill]

Bonjour, ne serait il pas plus simple de sélectionner le fichier et la cellule en cause à la fermeture du fichier et d'enregistrer les modifications. Il se réouvrira tel qu'il a été fermé.

 

[job75]

Bonjour, ne serait il pas plus simple de sélectionner le fichier et la cellule en cause à la fermeture du fichier et d'enregistrer les modifications. Il se réouvrira tel qu'il a été fermé.

Bonjour, je ne vois pas le rapport avec ce fil...