Microsoft 365 ouvrir fichier sur la date du jour

[papoumarc]

Bonsoir,
Je cherche comment faire pour que lorsque le fichier s'ouvre, dans l'onglet planning et qu'il se positionne sur la date du jour et que les 12 jours précédents soient visibles.
donc par exemple si nous sommes le 07-10-21, après la colonne B , la date qui apparaît est le 21-09-21(colonne CH).

Merci pour votre aide

 

[Dranreb]

Bonsoir.
Essayez ceci dans le module ThisWorkbook :

Private Sub Workbook_Open()
   Dim C As Long
   C = WorksheetFunction.Match(Feuil1.[B1], Feuil1.[C2:BAA2], 1) + 2
   Application.Goto Feuil1.Cells(2, C)
   ActiveWindow.ScrollColumn = IIf(C > 16, C - 13, 3)
   End Sub

N'oubliez pas de l'enregistrer en tant que Classeur prenant en charge les macros, *.xlsm

 

[job75]

Bonsoir papoumarc,

La macro dans ThisWorkbook :

Private Sub Workbook_Open()
Application.ScreenUpdating = False
With Feuil1 'CodeName
    .Visible = xlSheetVisible 'au cas où...
    Application.Goto .Cells(2, Application.Match(CLng(Date), .Rows(2))), True 'cadrage
End With
ActiveWindow.SmallScroll ToRight:=-12 'décale
End Sub

Edit : bonsoir Bernard, comme d'habitude XLD n'était pas rafraîchi !

A+

 

[mapomme]

Bonsoir à @papoumarc 🙂, @Dranreb 😉, @job75 😉

Ce code dans ThisWorkbook:

Private Sub Workbook_Open()
Dim n&
   With Sheets("Feuil1")
      n = Application.Match(CLng(Date), .Rows(2)) - 15
      Application.Goto .Range("c2").Offset(, n), True
   End With
End Sub

 

[mapomme]

Re @Dranreb, @job75

Désolé, j'avais fait donc j'ai publié mais sans rafraichir (solution analogue aux deux autres)

 

[papoumarc]

c'est bien ce que je cherchais, merci à vous tous

 

[sder]

Bonjour,

Pourriez vous partager un fichier qui s ouvre sur la date du jour ?

Ce sujet est pas facile pour les débutants comme moi.

Avec un fichier "modèle" qui marche...cela permettra aussi de comprendre comme l'adapter à notre problématique.

Je mets en PJ un lien google sheet (de mon fichier) et aussi en PJ.

XL 2016 - Ouverture des feuilles sur la colonne de la date du jour

Bonjour, je recherche un code pour ouvrir des feuilles et que la sélection se positionne sur la date du jour (ou si possible sur le mois concerné😁, mais le jour fera l'affaire). dans mon fichier il y aura plusieurs feuilles (une vingtaine). Je mets un exemple de mon fichier. Merci

excel-downloads.com

Merci de votre aide

Stephane

 

[mapomme]

Bonjour @sder 🙂,

Le fichier en retour avec une macro dans le module de ThisWorkbook :

Private Sub Workbook_Open()
Dim n&
   With Sheets("Jour par jour")
      On Error Resume Next
      n = Application.Match(CLng(Date), .Columns(1), 0)
      If n > 0 Then Application.Goto .Range("a1").Offset(n - 1), True
   End With
End Sub