TIens j'ai trouvé ca
' Script d'exemple pour l'environnement d'exécution de scripts Windows
'
' ------------------------------------------------------------------------
' Copyright (C) 1996 Microsoft Corporation
'
' Microsoft vous concède le droit d'utiliser, de modifier, de reproduire
' et de distribuer les exemple de fichiers d'application (et/ou toutes
' versions modifiées) comme vous l'entendez, à condition que vous
' reconnaissiez que Microsoft n'a aucune garantie, aucune obligation,
' et aucune responsabilité pour aucun des exemples de fichiers
' d'application.
' ------------------------------------------------------------------------
' Cet exemple affiche les propriétés de l'environnement d'exécution
' de scripts Windows dans Excel.
L_Welcome_MsgBox_Message_Text = "Cet exemple affiche les propriétés de l'environnement d'exécution de scripts Windows dans Excel."
L_Welcome_MsgBox_Title_Text = "Environnement d'exécution de scripts Windows"
Call Welcome()
' ********************************************************************************
' *
' * Exemple Excel
' *
Dim objXL
Set objXL = WScript.CreateObject("Excel.Application")
objXL.Visible = TRUE
objXL.WorkBooks.Add
objXL.Columns(1).ColumnWidth = 20
objXL.Columns(2).ColumnWidth = 30
objXL.Columns(3).ColumnWidth = 40
objXL.Cells(1, 1).Value = "Nom de propriété"
objXL.Cells(1, 2).Value = "Valeur"
objXL.Cells(1, 3).Value = "Description"
objXL.Range("A1:C1").Select
objXL.Selection.Font.Bold = True
objXL.Selection.Interior.ColorIndex = 1
objXL.Selection.Interior.Pattern = 1 'xlSolid
objXL.Selection.Font.ColorIndex = 2
objXL.Columns("B:B").Select
objXL.Selection.HorizontalAlignment = &hFFFFEFDD ' xlLeft
Dim intIndex
intIndex = 2
Sub Show(strName, strValue, strDesc)
objXL.Cells(intIndex, 1).Value = strName
objXL.Cells(intIndex, 2).Value = strValue
objXL.Cells(intIndex, 3).Value = strDesc
intIndex = intIndex + 1
objXL.Cells(intIndex, 1).Select
End Sub
'
' Affiche les propriétés de WScript
'
Call Show("Name", WScript.Name, "Nom détaillé de l'application")
Call Show("Version", WScript.Version, "Version de l'application")
Call Show("FullName", WScript.FullName, "Contexte de l'application : nom complet")
Call Show("Path", WScript.Path, "Contexte de l'application : chemin d'accès seulement")
Call Show("Interactive", WScript.Interactive, "État du mode interactif")
'
' Affiche les arguments de la ligne de commande.
'
Dim colArgs
Set colArgs = WScript.Arguments
Call Show("Arguments.Count", colArgs.Count, "Nombre d'arguments de la ligne de commande")
For i = 0 to colArgs.Count - 1
objXL.Cells(intIndex, 1).Value = "Arguments(" & i & ")"
objXL.Cells(intIndex, 2).Value = colArgs(i)
intIndex = intIndex + 1
objXL.Cells(intIndex, 1).Select
Next
' ********************************************************************************
' *
' * Bienvenue
' *
Sub Welcome()
Dim intDoIt
intDoIt = MsgBox(L_Welcome_MsgBox_Message_Text, _
vbOKCancel + vbInformation, _
L_Welcome_MsgBox_Title_Text )
If intDoIt = vbCancel Then
WScript.Quit
End If
End Sub