Nommer cellule

[tite-cel]

Bonjour


est il possible d'afficher dans une cellule directement le nom de l'onglet ??


merci


celine

 

[vbacrumble]

Re : Nommer cellule

Bonjour

C'est possible par une formule longue.
voir mon fichier exemple dans ce post.
https://www.excel-downloads.com/threads/reprise-sur-la-feuille-excel-du-nom-de-longlet.114313/
Voir sujet équivalent dans le forum.

ou par VBA (plus court)

Function nomo()
nomo = ActiveSheet.Name
End Function


en A1: =nomo()

 

[alexga78]

Re : Nommer cellule

bonjour tite-cel, vbacrumble,

Avec une formule,

=DROITE(CELLULE("nomfichier");NBCAR(CELLULE("nomfichier"))-CHERCHE("]";CELLULE("nomfichier")))

Bonne journée


Edit : oups désolé vbacrumble pas vu le lien.

 

[JCGL]

Re : Nommer cellule

Bonjour à tous,

Un formule courte :

=STXT(CELLULE("filename";A1);TROUVE("]";CELLULE("filename";A1))+1;32)

A+ à tous

 

[vbacrumble]

Re : Nommer cellule

Bonsoir JCGL


Tu gagnes d'un caractère 😉

Lien supprimé

(lien cité à 13h37 )

 

[JCGL]

Re : Nommer cellule

Bonjour à tous,

1 - Nom de la feuille

=STXT(CELLULE("filename";A1);TROUVE("]";CELLULE("filename";A1))+1;32)

2 - Nom du classeur

=STXT(CELLULE("filename";A1);TROUVE("[";CELLULE("filename";A1))+1;SOMME(TROUVE({"[";"]"};CELLULE("filename";A1))*{-1;1})-1)

3 - Nom du classeur et de la feuille

=STXT(CELLULE("filename";A1);TROUVE("[";CELLULE("filename";A1));300)

4 - Chemin d'accès et Nom du répertoire

=GAUCHE(CELLULE("filename";A1);TROUVE("[";CELLULE("filename";A1))-2)

5 - Chemin complet

=CELLULE("filename";A1)

A+ à tous

 

[JCGL]

Re : Nommer cellule

Bonjour à tous,

Oups désolé VBACrumble, je n'avais pas suivi le lien déposé. Je n'avais vu que la fonction personnalisée.

A++
A+ à tous

Edition : Le nom d'une feuille est limité (< 32 caractères)

 

[vbacrumble]

Re : Nommer cellule

Re


Pas grave JCGL

Cela donnera de la matière à tite-cel pour nommer nommer et nommer encore

(L'onglet à l'échalote, ça peut être bon , mais ça ni VBA ni Excel ne savent faire 😉 )

Peut-être tite-cel sait-elle ?

Edition: c'est que je disais : 225 dépasse 32 d'un caractère
Tu as gagné un onglet bien saignant ou bleu ? 😉