Nombre maximum de SI

[FredVincent]

Bonjour , j'ai la formule suivante , qui peut paraitre compliqué à première vue mais qui est très simple, car elle suit toujours la même logique:

=SI((C73+($C$71-C71))<Calcul!$E$37;Calcul!$A$35;SI(ET((C73+($C$71-C71))>Calcul!$E$37;(C73+($C$71-C71))<Calcul!$F$37);Calcul!$A$37;SI(ET((C73+($C$71-C71))>Calcul!$E$38;(C73+($C$71-C71))<Calcul!$F$38);Calcul!$A$38;SI(ET((C73+($C$71-C71))>Calcul!$E$39;(C73+($C$71-C71))<Calcul!$F$39);Calcul!$A$40;SI(ET((C73+($C$71-C71))>Calcul!$E$40;(C73+($C$71-C71))<Calcul!$F$40);Calcul!$A$40;SI(ET((C73+($C$71-C71))>Calcul!$E$41;(C73+($C$71-C71))<Calcul!$F$41);Calcul!$A$41;SI(ET((C73+($C$71-C71))>Calcul!$E$42;(C73+($C$71-C71))<Calcul!$F$42);Calcul!$A$42;"x")))))))

Malheureusement, lorsque je tente d'ajouter un autre SI dans ma formule, j'ai un message comme quoi ma formule contient une erreur. Pourtant, je garde toujours la même logique. Existe-t-il un nombre maximal de SI que l'on peut mettre dans une formule? Existe-t-il une autre manière de mettre une fonction SI en suivant une suite logique comme ma formule ci haut?

Merci, je me gratte la tête depuis des jours...

 

[Excel-lent]

Re : Nombre maximum de SI

Slt FredVincent,

Par défaut, dans Excel, on peut imbriquer au MAXIMUM 7 "si"

Pourquoi faire ($C$71-C71) ??? cela fait forcément 0, non?

Je ne comprend pas pourquoi tu as mis la formule ET alors que tu n'as qu'UNE seule "valeur logique".

 

[ziopizza]

Re : Nombre maximum de SI

Bonsoir le fil,
Trouvé sur un autre site,

Existe t-il un moyen, tout en restant dans la même cellule de dépasser le nombre de 7 SI qui s'imbriquent dans une fonction ? Nommer la formule qui a une serie de 7 si (sept1)
dans une cellule:
=SI($A$1=1;11;SI($A$1=2;22;SI($A$1=3;33;SI($A$1=4;44;SI($A$1=5;55;SI($A$1=6;
66;SI($A$1=7;77;FAUX)))))))

nommer la formule qui a une autre serie de 7 si (sept2)
dans un autre cellule:
=SI($A$1=8;88;SI($A$1=9;99;SI($A$1=10;100;SI($A$1=11;110;SI($A$1=12;120;SI($
A$1=13;130;SI($A$1=14;140;FAUX)))))))

dans une troisième:
=si(sept1;sept1;sept2)
...Patrick MacKay, (N°506)
Salut à tous
Yves

 

[JeanMarie]

Re : Nombre maximum de SI

Bonsoir Fred

Il y a plusieurs solutions pour résoudre ton problème. Pour te donner la meilleure, il est préférable de mettre un exemple sur le forum.

Le plus important c'est que tu nous dises le type de données (numérique ou texte) dans les cellules de la colonne A.. , et les valeurs de cellules E et F de la feuille Calcul.

@+Jean-Marie

 

[FredVincent]

Re : Nombre maximum de SI

Merci de répondre aussi vite!! SI je met $C$71-C71, c'Est que je glisse la formule de gauche a droite. La cellule suivante sera donc $C$71-C72 etc...
Ensuite, si je met la fonction ET, c'est parce que je cherche une valeur qui se trouve entre 2 valeur. Par exemple
SI(ET((C73+($C$71-C71))>Calcul!$E$37;(C73+($C$71-C71))<Calcul!$F$37);

Je veux que ma valeur C73 > $E$37 mais que C73 < $F$37.

Peut-etre as tu une meilleure solution... je la prendrais bien, je sui novice en excel.

Pour mon problème , j'ai trouvé une discussion intéressante qui utilise la fonction de recherche a partir d'un index dans le genre:

=INDEX(Base!B:B;EQUIV(A1;Base!A:A;0)).

Comment l'adapter a mon problème? Je ne cherche pas une donnée équivalente mais plutôt une données qui se situerais entre 2 valeurs?
Je sens que je suis sur la bonne piste... ne me manque qu'un guide spirituel...
Merci

 

[criscris11]

Re : Nombre maximum de SI

Bonsoir à tous les trois,
Je voulais juste intervenir sur la réponse de Ziopizza car effectivement cela peut-être une solution mais il y a une condition et de taille : l'imbrication de formules renommées ne fonctionne que si les Si renvoie des valeurs numériques et sont différentes de 0 d'où la question de Jean-marie, je pense.
Bonne soirée.
Chris.

 

[FredVincent]

Re : Nombre maximum de SI

Wow , le temps d'écrire mon message et j'ai déja des réponse supplémentaire. Je vous ai fait un exemple simple. Sur la feuille1 , la ligne 1 contient mes données de référence. La ligne 2 (???), la formule que je veux bâtir sans utiliser de SI.
Sur la feuille 2 , la colone A contient les réponse a mettre sur la ligne 2 de la feuille 1 en relation avec les colonne B et C de la feuille 2.

Par exemple , Si feuille1!A1 > feuille2!B2 et < feuille2!C2 = réponse feuille2!A2.
et ainsi de suite...

Par contre je suis limité par le nombre de si (7). Ne pas se fier a mon exemple, la feuille 2 possède en réalité plusieurs valeurs (40 ligne)

Donc j'avais pensé utilisé la fonction
INDEX(Base!B:B;EQUIV(A2;Base!A:A;0)) adapté a mon problème.
Merci de m'aider, me semble que ça doit pas être trop compliqué...

 

[JeanMarie]

Re : Nombre maximum de SI

Re...

Plusieurs solutions possibles

=SOMMEPROD(Feuil2!$A$2:$A$7*(Feuil2!$B$2:$B$7<Feuil1!A1)*(Feuil2!$C$2:$C$7>Feuil1!A1))
=INDEX(Feuil2!$A$2:$A$7;EQUIV(1;FREQUENCE(Feuil1!A1;Feuil2!$C$2:$C$7);0);1)

La deuxième formule permet de retourner une valeur Texte, que ne permet pas la première

@+Jean-Marie

 

[FredVincent]

Re : Nombre maximum de SI

Hey ça fonctionne!!! J'aime bien la 2e propo. Merci a tous...

 

[Monique]

Re : Nombre maximum de SI

Bonjour,

Index et n° de ligne, le n° de ligne étant renvoyé par SommeProd
et peut renvoyer du texte :

=INDEX(Feuil2!$A$1:$A$7;SOMMEPROD((Feuil2!$B$2:$B$7<A1)*(Feuil2!$C$2:$C$7>A1)*LIGNE(Feuil2!$B$2:$B$7)))

=INDEX(Reponse;SOMMEPROD((Bas<A1)*(Haut>A1)*LIGNE(Bas)))
(la plage "Reponse" part de la ligne 1)