Nombre max d'occurences d'un car. ASCII

[Art]

Chaleureux Bonjour à tous et à toutes en ce frileux dimanche.
Voici mon problème.
De quelle manière, en VBA, puis je trouver, dans une colonne entière par exemple, la cellule qui contiendrait le plus grand nombre de mise à la ligne, c'est à dire de Chr(10).
Merci à tous
@+
Art

 

[wally]

Bonjour Art et le forum,

Voici une possibilité. Ce code recherche les Chr(10) dans la colonne A :

Sub Recherche_Saut_Ligne()

Dim oRge As Range
Dim sAdr As String
Dim iCpt As Integer
Dim iMax As Integer
Dim iPos As Integer

iMax = 0
For Each oRge In Range("A1:A" & Range("A65536").End(xlUp).Row)
iCpt = 0
iPos = InStr(1, oRge.Value, Chr(10))
If iPos > 0 Then
Do While iPos > 0
iCpt = iCpt + 1
iPos = InStr(iPos + 1, oRge.Value, Chr(10))
Loop
If iCpt = iMax Then
sAdr = sAdr & " / " & oRge.Address(0, 0)
ElseIf iCpt > iMax Then
iMax = iCpt
sAdr = oRge.Address(0, 0)
End If
End If
Next oRge

If iMax = 0 Then
MsgBox "Aucun saut de ligne n'a été trouvé."
Else
MsgBox "Le nombre maximum de sauts de ligne (" & iMax & ") se trouve dans la/les cellule(s) :" & vbCrLf & vbCrLf & sAdr
End If

End Sub


Slts

wally

 

[Art]

Bonjour à tous
Wally, ta macro est tout simplement formidable, c'est tout à fait ce dont j'avais besoin.
Merci à toi et à tout les participants à ce forum.
@+
Art