Nombre de valeurs enchainées en 4, 5 ou 7 jours

[BANDIN]

Bonjour,

dans mon fichier Essai V8, j'aimerais calculé automatiquement en N21, N22, N23 le nombre de valeur enchainée dans la colonne C. N21 = 2 valeurs en 4 jours consécutifs, en N22 2 en 5 jours puis N23 3 en 7 jours.
Par exemple en N21 je voudrais savoir combien de fois dans l'année il y a eu 2 valeurs en 4 jours consécutifs (ici l'exemple serait 3 : du 15/07 au 18/07; du 1/08 au 4/08 et du 4/08 au 7/08)

Je vous avoue que je suis bien bloqué
Pouvez vous m'aider

Merci
Bandin

 

[job75]

Bonsoir BANDIN,

Vous parlez de N21 N22 N23 ? Dans votre fichier ce serait plutôt N20 N21 N22 non ?

A+

 

[job75]

Formule en N20 =SOMMEPROD(N(NB.SI(DECALER(C$4;LIGNE(C$4:C$409)-4;;4);">0")=2))

Formule en N21 =SOMMEPROD(N(NB.SI(DECALER(C$4;LIGNE(C$4:C$409)-4;;5);">0")=2))

Formule en N22 =SOMMEPROD(N(NB.SI(DECALER(C$4;LIGNE(C$4:C$409)-4;;7);">0")=3))

 

[BANDIN]

Oui vous avez raison job75 j'ai fait une erreur de cellule. Cela dit vous avez très bien répondu à ma question. Merci beaucoup
Je me permets d'être un peu gourmand :
si je veux en P20 la somme des valeurs cumulées de la colonne C au lieu du nombre de valeurs. Exemple en N20 le résultat était 3, en P20 ca devrait être 209 (23+86+6+78+16).

Merci

Bandin

 

[job75]

Pas d'accord avec votre résultat 209 car il faut compter 2 fois le 78 en C26 ce qui donne 287.

Les 3 formules :

=SOMMEPROD((NB.SI(DECALER(C$4;LIGNE(C$4:C$409)-4;;4);">0")=2)*SOUS.TOTAL(9;DECALER(C$4;LIGNE(C$4:C$409)-4;;4)))

=SOMMEPROD((NB.SI(DECALER(C$4;LIGNE(C$4:C$409)-4;;5);">0")=2)*SOUS.TOTAL(9;DECALER(C$4;LIGNE(C$4:C$409)-4;;5)))

=SOMMEPROD((NB.SI(DECALER(C$4;LIGNE(C$4:C$409)-4;;7);">0")=3)*SOUS.TOTAL(9;DECALER(C$4;LIGNE(C$4:C$409)-4;;7)))

Bonne nuit

 

[BANDIN]

Merci Job75. C'est parfait. Il me reste deux infos à trouver, je le publie sur le fil de discussion
bonne journée

Bandin