Microsoft 365 Nombre de valeurs de type "texte" uniques selon plusieurs critères.

PhilippeLM · 3 Juin 2023

Bonjour à tous,
je vous remercie par avance pour votre aide sur le sujet ci-dessous.
Voici les données pour comprendre ma requête (avec un fichier Excel en pj, plus facile à exploiter qu'une image).

De ces données, je souhaite obtenir le nombre de quiz uniques et réussis pour la semaine 1 (S1). pour l'ID interne suivant : 8120638. Le résultat attendu étant "4".
Je souhaite pouvoir reproduire la formule pour n'importe quel ID Interne.
Mes essais n'ont pas été concluants jusqu'à présent.
Je vous remercie par avance pour votre aide.

R@chid · 4 Juin 2023

Bonjour @ tous,
Salut @mapomme ,

mapomme à dit:
Bonsoir R@chid ,

Avec O365. J'avais trouvé la même formule que toi mais il y a un petit PB si le résultat du filtre est vide (prendre S9) et je n'ai pas trouvé de parade "élégante et concise". NBVAL d'un filtre vide retourne 1 chez moi et non pas 0.

Oui t'as raison, on peut contourner le problème comme suit :

VB:

=SIERREUR(LIGNES(UNIQUE(FILTRE(H2:H29;(E2:E29=8120653)*(DROITE(F2:F29;2)="S1")*(J2:J29="Réussi"))));0)

Cordialement

ALS35 · 3 Juin 2023

Bonjour,
Quelque chose comme ça peut-être :

VB:

=SOMME(N(UNIQUE(FILTRE(H2:H29;(E2:E29=8120638)*(BYROW(F2:F29;LAMBDA(p;PRENDRE(FRACTIONNER.TEXTE(p;" ");;-1)))="S1")*(J2:J29="Réussi");""))<>""))

Tu peux mettre les valeurs testées dans des cellules pour les faire varier
Cordialement

job75 · 3 Juin 2023

Bonjour PhilippeLM, ALS35,

Inutile d'utiliser les nouvelles fonctions d'Office 365, sur toutes versions :

Code:

=SOMMEPROD((E2:E29=8120638)*ESTNUM(CHERCHE("S1";F2:F29))*(LIGNE(H2:H29)=EQUIV(H2:H29;H:H;0))*(J2:J29="Réussi"))

A+

Gégé-45550 · 3 Juin 2023

job75 à dit:
Bonjour PhilippeLM, ALS35,

Inutile d'utiliser les nouvelles fonctions d'Office 365, sur toutes versions :

Code:

=SOMMEPROD((E2:E29=8120638)*ESTNUM(CHERCHE("S1";F2:F29))*(LIGNE(H2:H29)=EQUIV(H2:H29;H:H;0))*(J2:J29="Réussi"))

A+

Bonjour,
la formule ne marche pas pour la valeur 8120652, même si on trie le tableau sur l'ID en mettant la valeur 8120652 en tête.
... et je n'arrive pas à comprendre pourquoi ? ça m'énerve !
Cordialement

job75 · 3 Juin 2023

En effet la méthode utilisée pour éliminer les doublons ne va pas du tout.

R@chid · 3 Juin 2023

Bonjour @ tous,

Sous Excel pour Microsoft 365 :

VB:

=NBVAL(UNIQUE(FILTRE(H2:H29;(E2:E29=8120638)*(DROITE(F2:F29;2)="S1")*(J2:J29="Réussi"))))

Cordialement

R@chid · 3 Juin 2023

Re,
Toutes versions d'Excel :

VB:

=NB(1/SI((E2:E29=8120638)*(DROITE(F2:F29;2)="S1")*(J2:J29="Réussi");EQUIV(E2:E29&F2:F29&H2:H29&J2:J29;E2:E29&F2:F29&H2:H29&J2:J29;0)=LIGNE(INDIRECT("1:"&LIGNES(E2:E29)))))

@ valider par Ctrl+Maj+Entrée

Cordialement

mapomme · 3 Juin 2023

Bonsoir R@chid ,

Avec O365. J'avais trouvé la même formule que toi mais il y a un petit PB si le résultat du filtre est vide (prendre S9) et je n'ai pas trouvé de parade "élégante et concise". NBVAL d'un filtre vide retourne 1 chez moi et non pas 0.

Gégé-45550 · 3 Juin 2023

mapomme à dit:
Bonsoir R@chid ,

Avec O365. J'avais trouvé la même formule que toi mais il y a un petit PB si le résultat du filtre est vide (prendre S9) et je n'ai pas trouvé de parade "élégante et concise". NBVAL d'un filtre vide retourne 1 chez moi et non pas 0.

Pas de pb chez moi, avec S9 => résultat=0

mapomme · 4 Juin 2023

Gégé-45550 à dit:
Pas de pb chez moi, avec S9 => résultat=0

Ça m'étonne un peu car avec les formule O365, j'ai l'erreur...

Voir le fichier joint.

En N2 le choix de la semaine
En N6, la formule pour avoir la liste des Id sans doublons
En O6, la formule de comptage à recopier vers le bas

En N12, le tableau récapitulatif des erreurs (1 au lieu de zéro).

Gégé-45550 · 4 Juin 2023

mapomme à dit:
Ça m'étonne un peu car avec les formule O365, j'ai l'erreur...

Voir le fichier joint.

En N2 le choix de la semaine

En N6, la formule pour avoir la liste des Id sans doublons

En O6, la formule de comptage à recopier vers le bas

En N12, le tableau récapitulatif des erreurs (1 au lieu de zéro).

moi je parlais de la dernière formule de Rachid

VB:

=NB(1/SI(($E$2:$E$29=O5)*(DROITE($F$2:$F$29;2)="S9")*($J$2:$J$29="Réussi");EQUIV($E$2:$E$29&$F$2:$F$29&$H$2:$H$29&$J$2:$J$29;$E$2:$E$29&$F$2:$F$29&$H$2:$H$29&$J$2:$J$29;0)=LIGNE(INDIRECT("1:"&LIGNES($E$2:$E$29)))))

ou la valeur de l'ID interne est en O5

Gégé-45550 · 4 Juin 2023

mapomme à dit:
Ça m'étonne un peu car avec les formule O365, j'ai l'erreur...

Voir le fichier joint.

En N2 le choix de la semaine

En N6, la formule pour avoir la liste des Id sans doublons

En O6, la formule de comptage à recopier vers le bas

En N12, le tableau récapitulatif des erreurs (1 au lieu de zéro).

[EDIT 01:40] Une solution ?

VB:

=SI(SOMME((--(DROITE($F$2:$F$29;2)=$N$2))*(($E$2:$E$29)=O8)*($J$2:$J$29="Réussi"))>0;NBVAL(UNIQUE(FILTRE($H$2:$H$29;($E$2:$E$29=O8)*(DROITE($F$2:$F$29;2)=$N$2)*($J$2:$J$29="Réussi"))));0)

avec l'ID interne en O8 [/EDIT]

mapomme · 4 Juin 2023

Re,
Du coup, c'est plus long qu'avec un SOMMEPROD(). Il doit y avoir plus simple avec O365 mais maintenant, il est temps de faire dodo . On verra tout ça tout à l'heure.
Bonnet de nuit.

JHA · 4 Juin 2023

Bonjour à tous

Un essai avec un TCD

JHA

Gégé-45550 · 4 Juin 2023

mapomme à dit:
Re,
Du coup, c'est plus long qu'avec un SOMMEPROD(). Il doit y avoir plus simple avec O365 mais maintenant, il est temps de faire dodo . On verra tout ça tout à l'heure.
Bonnet de nuit.

re
Voir #6 de @R@chid

Microsoft 365 Nombre de valeurs de type "texte" uniques selon plusieurs critères.

PhilippeLM

XLDnaute Nouveau

Pièces jointes

R@chid

ALS35

XLDnaute Occasionnel

job75

XLDnaute Barbatruc

Gégé-45550

XLDnaute Accro

job75

XLDnaute Barbatruc

R@chid

XLDnaute Barbatruc

R@chid

XLDnaute Barbatruc

mapomme

XLDnaute Barbatruc

Gégé-45550

XLDnaute Accro

mapomme

XLDnaute Barbatruc

Pièces jointes

Gégé-45550

XLDnaute Accro

Gégé-45550

XLDnaute Accro

mapomme

XLDnaute Barbatruc

JHA

XLDnaute Barbatruc

Pièces jointes

Gégé-45550

XLDnaute Accro

Discussions similaires