Microsoft 365 NB.SI sous condition_fusionner deux formules

[aeca]

Bonjour,
Je cherche à incrémenter une colonne en fonction du contenu d'une autre.

Dans mon exemple, j'ajoute des commentaires dans la colonne A et je voudrais que :
- si la colonne A reste vide, alors la colonne C fait remonter "rien-1" 2 3 4 etc. en incrémentant à chaque fois qu'une ligne est vide.
- Et en même temps, si j'écris un commentaire, je voudrais que la colonne C donne plutôt "note-1" 2 3 4 etc.

J'arrive à obtenir ce que je veux mais en passant par une formule intermédiaire (voir en colonne 2)
Je n'ai pas réussi à obtenir le résultat souhaité en compilant tout ça en une seule formule.

J'ai testé avec une fonction SI :

SI(A2<>"";"note"&"-"&NB.SI(A2:$A$2;@A2:$A$2);"vide"&"-"&NB.SI(A2:$A$2;@A2:$A$2))

mais cela ne fonctionne pas
- j'obtiens un résultat qui s'incrémente correctement pour les cellules vides
- mais qui, en cas de cellule non vide, ne s'incrémente que si le contenu des cellules est identique. Ce qui ne sera jamais le cas car mes commentaires sont propres à chaque ligne.


Pourriez vous m'aider à y voir plus clair s'il vous plait?

Merci par avance

aeca

 

[chris]

Bonjour

=B2&"-"&NB.SI(B2:$B$2;$B2)

 

[job75]

Bonjour aeca, chris,

En B2 :

=REPT("rien-"&NB.VIDE(A$2:A2);ESTVIDE(A2))&REPT("note-"&NB.SI(A$2:A2;"<>");NON(ESTVIDE(A2)))

A+

 

[aeca]

Bonjour Chris, Job75

Merci pour vos réponses

@job75 : parfait c'est exactement ce que je cherchais ! merci beaucoup!

 

[sylvanu]

Bonsoir Aeca, Chris, Job,
A quoi sert la colonne B ?
On peut s'en passer et mettre en colonne B directement :

=SI(A2<>"";"note-"&NB.SI($A$2:A2;"*");"rien-"&NB.SI($A$2:A2;""))

Non ?

 

[job75]

Hello sylvanu,

Pour le fun ta formule prend 74 octets en mémoire, la mienne 73 octets...

Contrairement à REPT la fonction SI prend beaucoup d'octets.

 

[sylvanu]

Hello Job,
1 octet de moins !
Votre Asus a t-il si peu de mémoire ?

 

[job75]

C'est par respect pour l'environnement, 1 octet consomme de l'énergie

 

[aeca]

Bonsoir Aeca, Chris, Job,
A quoi sert la colonne B ?
On peut s'en passer et mettre en colonne B directement :

=SI(A2<>"";"note-"&NB.SI($A$2:A2;"*");"rien-"&NB.SI($A$2:A2;""))

Non ?

Bonsoir Sylvanu,
C'était l'objet de ma demande; je souhaitais me passer de la colonne B mais n'y parvenais pas.

Merci pour cette formule également.
Je note par contre qu'avec cette dernière, si je mets des chiffres dans la colonne A, l'incrémentation repart de 1.

Je n'ai pas eu ce problème avec la formule REPT que je conserve donc ;-)
@job75

Merci à vous !

 

[job75]

Je note par contre qu'avec cette dernière, si je mets des chiffres dans la colonne A, l'incrémentation repart de 1.

Oui il faut remplacer "*" par "<>", la formule de sylvanu pèsera 75 octets.

Voir aussi avec des valeurs d'erreur en colonne A...

 

[job75]

Bon allez cette formule pèse 71 octets, prenez donc cette solution :

=SI(ESTVIDE(A2);"rien-"&NB.VIDE(A$2:A2);"note-"&NB.SI(A$2:A2;"<>"))