NB.SI et rechercher mot dans une colonne

[guijone]

Bonjour!

Avant de poser ma question, j'expose le contexte:

Je chercher à faire un graphique représentant des actions menées selon leur gravité en fonction du mois d'apparition de celles-ci.
J'ai donc quelque chose du genre:

Pour le mois de Mai: 2 actions bloquantes, 5 actions majeures, 3 actions mineures.

Je veux donc représenter cela sous forme d'histogramme empilé afin que l'on puisse voir les 3 gravités en fonction du mois d'apparition.

J'ai donc choisi de faire un tableau sur la feuille 4 avec en ligne les différents mois et en colonne les 3 gravités. Pour remplir mon tableau je veux donc répondre à la phrase suivante: " Si les cellules de B2 à B136 contiennent "janv" alors dénombrer les cellules D2 à D136 contenant "Mineure" "

J'utilise donc la formule suivante:

=SI((Feuil1!B2:B136)="janv";NB.SI(Feuil1!D2: D136; "Mineure");0)

mais je dois avoir une erreur au niveau de la syntaxe pour trouver "janv" car avec une cellule seule ça fonctionne!

En espérant avoir été clair! Si vous avez une idée, je suis tout ouïe!

Merci à tous

 

[nat54]

Re : NB.SI et rechercher mot dans une colonne

Bonjour

Merci de fournir un ficher exemple

 

[guijone]

Re : NB.SI et rechercher mot dans une colonne

Voici un fichier exemple 🙂

Merci d'avance

 

[mth]

Re : NB.SI et rechercher mot dans une colonne

re bonjour guijone, bonjour nat54,

Un essai en cellule M28 de la FEUIL4:

=SOMMEPROD((MOIS(Feuil1!$B$2:$B$11)=MOIS(Feuil4!M$27))*(ANNEE(Feuil1!$B$2:$B$11)=ANNEE(Feuil4!M$27))*(Feuil1!$D$2:$D$11=Feuil4!$L28))

A coller vers le bas et vers la droite (et en réactivant le calcul automatique ...)

Bonne journée,

mth

 

[guijone]

Re : NB.SI et rechercher mot dans une colonne

Merci beaucoup!
Ça fonctionne très bien 😉

 

[guijone]

Re : NB.SI et rechercher mot dans une colonne

J'ai une autre question liée au sujet:

En fait le nombre de lignes ne sera pas fixe, c'est à dire que le fichier sera modifié au fur et à mesure. C'est pourquoi je voudrais remplacer les numéros de lignes par une variable indiquant la dernière ligne où il y a des données.

Est-il possible de faire cela? Faut-il passer par du VB?

Merci d'avance 🙂

 

[Tibo]

Re : NB.SI et rechercher mot dans une colonne

Bonjour,

La formule de Mireille 😉 adaptée avec la fonction DECALER :

en M28 :

=SOMMEPROD((MOIS(DECALER(Feuil1!$B$1;1;0;NBVAL(Feuil1!$B:$B)-1))=MOIS(
Feuil4!M$27))*(ANNEE(DECALER(Feuil1!$B$1;1;0;NBVAL(Feuil1!$B:$B)-1))=ANNEE(
Feuil4!M$27))*(Feuil1!$D$2:$D$11=Feuil4!$L28))

Je te laisse tester

@+

 

[guijone]

Re : NB.SI et rechercher mot dans une colonne

Merci pour ta réponse rapide 😉

Par contre je veux aussi que la colonne D soit de taille variable, comme la B. Parce que si je rajoute une ligne dans ma feuille1, la formule n'est plus bonne, étant donné que D13 a été remplie.
J'ai donc essayé d'utiliser NBVAL mais sans succès, car ça me renvoie une valeur nulle.
Je n'ai pas du bien comprendre... Il faut aussi que j'utilise DECALER pour dire que la colonne D est variable?

 

[Tibo]

Re : NB.SI et rechercher mot dans une colonne

re,

Correction de la formule proposée plus haut :

=SOMMEPROD((MOIS(DECALER(Feuil1!$B$1;1;0;NBVAL(Feuil1!$B:$B)-1))=MOIS(
Feuil4!M$27))*(ANNEE(DECALER(Feuil1!$B$1;1;0;NBVAL(Feuil1!$B:$B)-1))=ANNEE(
Feuil4!M$27))*(DECALER(Feuil1!$D$1;1;0;NBVAL(Feuil1!$B:$B)-1)=Feuil4!$L28))

à recopier vers le bas et vers la droite

Essaye et dis-nous

@+

 

[guijone]

Re : NB.SI et rechercher mot dans une colonne

Super!

Merci beaucoup 🙂

Bonne journée