Microsoft 365 nb.si.ens sur 12 colonnes sous plusieurs conditions dont < ou > à 0

[jerome91]

Bonjour,
Je cherche à simplifier une formule nb.si.ensemble.
En effet, j'ai 12 mois d'info avec des valeurs > ou < ou à 0 ou vide, et je souhaiterais en fonction de différentes conditions (Région, agence, client), le nombre de valeurs > ou < à 0.
A date, j'ai mis une formule nb.si.ens comme vous le verrez un peu longue (2 nb.si.ens par mois avec < ou > à 0 soit 24 formules nb.si.ens).
Pourriez-vous m'aider à la remplacer ?
Merci.
Cdt,
Jérôme

 

[mapomme]

Bonsoir @jerome91 ,

Essayez cette formule (uniquement avec O365) :

=SOMMEPROD(--(ABS(FILTRE(D2:O10;(A2:A10=S4)*(B2:B10=T4)*(C2:C10=U4)))>0))

 

[mapomme]

Re,

Pour toutes les versions, celle-ci doit le faire:

=SOMMEPROD((ABS(D2:O10)>0)*(A2:A10=S4)*(B2:B10=T4)*(C2:C10=U4))

 

[Jacky67]

Bonjour,
Je cherche à simplifier une formule nb.si.ensemble.
En effet, j'ai 12 mois d'info avec des valeurs > ou < ou à 0 ou vide, et je souhaiterais en fonction de différentes conditions (Région, agence, client), le nombre de valeurs > ou < à 0.
A date, j'ai mis une formule nb.si.ens comme vous le verrez un peu longue (2 nb.si.ens par mois avec < ou > à 0 soit 24 formules nb.si.ens).
Pourriez-vous m'aider à la remplacer ?
Merci.
Cdt,
Jérôme

Bonjour jerome91, mapomme
Ou encore toute version

=SOMMEPROD(($A$2:$A$10=$S4)*($B$2:$B$10=$T4)*($C$2:$C$10=$U4)*($D$2:$O$10<>0))

​

 

[R@chid]

Bonjour @ tous,

=SOMMEPROD(--(ABS(FILTRE(D2:O10;(A2:A10=S4)*(B2:B10=T4)*(C2:C10=U4)))>0))

Un peu plus longue que celle de l'ami mapomme, mais elle est plus rapide sur les grandes plages de données :

=SOMME(--(RECHERCHEX(CONCAT(S4:U4);BYROW(A2:C10;LAMBDA(c;CONCAT(c)));D2:O10)<>0))

Excel pour Microsoft 365.


Bien cordialement

 

[jerome91]

Bonjour @ tous,

Un peu plus longue que celle de l'ami mapomme, mais elle est plus rapide sur les grandes plages de données :

=SOMME(--(RECHERCHEX(CONCAT(S4:U4);BYROW(A2:C10;LAMBDA(c;CONCAT(c)));D2:O10)<>0))

Excel pour Microsoft 365.


Bien cordialement

Merci pour toutes vos réponses.
Jérôme