Nb de jours ouvrés pour un mois et une année données

[chris6999]

Bonjour

Je souhaiterais pour remonter dans ma place C7 à C17 le nombre de jour ouvrés pour chaque mois (précisé dans la colonne B) et pour l'année identifiée dans la zone nommée An (C4)
Il faudrait exclure bien sûr les jours fériés (zone nommée Fer dans la même feuille).

J'ai trouvé pas mal de fils sur le sujet mais à partir de dates de début et de fin qui ne correspondent pas à mes attentes.

Un peu d'aide serait la bienvenue.

Merci d'avance
Cordialement

 

[Efgé]

Re : Nb de jours ouvrés pour un mois et une année données

Bonjour chris6999

Peut être en $C$7 et à tirer vers le bas:
=NB.JOURS.OUVRES(SOMME(1&B7&An);DATE(An;MOIS(SOMME(1&B7&An))+1;0);Fer)

Cordialement

 

[Modeste geedee]

Re : Nb de jours ouvrés pour un mois et une année données

Bonsour®

'ai trouvé pas mal de fils sur le sujet mais à partir de dates de début et de fin qui ne correspondent pas à mes attentes.

🙄
la fonction NB.JOURS.OUVRES nécessite cependant les arguments date début et date fin !!!

 

[chris]

Re : Nb de jours ouvrés pour un mois et une année données

Bonjour

Dans le même esprit que Efgé que je salue 🙂,

=NB.JOURS.OUVRES(DATEVAL("1"&B7&An);SI(B8<>"";DATEVAL("1"&B8&An)-1;DATEVAL("1"&$B$7&An+1)-1);Fer)

mais en modifiant ta colonne B avec cette formule

=DATE(An;LIGNE(A1);1)

tu pourrais utiliser

=NB.JOURS.OUVRES(B7;FIN.MOIS(B7;0);Fer)

Edit : Coucou Modeste qui est passé entre temps...

Edit2 : sur 2003 ces fonctions ne sont disponibles qu'en activant la macro complémentaire Utilitaire d'analyse

 

[pierrejean]

Re : Nb de jours ouvrés pour un mois et une année données

Bonjour à tous

Avec une fonction personnalisée

 

[chris6999]

Re : Nb de jours ouvrés pour un mois et une année données

Bonsoir à tous

Merci encore pour votre aide. Je vous fais un retour après avoir testé vos propositions

Bonne soirée

 

[JCGL]

Re : Nb de jours ouvrés pour un mois et une année données

Bonjour à tous,

Sans modifier les mois en Texte :

=NB.JOURS.OUVRES(DATE(An;MOIS(1&B7);1);DATE(An;MOIS(1&B7)+1;0);Fer)

A+ à tous

 

[Modeste geedee]

Re : Nb de jours ouvrés pour un mois et une année données

Bonsour® JC

😱
de même pour passer outre l'absence des accents (ou nom de mois étrangers) :

=NB.JOURS.OUVRES(DATE(An;EQUIV(B7;$B$7:$B$18;0);1);DATE(An;EQUIV(B7;$B$7:$B$18;0)+1;0);Fer)
🙄
Lien supprimé

 

[chris6999]

Re : Nb de jours ouvrés pour un mois et une année données

Bonsoir

Je reviens vers vous après avoir testé vos nombreuses propositions qui fonctionnent merveilleusement.
J'ai finallement opté pour celle de Chris car il fallait bien en choisir une.

Merci à tous.
Vos codes vont rejoindre ma bibliothèque de néophite.

Bonne soirée