Multiselection OptionButton

[bucuresti]

Bonjour, Bonsoir

Je suis toute nouvelle sur le forum et en cours d'amélioration pour ma pratique excel.
Après de multiples recherches sur ce forum et sur le net je n'ai pas trouvé de solution à mon problème à moins quand voyant l'astuce je n'ai pas compris .

Voilà mon problème :
Je souhaite mettre en place un petit logiciel où un userform apparaît .
Le but est de choisir une colonne & une ligne , grâce à des boutons d'options.
Une fois que cela est fait un message apparaît dans la cellule choisit

Pour l'instant si l'intervenant sélectionne :
A5 le message HELP apparait dans la cellule et ça marche pour toute les options B10 ...

Mais ce que je souhaite c'est que le message change par exemple si l'intervenant choisit
A & 5 alors HELP apparait en A5
mais
S'il choisit A & 10 alors SOS apparait en A 10

je n'arrive donc pas a faire varier mon texte en fonction des cellules selectionnées =S

Je vous ai mis mon fichier en PJ

Merci par avance de votre aide

Bonne journée , soirée à toutes et à tous

 

[mapomme]

Re : Multiselection OptionButton

Bonjour bucuresti et bienvenue sur XLD,

Un essai dans le fichier joint. Les boutons d'option de ligne ont été renumérotés à partir de 101.

Dans le programme, une constante de type texte et de nom quoi a été déclarée.

Cette constante contient les textes à afficher en fonction des adresses choisies par l'utilisateur. La saisie de cette constante se fait par paire Adresse;Texte à insérer

Exemple:

Const quoi = "a5;SOS;a10;Help;b5;Au secours;b10;Aidez moi;c10;;d10;Trop tard!"

• En A5 on insèrera le texte SOS paire 'a5;SOS'
• En A10 on insèrera le texte Help paire 'a5;Help'
• En B5 on insèrera le texte Au secours paire 'a5;Au secours'
• En B10 on insèrera le texte Aidez moi paire 'a5;Aidez moi'
• En C10 on insèrera le texte vide paire 'c10;;' -> revient à effacer le contenu de la cellule
• En D10 on insèrera le texte Trop tard! paire 'a5;Trop tard!'

Les cellules dont l'adresse ne figure pas dans la constante resteront inchangées(i.e. C5, D5)

Le code:

Option Explicit
Dim colonne, ligne
Const quoi = "a5;SOS;a10;Help;b5;Au secours;b10;Aidez moi;c10;;d10;Trop tard!"

Private Sub CommandButton1_Click()
Dim i&, tabquoi, adr$
tabquoi = Split(UCase(quoi), ";")
adr = UCase(colonne & ligne)
For i = 0 To UBound(tabquoi) - 1 Step 2
  If adr = tabquoi(i) Then
    Range(adr) = tabquoi(i + 1)
    Exit For
  End If
Next i
  Unload Me
End Sub

Private Sub activer()
Dim i&
  For i = 1 To 4
    If Me.Controls("OptionButton" & i) Then colonne = Me.Controls("OptionButton" & i).Caption
  Next i
  For i = 1 To 2
    If Me.Controls("OptionButton" & 100 + i) Then ligne = Me.Controls("OptionButton" & 100 + i).Caption
  Next i
  If colonne <> "" And ligne <> "" Then
    CommandButton1.Enabled = True
    CommandButton1.Caption = "Valider le choix"
  End If
End Sub

Private Sub OptionButton1_Click()
    activer
End Sub
Private Sub OptionButton2_Click()
    activer
End Sub
Private Sub OptionButton3_Click()
    activer
End Sub
Private Sub OptionButton4_Click()
    activer
End Sub
Private Sub OptionButton101_Click()
    activer
End Sub
Private Sub OptionButton102_Click()
    activer
End Sub

 

[bucuresti]

Re : Multiselection OptionButton

Merci Beaucoup Beaucoup !

je ne connaissais pas la constante,
je vais me pencher encore sur le code pour être sur de bien avoir tout compris mais ça marche !!!!!

Merci Merci Merci

Bon weekend et Joyeuses Fêtes de fin d'années

 

[laetitia90]

Re : Multiselection OptionButton

bonjour bucuresti , mapomme🙂
dans le cas present on pourrait utiliser Tag

mais bon perso j'utiliserai des combo... ou listbox une pour column , une pour row & une pour selectionner
ce qu il faut ecrire......... a mon avis plus simple & offre plus de possibilitées . code plus simple egalement