Moyenne conditionnelle

[Fab117]

Salut est-il possible de faire une moyenne des valeurs d'une colonne en ne prenant en compte que les cellules :
- non vides
- et celles dont la cellule de la colonne C (sur la même ligne) contient le chiffre 25

Merci d'avance et bon week-end.

Fab

 

[Tibo]

Re : Moyenne conditionnelle

Salut Fab,

une solution à base de SOMMEPROD :

=SOMMEPROD((B5:B50<>"")*(C5:C50=25);B5:B50)/SOMMEPROD((B5:B50<>"")*(C5:C50=25))

@+

 

[Monique]

Re : Moyenne conditionnelle

Bonjour,

Avec la fonction Moyenne() en matriciel :
=MOYENNE(SI(C5:C50=25;SI(B5:B50<>"";B5:B50)))

à valider en appuyant simultanément sur ctrl, maj et entrée

Idem :
=MOYENNE(SI((C5:C50=25)*(B5:B50<>"");B5:B50))

 

[Fab117]

Re : Moyenne conditionnelle

Super,
Merci beaucoup,j'essaye ça lundi matin sur mon fichier.
Merci et bonne fin de week-end.

Fab

 

[Fab117]

Re : Moyenne conditionnelle

Salut,
J'ai essayé la formule de Monique, en rajoutant des conditions supplémentaires, mais il me met un message d'erreur.
=MOYENNE(SI(F23:F100=25;SIG23:G100=60;SI(I23:I100<>"";I23:I100)))

En fait, je voudrais qu'il fasse la moyenne des valeurs I23:I100
A condition :
- Qu'il ne prenne pas en compte les cases vides
- Que le chiffre de la colonne F soit 25
- Que le chiffre de la colonne G soit 60 ou 65

Rien que ça.
Merci d'avance.

Fab

 

[Monique]

Re : Moyenne conditionnelle

Bonjour,

Fais un essai comme ça :
=MOYENNE(SI((I23:I100<>"")*(F23:F100=25)*((G23:G100=60)+(G23:G100=65));I23:I100))
à valider par ctrl, maj et entrée

MOYENNE(SI((condA)*(condB)*((condC1)+(condC2));plage))

 

[Fab117]

Re : Moyenne conditionnelle

Malheureusement, ça ne fonctionne pas avec (en fait j'avais encore oublié une condition, le chiffre de la colonne H devait être égal à zéro):

=MOYENNE(SI((I26:I100<>"")*(F26:F100=25)*(H26:H100=0)*((G26:G100=60)+(G26:G100=65));I26:I100))

Sais-tu pourquoi ?

Fab

 

[Fab117]

Re : Moyenne conditionnelle

A quoi ça tient parfois ?
En fait j'ai Excel en version anglaise => en mettant AVERAGE à la place de MOYENNE et IF à la place de SI, ça marche.

Merci beaucoup pour ton aide.

Fab

 

[Monique]

Re : Moyenne conditionnelle

Re,

Je t'ai quand même préparé un fichier
avec 3 séries différentes de conditions.

 

[Fab117]

Re : Moyenne conditionnelle

Encore une question,
Sur le même principe, sais-tu si on peut faire des graphiques ?
Il ne prendrait par exemple que les valeurs dont les autres cellules de la ligne remplissent certaines conditions (les mêmes que pour le calcul de la moyenne) ?

P. ex. sur le fichier joint :
Au lieu de ne représenter que la moyenne pour la condition 25/60, j'aurai souhaité pouvoir tracer toutes les analyses 25/60.

On m'a parlé des Pivot table (j'ai d'ailleurs pu voir le résultat et c'est ce que je cherche à faire). Je ne sais pas si c'est la solution à mon problème. Si c'est le cas, sais-tu où je pourrais trouver un tutorial pour l'utiliser ?
Merci.

Fab

 

[Monique]

Re : Moyenne conditionnelle

Re,

Graphique ou Pivot table, je passe la main.
Tu cherches "Tableau croisé dynamique" dans le forum.
(= pivot table)

 

[Fab117]

Re : Moyenne conditionnelle

Merci et bonne fin de journée.

Fab