XL 2010 Modif Code d'un Bouton

[MuscatMimi]

Bonsoir a tout le Forum et joyeuses fêtes a tous

J'a ce Code de D Josserand qui date de 2005,Je désire commencer a valider Les données d'une ligne de ma ListBox a partir de la ligne 12
de ma feuille,et ainsi de suite,j'y arrive pas

Private Sub CommandButton2_Click()
Dim L As Integer, x As Byte
L = Sheets("Feuil1").Range("B600").End(xlUp).Row + 1 'incrémente données
    With Me.ListBox2
        For x = 0 To .ListCount - 1
            If .Selected(x) = True Then
                'Feuil1.Range("A" & L) = .Column(0, x)
                Feuil1.Range("B" & L) = .Column(0, x)
                Feuil1.Range("C" & L) = .Column(1, x)
                
                L = L + 1
            End If
        Next x
    End With
End Sub

Merci a tous a l'avance,prenez soin de vous
Cordialement
christian

 

[laurent950]

Bonjour,

Je désire commencer a valider Les données d'une ligne de ma ListBox a partir de la ligne 12

For x = 12 To .ListCount - 1

 

[MuscatMimi]

Bonsoir Laurent
j'ai déjà essayé ceci mais ça ne fonctionne pas

 

[Staple1600]

Bonjour le fil

Je pense qu'un fichier exemple et patati et patatata...
😉
(ce que logiquement un XLDnaute Accro pensera aussi même les jours de réveillon 🙄)

EDITION: Bim !!! Transmission de pensée en direct 😉

 

[Staple1600]

Re

Heureusement que l'XLDnaute accro connait la charte et notamment le point RGP et fait en sorte de joindre un fichier anonyme...
C'est quoi tous ces emails valides dans ta PJ ?

 

[MuscatMimi]

pas grave j'ai pas pensé a les modifier

 

[MuscatMimi]

voici le fichier modifié

 

[Staple1600]

Re

Si c'est grave (relis la charte du forum... 🙄)
Sinon pour la question, voici comment je vois la chose

'*********Staple1600 2020 (le dernier jour)*********

Private Sub CommandButton2_Click()
 With Me.ListBox2
 Sheets("Feuil1").Cells(Rows.Count, 2).End(3)(2).Resize(, 2) = _
 Array(.Column(0, .ListIndex), .Column(1, .ListIndex))
 End With
End Sub

Private Sub ListBox2_Click()
CommandButton2.Visible = True
End Sub

Private Sub UserForm_Initialize()
With Sheets("Feuil2")
   ListBox2.List = .Range("B2:C" & .Range("C65536").End(xlUp).Row).Value
End With
CommandButton2.Visible = False
End Sub

 

[laurent950]

Bonjour @Staple1600

J'ai une question que j'ai essayer de développer : (je me trompe a qu'elle endroit ?)

Sheets("Feuil1").Cells(Rows.Count, 2).End(3)(2).Resize(, 2) = ""
Feuille 1
Cellule (Colonne 2) soit colonne B ' Pour 2
Rows.Count = ' Dernière cellule non vide de la colonne 2 avec :
- End(3) ' C'est l'équivalent de Xlup pour le code 3 ?
- Puis se qui suit (2) C'est la colonne 2 soit la colonne B
Resize :
- Cellule active avec déplacement d'une sur la droite : Soit Colonne B et C

 

[MuscatMimi]

je viens d'essayer les deux codes mais ça ne me valide pas mes données a partir de la ligne 12 de la feuil 1

 

[Staple1600]

Re

=>laurent950
(à tester sur une feuille vierge)

Sub Questions_A_Laurent()
Dim Umma As Range, Gumma As Range
Randomize 1600
Columns(2).Clear
Cells(Int((Rnd * 17) + 1), 2) = "Staple"
Set Umma = Cells(Rows.Count, "B").End(xlUp).Offset(1, 0)
Set Gumma = Cells(Rows.Count, 2).End(3)(2)
zX = Umma.Address(0, 0): zY = Gumma.Address(0, 0)
MsgBox Umma.Address = Gumma.Address, vbInformation, zX & "<|>" & zY
MsgBox Umma.Resize(, 2).Address
With Application
Umma.Resize(, 2) = Array(.UserName, .UsableWidth)
End With
End Sub

Fiat Lux, désormais ? 😉

 

[Staple1600]

Re

=>vaucluseimmo
Mets le mot Staple en B12 puis ressaies mon code
et tu verras que cela fonctionne 😉

 

[laurent950]

Re @Staple1600
Excellent, mille merci pour cette explication par le code qui vaut tous les long discours.
J'ai saisie

 

[patricktoulon]

bonsoir a tous

J'a ce Code de D Josserand qui date de 2005,Je désire commencer a valider Les données d'une ligne de ma ListBox a partir de la ligne 12
de ma feuille,et ainsi de suite,j'y arrive pas

on va faire simple si vous le voulez bien

Option Explicit
Private Sub CommandButton2_Click()
    Dim L&, x&
    L = Application.Max(12, Sheets("Feuil1").Range("B" & Rows.Count).End(xlUp).Row + 1)    '12 ou plus!!!!!
    With Me.ListBox2
        For x = 0 To .ListCount - 1
            If .Selected(x) Then Feuil1.Range("B" & L).Resize(, 2) = Array(.List(x, 0), .List(x, 1)): L = L + 1
        Next x
    End With
End Sub

Private Sub ListBox2_Click()
    CommandButton2.Visible = True
End Sub

Private Sub UserForm_Initialize()
    ListBox2.List() = Feuil2.Range("B2", Feuil2.Range("C" & Rows.Count).End(xlUp)).Value
    CommandButton2.Visible = False
End Sub

si plus de 2 ou 3 colonne pour la listbox je peux vous montrer comment on simplifie l'array
et rowssource oubliez si vous l'utilisez en vba ca n'a pas de sens 😉

bien sur si vous voulez que la boucle ai un sens mettez la listbox en multiselect
sinon remplacer ceci

  For x = 0 To .ListCount - 1
            If .Selected(x) Then Feuil1.Range("B" & L).Resize(, 2) = Array(.List(x, 0), .List(x, 1)): L = L + 1
        Next x

par cela

Feuil1.Range("B" & L).Resize(, 2) = Array(.List(.listindex, 0), .List(.listindex, 1))

 

[Staple1600]

Bonsoir patricktoulon

=>patricktoulon
N'est-ce pas simple ce qu'on peut lire dans le message#8?