XL 2010 Menu déroulant conditionnel

Private Sub Worksheet_Change(ByVal Target As Range)
    '
    ' Variable qui contiendra soit la liste des communes soit "Communes non trouvées"
    Dim liste As Variant
    '
    '  La cellule doit être dans la plage C10:C100 ( à adapter )
    If Target.Count = 1 And Not Intersect(Target, Range("C10:C100")) Is Nothing Then
        '
        ' Son type doit être un numérique (les valeurs numériques pour excel sont en type Double)
        If TypeName(Target.Value) = "Double" Then
            '
            ' Appel à la fonction pour obtenir la liste
            liste = CommunesParNumDepartement(CInt(Target.Value))
            '
            ' Travailler sur la celllule à droite de la cellule qui a changé
            With Target.Offset(, 1)
                '
                ' Si la fonction a retourné un tableau
                If IsArray(liste) Then
                    '
                    ' Ajouter l'item "Choisir une commune en fin de liste"
                    liste(UBound(liste)) = "Choisir une commune"
                    '
                    ' Transformer la liste en chaîne de caractères
                    ' dont chaque nom de commune sera séparé par une virgule
                    ' pour la liste de validation
                    liste = Join(liste, ",")
                Else
                    '
                    ' Si la liste n'est pas un tableau elle devient :
                    liste = "Communes non trouvées"
                End If
                '
                ' Sélection et valorisation de la cellule
                .Select
                .Value = Empty
                '
                ' suppression de validation existante, création de la nouvelle
                With .Validation
                    .Delete
                    .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, _
                         Operator:=xlBetween, Formula1:=liste
                End With
            End With
        End If
    End If
End Sub

Function CommunesParNumDepartement(NumDep As Integer) As Variant
    '
    ' Fonction permettant de retourner la liste des communes
    ' filtrées par Numéro du département
    '
    Dim cnx As Object, rst As Object
    Set cnx = CreateObject("adodb.connection")
    '
    ' Connexion au classeur lui-même (doit être enregistré sur disque dur)
    '
    cnx.connectionstring = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" _
                & ThisWorkbook.FullName & ";Extended Properties=""Excel 12.0 Xml;HDR=YES"";"
    cnx.cursorlocation = 3
    cnx.Open
    '
    ' interrogation de la table de données
    '
    Set rst = cnx.Execute("SELECT Nom_commune FROM [BDD$] WHERE Departement = " & NumDep & " ORDER BY Nom_commune;")
    '
    ' si quelque chose a été trouvé
    ' retourner le résultat sous formue de tableau
    '
    If Not rst.Bof And Not rst.EOF Then CommunesParNumDepartement = Split(rst.getstring(), vbCr)
    '
    ' fermer et nettoyer proprement les objets
    '
    rst.Close: Set rst = Nothing
    cnx.Close: Set cnx = Nothing
End Function