max.si

[bigbig]

Bonjour à tous,

Il y a la fomule somme.si qui fait une somme sous condition.
Nb.si fonctionne de la même façon.

Or je cherche à faire les fonction max.si et min.si équivalente et qui n'existe pas.

Comment faire ?

De préférence en formule, sans macro...

Merci de votre aide, A+

 

[theendlessummer]

salut

si tu veux faire qu'une formule conditionnelle peux tu un peu plus detaille car des fois on pense a quelque chose et il y a plus simple surtout pour des fonctions qui n'existent pas apriori

Sebastien

 

[bigbig]

En faite, j'ai une colonne de nombres.

Je désire trouver la valeur minimale dans cette liste.
Avec en plus la contrainte de ne pas prendre en compte les cellules inférieur à 2 par exemple (En faite la limite est définis dans une autre case)

Ex:
Colonne de chiffres :
5
3
5
6
1
3
4

Avec la contrainte de ne pas tenir compte des nombres inférieur ou égale à 2.
Résultat attendu : 3 dans l'exemple.

Et équivalent pour le max avec limite maxi.

Y a sans doute un truc tout simple, mais je vois pas...

Voilà

 

[theendlessummer]

bonsoir,

disons que tes chiffres soient en colonne A.

Si tu veux raisonner qu'en formule mets alors la conditionnelle si min de la serie de tes chiffres <2 alors rien sinon min de la serie.
Et dans une autre cellule max de la serie.

j'espere que cela repond a ta question.

Bonne soiree

 

[theendlessummer]

re,

Si tu veux quand meme qu'il te donne un min sans tenir compte des chiffres inferieurs a 2 metsla formule donnee pour le min dans les cellules a cote (colonne b disons) de chacun de tes chiffres et applique la fonction min en colonne c sur cette serie. cela ne devrait pas tenir compte des nouvelles cellules vides car chiffres<2

Courage
A+

 

[bigbig]

Merci de cette solution utilisant une colonne intermédiaire et qui marche bien.

Mais c'est sur un gros fichier que je dois faire celà et rajouter une colonne intermédiaire risque d'alourdir fortement mon fichier pour pas grand chose...

Il dois aussi avoir une solution matricielle je pense (connais pas trop les matrice sous excel...). Mais celà utilisera trop de resource pour le calcul matriciel...

Une autre solution sans toute une colonne intermédiaire ?

Merci, A+

 

[Charly2]

Bonsoir bigbig, bonsoir Theendlesummer,
bonsoir à toutes et à tous

Sans passer par une colonne intermédiaire, tu peux aussi le faire avec une formule matricielle.

Tes valeurs en A1:A20 et la valeur mini en B1 pour l'exemple. On doit donc obtenir le mini de A1:A20 pour les valeurs supérieures à B1 (si B1 = 2, on ne prend dans A1:A20 que les valeurs > 2) :

=SI(MAX($A$1:$A$20)‹=$B$1;'';MIN(SI($A$1:$A$20›$B$1;$A$1:$A$20)))

à valider par Ctrl+Majuscule+Entrée.

PS : Les caractères inférieurs et supérieurs ne passent pas sur le forum. Nous utilisons un subterfuge mais il faut les remplacer par leurs équivalents clavier en cas de Copier/Coller.

A+

 

[Jocelyn]

Bonjour le Forum,
Bonjour bigbig, theendlessummer, Charly2,

une formule matricielle plus courte.

=MIN(SI(A1:A10>2;A1:A10))

les formules matricielles sont a valider en appuyant simùultanement sur les touche ctrl+majuscule+entrée

Jocelyn

 

[Monique]

Bonjour

Sans validation matricielle
Minimum en A1:A20 des valeurs supérieures à B1
=PETITE.VALEUR(A$1:A$20;NB.SI(A$1:A$20;'‹='&B$1)+1)

Le max mais inférieur à B2 :
=GRANDE.VALEUR(A$1:A$20;NB.SI(A$1:A$20;'›='&B$2)+1)

Remplacer › et ‹ par les signes 'supérieur à' et 'inférieur à' du clavier

 

[Charly2]

Bonjour bigbig, bonjour Theendlesummer,
Bonjour Jocelyn, bonjour Monique,
Bonjour à tous les habitants de la Terre

Quand j'ai vu que vous étiez intervenus tous les deux, Monique et Jocelyn, je me suis dit que j'avais encore du boulot pour les formules.

Et puis... et puis je me suis aperçu que ma formule était plus longue que les vôtres mais qu'elle prévoyait le cas où toutes les valeurs seraient inférieures au minimum imposé ; pas certain que ce soit utile, mais bon :whistle:

J'engrange l'utilisation originale de PETITE.VALEUR et GRANDE.VALEUR par Monique. Pour la tienne, Jocelyn, je n'ai pas besoin puisqu'on a donné la même

A+