M'aider à trouver la formule

[Morice]

Bonjour à tous,

Excel est un logiciel que j'apprécie particulièrement mais ma connaissance en est assez limitée.

Quelqu'un peut-il m'écrire la formule pour trouver la valeur de I18 sachant que :

I18 = (C18+D18+E18+F18) divisé par 16
mais aussi
I18 = (C18+D18+E18+F18+G18) divisé par 20
mais aussi
I18 = (C18+D18+E18+F18+H18) divisé par 20
mais aussi
I18 = (C18+D18+E18+F18+G18+H18) divisé par 24

Si une âme bienveillante souhaite m'aider, enlever XYZ de mon adresse mail : jj@XYZmorice.info

Merci d'avance

 

[andré]

Salut Morice,

Ou bien je ne comprends pas ta question, ou bien je ne vois pas le problème.

Si les 4 conditions sont remplies il suffit d'écrire en I18 l'une des quatre conditions, par exemple la première : =SOMME(C18:F18)/16

S'il faut tester les 4 conditions et renvoyer VRAI ou FAUX suivant le résultat, la formule suivante y répond :
=(1° condition)+(2° consition)=(3° condition)+(4° condition)

S'il faut afficher le résultat si les 4 conditions sont remplies, sinon rien :
=SI(1° condition=ET(1° condition;2° condition;3° condition);1° condition;"")

Et si ce n'est pas cela ce que recherche, je te demanderai d'être un peu plus précis.

Ândré.

 

[Morice]

Merci André de t'occuper de mon problème

En fait ce que je souhaite afficher dans I18 c'est l'une où l'autre des 4 conditions.

Je ne suis pas vraiment sûr d'être très clair, mais si tu voulais m'envoyer ton adresse mail à jj@XYZmorice.info (en supprimant XYZ) je t'enverrais le tableau (très petit)

Tu comprendrais peut-être mieux ce que je cherche à expliquer.

Dans l'attente

Merci d'avance

 

[hurricane]

salut morice

si j'ai bien compris essai ça


=SI(SI(((C18+D18+E18+F18)/16);((C18+D18+E18+F18)/16);((C18+D18+E18+F18+G18)/20));((C18+D18+E18+F18+G18)/20);((C18+D18+E18+F18+G18+H18)/24))

@+

 

[Morice]

Merci Hurricane

Mais il y a un bug quelque part.

Si C18+D18+E18+F18 = 12 le résultat de I18 devrait être 12/16 = 0,75
or lorsque j'applique la première condition de la formule que tu m'indiques il est de : 0,60

Je suis confiant et impatient pour la suite.

APLUS

 

[Morice]

Re-bonjour

J'essaye de ré-expliquer.

La valeur de I18 doit prendre en compte les 4 conditions suivantes :

Si G18 et H18 = rien alors I18 =(C18+D18+E18+F18)/16
Si G18 = rien alors I18 =(C18+D18+E18+F18+H18)/20
Si H18 = rien alors I18 =(C18+D18+E18+F18+G18)/20
I18 =(C18+D18+E18+F18+G18+H18)/24

Est-ce plus clair ainsi.

Merci de votre patience

 

[andré]

Salut,

Il me semble que tu donnes toi-même la réponse :

SI(ET(G18="";H18="");(C18+D18+E18+F18)/16;SI(G18="";(C18+D18+E18+F18+H18)/20;SI(H18="";(C18+D18+E18+F18+G18)/20;
(C18+D18+E18+F18+G18+H18)/24)))

Vérifie quand même les (), moi je n'ai pas vérifié.

Ândré.

 

[Monique]

Bonjour,

En espérant qu'elle fonctionne :
=SOMME(C18:H18)/SI(ET(G18="";H18="");16;SI(OU(G18="";H18="");20;24))

 

[Morice]

Merci à Monique et à André

Votre réponse se vérifie exacte à tous les deux.

J'ai su expliquer ma demande, mais je ne savais pas faire.

Super ce forum.

APLUS

 

[andré]

Salut Monique,

Bien vu !

Partant de ton idée, je crois qu'il y a encore plus court.

somme de C18 à H18 à diviser par le nombre de cellules non vides entre C18 et H18 *4
ce qui donnerait : =SOMME(C18:H18)/NBVAL(C18:G18)*4

Ândré.

 

[andré]

Erreur !

Voici la formule exacte : =SOMME(C18:H18)/NBVAL(C18:H18)*4

Ândré.

 

[Monique]

Re,

C'est vrai, et c'est tentant quand on voit 16, 20 et 24
J'en étais à chercher quelque chose du style SOMME() / (VRAI+VRAI+FAUX+VRAI)
Au fait, c'est mieux avec / plutôt que *
=SOMME(C18:H18)/NBVAL(C18:H18)/4
Elle fonctionne, elle est courte et tout et tout mais
il ne faut pas de cellules vides entre C18 et F18
La solution est peut-être cette formule, parce que,
dans les 4 conditions, il n'y a pas de notion de cellules vides
en dehors de G18 et H18

 

[andré]

Rere,

D'accord, ce n'est pas seulement mieux, c'est aussi plus exact !
Mais alors que penses-tu de : =SOMME(C18:H18)/(4+NBVAL(G18:H18))/4 ?

Tu verras, ensemble on y arrivera (lol).

Ândré.

 

[Monique]

Re,
D'accord pour celle-là,
surtout qu'avec la précédente on avait un #DIV/0! si on effaçait toute la ligne.

 

[Morice]

Bravo

Il y a des jours on se sent moins désemparé.

APLUS