Macro VBA pour transférer des données d'une page Excel à une autre

Créer une discussion
Répondre
  • Initiateur de la discussion Initiateur de la discussion Jeff
  • Date de début Date de début

Boostez vos compétences Excel avec notre communauté !

Rejoignez Excel Downloads, le rendez-vous des passionnés où l'entraide fait la force. Apprenez, échangez, progressez – et tout ça gratuitement ! 👉 Inscrivez-vous maintenant !

S'inscrire
J

Jeff

Guest
Bonjour,

Mon problème est le suivant: j'ai sur une page excel un tableau classique, et la dernière colonne (disons colonne N) est un champ de sélection: je peux le renseigner ou non à "OK". Je voudrais créer une macro qui, sur le simple appui d'un bouton, me transfère toutes les lignes en "OK" sur une seconde page du même classeur. Chaque appui de ce bouton doit préalablement effacer le contenu de la page cible avant de copier les données.

Etant débutant en VBA, je n'ai que des notions de programmation, et toute aide serait la bienvenue.

Merci d'avance!

Jeff.
 
Trier par date Trier par votes
Bonsoir Jeff, bonsoir le forum,

Adapte la macro ci-dessous et applique-la à ton bouton :

Sub Macro1()
'déclaration des variables
Dim plage As Range
Dim cel As Range
Dim ici As Range
'définit la variable plage (j'ai choisis la colonne A mais il
'faut que tu prennes une des colonnes dont la donnée est toujours éditée"
Set plage = Sheets("Feuil1").Range("A1:A" & Sheets("Feuil1").Range("A65536").End(xlUp).Row)

'définit la variable ici (A1 de l'onglet "Feuil2")
Set ici = Sheets("Feuil2").Range("A1")

'efface toutes les données de l'onglet "Feuil2"
Sheets("Feuil2").Range("A1").CurrentRegion.Clear 'ou ClearContents pour garder les formats


'boucle sur toutes le cellules de la "plage décallée de 13" (Colonne N)
For Each cel In plage.Offset(0, 13)
'condition : si la cellule (colonne N) = "OK"
If cel.Value = "OK" Then
'copie la ligne entière et la colle dans la variable ici
cel.EntireRow.Copy Destination:=ici
Set ici = ici.Offset(1, 0) 'redéfinit la variable ici
End If 'fin condition
Next cel 'prochaine cellule de la colonne N
End Sub


À plus,

Robert
 
Vote positif 0 Vote négatif
C'est avec beaucoup de respect que je vous remercie pour cette aide.

Néanmoins j'ai un message d'erreur lors de l'utilisation:
" Erreur d'exécution 9, L'indice n'appartient pas à la sélection "
Erreur que je ne parviens pas à résoudre.

Avez-vous des pistes?

Merci encore,

Jeff
 
Vote positif 0 Vote négatif
Bonjour,

Je n'ai plus le problème d'erreur d'exécution 9.
J'ai également adapté le code afin de n'extraire vers la feuille de destination "feuil2" que trois colonnes du tableau initial, mais mon manque d'expérience VBA implique je pense une certaine lourdeur:

Voici le code, y a-t-il moyen de simplifier tout ça?


Sub test()


Dim i As Integer
Dim k As Integer
Dim plage As Range
Dim cel As Range
Dim ici As Range
Dim ici2 As Range
Dim ici3 As Range

k = 0
i = Sheets("Feuil1").Range("A65536").End(xlUp).Row
Set plage = Sheets("Feuil1").Range("A1:A" & i)
Set ici = Sheets("Feuil2").Range("A1")
Set ici2 = Sheets("Feuil2").Range("B1")
Set ici3 = Sheets("Feuil2").Range("C1")

Sheets("feuil2").Range("a1").CurrentRegion.Clear

For Each cel In plage.Offset(0, 13)
k = k + 1
If cel.Value = "ok" Then
Range("E" & k).Copy Destination:=ici
Range("F" & k).Copy Destination:=ici2
Range("K" & k).Copy Destination:=ici3
Set ici = ici.Offset(1, 0)
Set ici2 = ici.Offset(0, 1)
Set ici3 = ici.Offset(0, 2)
End If
Next cel

MsgBox ("Done")

End Sub


Si vous avez des idées pour alléger tout ça...
Merci beaucoup!

Jeff
 
Vote positif 0 Vote négatif
Bonjour Jeff, Robert, le Forum

Voici une Version "Light" :

Option Explicit

Sub ReportPlage()
Dim TabPlageSource As Variant
Dim i As Integer, L As Integer
Dim C As Byte, Ctab As Byte


  With Sheets("Feuil1")
    TabPlageSource = .Range("A2:N" & .Range("A65536").End(xlUp).Row)
  End With

Sheets("feuil2").Range("a1").CurrentRegion.Clear
L = 1

  For i = 1 To UBound(TabPlageSource)
       If UCase(TabPlageSource(i, 14)) = "OK" Then
           For C = 1 To 3
               Ctab = IIf(C = 3, 11, C + 4)
               Sheets("Feuil2").Cells(L, C) = TabPlageSource(i, Ctab)
           Next
       L = L + 1
       End If
  Next

MsgBox "Done"

End Sub


Et maintenant bien qu'ayant plus de lignes de codes, voici une version "Ultra Light", puisqu'on fait tout par Dynamic Array et que l'on écrit sur la feuille en une seule fois en fin de traitement. (Plus rapide)

Sub ReportPlageByArray()
Dim TabPlageSource As Variant
Dim TabPlageCible() As String
Dim TabCibleTmp() As String
Dim i As Integer, L As Integer, x As Integer
Dim C As Byte, Ctab As Byte


  With Sheets("Feuil1")
    TabPlageSource = .Range("A2:N" & .Range("A65536").End(xlUp).Row)
  End With

Sheets("feuil2").Range("a1").CurrentRegion.Clear
L = 1

  For i = 1 To UBound(TabPlageSource)
      If UCase(TabPlageSource(i, 14)) = "OK" Then
          ReDim Preserve TabPlageCible(3, x)
              For C = 0 To 2
                   Ctab = IIf(C = 2, 11, C + 5)
                   TabPlageCible(C, x) = TabPlageSource(i, Ctab)
              Next
      x = x + 1
      End If
  Next

  ReDim TabCibleTmp(UBound(TabPlageCible, 2), 3)
  For L = 0 To UBound(TabPlageCible, 2)
      For C = 0 To 2
          TabCibleTmp(L, C) = TabPlageCible(C, L)
      Next
  Next

Sheets("feuil2").Range("A1:C" & L) = TabCibleTmp()


MsgBox "Done"

End Sub


Bon Appétit
@+Thierry
 
Vote positif 0 Vote négatif
Re à tous,

je viens à peine de comprendre la première macro...

Ctab = IIf(C = 3, 11, C + 4)

C'est à se la prendre, se la couper et se la mettre derrière l'oreille pour la fumer plus tard, non !!!

J'ose à peine attaquer la seconde....

À plus,

Robert
 
Vote positif 0 Vote négatif
Re Bonjour Robert, Jeff, le Forum

Tout d'abord il restait un résidu inutile dans la seconde macro (L = 1 est Inutile dans "ReportPlageByArray")

Pour ce qui est du IIf, en fait c'est assez simple, notre ami Jeff veut transposer la Colonne "E", la Colonne "F" et la Colonne "K".

Afin de pouvoir passer tout ceci dans une seule et même boucle je me base sur le C (1 to 3) pour la feuille de réception (Colonne A, B, C, soit 1, 2,3), et je me décale mon Ctab dessus...(Pour mon Tableau en colonne E, F et K)

En Clair :

Ctab = 11 (Soit Colonne "K") Si C = 3

Ctab = C + 4 (Soit Colonne "E") si C = 1
ou bien
Ctab = C + 4 (Soit Colonne "F") si C = 2...

Tout ceci en une ligne grace au IIf...

Toto = IIf(Toto = 0, "Toto est Nul", "Toto est Bon")
Soit en Syntax :IIf(expression, truepart, falsepart)

C'est STéphane qui m'avait montré ce coup là il y a longtemps sur ce Forum, depuis je trouve çà génial.

Le principe sera le même en second code, mais on est en base Zéro pour l'Array, donc décalage, c'est tout.

Bon Aprèm et heureux que ça vous plaise.
@+Thierry
 
Vote positif 0 Vote négatif
Rejoins nos membres "Supporter XLD" et booste ton expérience Excel !
- Navigue sans publicité
- Accède à Cléa, notre assistante IA experte Excel... et pas que...
- Profite de fonctionnalités exclusives
Ton soutien permet à Excel Downloads de rester 100% gratuit et de continuer à rassembler les passionnés d'Excel.
Je deviens Supporter XLD
Assurez vous de marquer un message comme solution pour une meilleure transparence.

Discussions similaires

M
  • Résolu(e)
XL 2021 Problème d'activation d'une macro pour transférer des valeurs d'une feuille 1 à une feuille 2
Réponses
3
Affichages
152
MATLEA
M
M
  • Résolu(e)
XL 2021 Copier/Coller des valeurs d’une feuille à une autre à partir d’une cellule
Réponses
11
Affichages
453
MANU64360
M
O
  • Résolu(e)
XL 2013 VBA/ Macro qui classe des données dans une colonne unique
Réponses
5
Affichages
146
onyirimba
O
M
  • Question Question
XL 2021 Automatiser Changements des plages de données Graphique
Réponses
0
Affichages
161
Michel_ja
M
Chaton77
  • Résolu(e)
Microsoft 365 Vba : Transférer des données d'un tableau dans un autre fichier
Réponses
7
Affichages
749
Chaton77
Chaton77
M
  • Question Question
Microsoft 365 Macro pour changer le format de nombre à l'ouverture d'un CSV
Réponses
4
Affichages
193
oguruma
oguruma
M
  • Question Question
XL 2019 Transposer des données d'une feuille vers une autre sous forme de synthèse
Réponses
8
Affichages
626
mromain
mromain
L
  • Question Question
Microsoft 365 Trier des données d'une colonne dans une autre
Réponses
2
Affichages
439
Langrand
L
G
  • Résolu(e)
Copie de données d'une feuille à une autre
Réponses
2
Affichages
652
gui22
G
M
  • Question Question
XL 2021 Aide pour sauvegarde des données dans un calendrier automatique Excel
Réponses
2
Affichages
157
mimednejma
M
O
  • Résolu(e)
Microsoft 365 Amélioration/réparation d'une Macro et création d'un bouton pour calcul consommation
2
Réponses
27
Affichages
1 K
Olihoes
O
P
  • Question Question
XL 2021 Code VBA pour copier coller des données de cellules d'une feuille a une autre
2
Réponses
15
Affichages
1 K
lafleur
L
S
  • Question Question
Microsoft 365 VBA pour copier une une des données d'une ligne à une autre
Réponses
3
Affichages
938
salma_hayek
S
A
  • Question Question
XL 2021 Générer des données à partir d'une ligne spécifique jusqu'à une autre
Réponses
5
Affichages
545
gbinforme
G
P
  • Résolu(e)
XL 2021 Requête API - VBA Excel - Parse JSON
Réponses
2
Affichages
483
picc
P
A
  • Résolu(e)
XL 2016 Passer d'une MFC à une macro pour supprimer le bazar dans les règles.
2 3
Réponses
42
Affichages
2 K
TooFatBoy
TooFatBoy
S
  • Résolu(e)
XL 2016 copier des données d'une feuille à une autre selon critères et protection de la feuille 1
Réponses
6
Affichages
779
steph_29120
S
M
  • Question Question
XL 2013 MACRO VBA pour imprimer tous les bulletins d'un établissement scolaire
Réponses
4
Affichages
686
MBEPID
M
F
  • Résolu(e)
XL 2021 VBA et Power Query : ecrire des requetes avec variables
2
Réponses
28
Affichages
2 K
Florent74
F
M
  • Résolu(e)
XL 2013 Macross supprimant les données de cellule en dehors d'une période définie dans deux autres cellules
Réponses
9
Affichages
683
MarineU
M
Retour