Macro VBA dans Excel 2003

[ritournelle]

Bonjour,

J'aurais besoin d'aide pour modifier légèrement la macro suivante :

Sub EnvoiCondition()
    Dim Adresse As String   'Les déclarations de variables au début
    Dim Table As Range
    Dim Valeur
    
    Set Table = Sheets("Codes").Range("A2:D36")  'Définition de la plage de données
    Valeur = Range("A4").Value                   'Valeur à rechercher
    If Valeur <> "" Then
        On Error GoTo ErrH
        Adresse = WorksheetFunction.VLookup(Valeur, Table, 3, False)
        On Error GoTo 0
        If Adresse <> "" Then
            'Envoyer un mail
            ThisWorkbook.SendMail Recipients:=Adresse
        Else
            'Envoyer un fax
            ActiveWindow.SelectedSheets.PrintOut Copies:=1, _
                ActivePrinter:="DelFax sur Ne03:", Collate:=True
        End If
    End If
    Exit Sub
ErrH:
    MsgBox "La valeur " & Valeur & " n'existe pas dans la table."
End Sub

Je souhaiterais que dans l'envoi e-mail ne soit envoyé QUE la feuille active (et non le fichier au complet) en pièce jointe (et non en corps du message).

Merci par avance pour votre aide.
Bien cordialement.

 

[MichelXld]

Re : Macro VBA dans Excel 2003

bonsoir


Si j'ai bien compris, remplace

ThisWorkbook.SendMail Recipients:=Adresse

par

ActiveSheet.Copy
ActiveWorkbook.SendMail Recipients:=Adresse
ActiveWorkbook.Close False

bon week end
michel
Microsoft Excel MVP

 

[ritournelle]

Re : Macro VBA dans Excel 2003

Bonjour Michel,

Grand merci pour ta réponse ! C'est exactement ce que je souhaitais !

Dans la foulée je me permets encore une question :

Comment faire pour que l'objet du mail envoyé ait un autre intitulé que celui de la feuille Excel ? Quel est le code pour cela ?

D'avance merci.
Bonne journée à tous.

 

[MichelXld]

Re : Macro VBA dans Excel 2003

bonjour


La méthode SendMail possède un deuxième argument : Subject, qui permet de spécifier le titre du message .

ActiveWorkbook.SendMail Recipients:=Adresse, Subject:="Titre du message"

bon week end
michel
Microsoft Excel MVP

 

[ritournelle]

Re : Macro VBA dans Excel 2003 RESOLU

C'est nickel !
Merci beaucoup pour ton aide Michel, elle m'a été précieuse.

Bon week-end à toi aussi.
Bien cordialement,

Caroline